Abfragen für die StorageBlobLogs-Tabelle

Informationen zur Verwendung dieser Abfragen im Azure-Portal finden Sie im Log Analytics-Lernprogramm. Informationen zur REST-API finden Sie unter "Abfrage".

Häufigste Fehler

Listet 10 häufigste Fehler in den letzten 3 Tagen auf.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by StatusText
| top 10 by count_ desc

Vorgänge, die die meisten Fehler verursachen

Listet die obersten 10 Vorgänge auf, die die meisten Fehler in den letzten 3 Tagen verursachen.

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by OperationName
| top 10 by count_ desc

Vorgänge mit der höchsten Latenz

Listet die obersten 10 Vorgänge mit der längsten End-to-End-Latenz in den letzten 3 Tagen auf.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| top 10 by DurationMs desc
| project TimeGenerated, OperationName, DurationMs, ServerLatencyMs, ClientLatencyMs = DurationMs - ServerLatencyMs

Vorgänge, die serverseitige Drosselung verursachen

Hiermit werden alle Vorgänge aufgelistet, die in den letzten 3 Tagen Fehler durch eine serverseitige Drosselung verursacht haben.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText contains "ServerBusy"
| project TimeGenerated, OperationName, StatusCode, StatusText, _ResourceId

Anonyme Anforderungen anzeigen

Hiermit werden alle Anforderungen mit anonymem Zugriff in den letzten 3 Tagen aufgelistet.

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and AuthenticationType == "Anonymous"
| project TimeGenerated, OperationName, AuthenticationType, Uri, _ResourceId

Diagramm für häufige Vorgänge

Ein Kreisdiagramm mit Vorgängen, die in den letzten 3 Tagen verwendet werden.

StorageBlobLogs
| where TimeGenerated > ago(3d)
| summarize count() by OperationName
| sort by count_ desc 
| render piechart