Abfragen für die VIAudit-Tabelle

Informationen zur Verwendung dieser Abfragen im Azure-Portal finden Sie im Log Analytics-Lernprogramm. Informationen zur REST-API finden Sie unter "Abfrage".

Videoindexerüberwachung nach Konto-ID

Anzeigen von Überwachungsereignissen für Konto (AccountId = <GUID-ID>) mit einem optionalen Filter nach Benutzer-UPN.

VIAudit
| where AccountId == "<AccountId>"  // please fill in the accountId <Guid>
// | where Upn == "<Upn>" // to to filter on a specific user upn, uncomment this line
| limit 100

Videoindexerüberwachung top 10 Benutzer nach Vorgängen

Rendern des Zeitdiagramms von top 10 Benutzern nach Vorgängen mit einer optionalen Konto-ID zum Filtern.

// Trend of top 10 active Upn's
VIAudit
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
| where TimeGenerated > ago(30d)
| summarize count() by Upn
| top 10 by count_ desc
| project Upn
| join (VIAudit
| where TimeGenerated > ago(30d)
| summarize count() by Upn, bin(TimeGenerated,1d)) on Upn
| project TimeGenerated, Upn, count_
| render timechart

Analysierte Fehlermeldung für die Videoindexerüberwachung

Fehler beim Anzeigen von Überwachungsereignissen mit einer optionalen Konto-ID zum Filtern.

// Project failures with detailed error message.
VIAudit
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
| where  Status == "Failure"
| parse Description with "ErrorType: " ErrorType ". Message: " ErrorMessage ". Trace" *
| project TimeGenerated, OperationName, ErrorMessage, ErrorType, CorrelationId, _ResourceId

Fehler bei der Videoindizierungsüberwachung

Anzeigen von Überwachungsprotokollen aller fehlgeschlagenen Vorgangsversuche mit einem optionalen Filter nach Konto-ID und Benutzer-UPN.

VIAudit
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
// | where Upn == "<Upn>" // to to filter on a specific user upn, uncomment this line
| where Status == "Failure"
| limit 100