Freigeben über

Problembehandlung: Protokollüberwachungen (Visual Basic)

  • Artikel

Sie können die Objekte My.Application.Log und My.Log verwenden, um Informationen über Ereignisse zu protokollieren, die in Ihrer Anwendung auftreten.

Weitere Informationen zur Bestimmung, welche Protokolllistener diese Nachrichten erhalten, finden Sie unter Exemplarische Vorgehensweise: Bestimmen, wohin „My.Application.Log“ Informationen schreibt.

Das Log-Objekt kann das Filtern von Protokollen verwenden, um die Menge an Informationen zu beschränken, die protokolliert werden. Wenn die Filter falsch konfiguriert sind, können die Protokolle falsche Informationen enthalten. Weitere Informationen zur Filterung finden Sie unter Exemplarische Vorgehensweise: Filterung der Ausgaben von „My.Application.Log“.

Wenn ein Protokoll falsch konfiguriert ist, könnten Sie weitere Informationen über die aktuelle Konfiguration benötigen. Sie können diese Informationen über die erweiterte Eigenschaft TraceSource des Protokolls erhalten.

Bestimmen der Protokolllistener für das Protokollobjekt im Code

  1. Importieren Sie am Anfang der Codedatei den System.Diagnostics-Namespace. Weitere Informationen finden Sie unter Imports-Anweisung (.NET-Namespace und -typ).

    Imports System.Diagnostics

  2. Erstellen Sie eine Funktion, die eine Zeichenfolge mit Informationen für jeden Listener des Protokolls zurückgibt.

    Function GetListeners(ByVal listeners As TraceListenerCollection) As String
    Dim ret As String = ""
    For Each listener As TraceListener In listeners
        ret &= listener.Name
        Dim listenerType As Type = listener.GetType
        If listenerType Is GetType(DefaultTraceListener) Then
            Dim tmp As DefaultTraceListener =
                DirectCast(listener, DefaultTraceListener)
            ret &= ": Writes to the debug output."
        ElseIf listenerType Is GetType(Logging.FileLogTraceListener) Then
            Dim tmp As Logging.FileLogTraceListener =
                DirectCast(listener, Logging.FileLogTraceListener)
            ret &= ": Log filename: " & tmp.FullLogFileName
        ElseIf listenerType Is GetType(EventLogTraceListener) Then
            Dim tmp As EventLogTraceListener =
                DirectCast(listener, EventLogTraceListener)
            ret &= ": Event log name: " & tmp.EventLog.Log
        ElseIf listenerType Is GetType(XmlWriterTraceListener) Then
            Dim tmp As Diagnostics.XmlWriterTraceListener =
                DirectCast(listener, XmlWriterTraceListener)
            ret &= ": XML log"
        ElseIf listenerType Is GetType(ConsoleTraceListener) Then
            Dim tmp As ConsoleTraceListener =
                DirectCast(listener, ConsoleTraceListener)
            ret &= ": Console log"
        ElseIf listenerType Is GetType(DelimitedListTraceListener) Then
            Dim tmp As DelimitedListTraceListener =
                DirectCast(listener, DelimitedListTraceListener)
            ret &= ": Delimited log"
        Else
            ret &= ": Unhandled log type: " &
                listenerType.ToString
        End If
        ret &= vbCrLf
    Next

    Return ret
End Function

  3. Übergeben Sie die Auflistung der Ablaufverfolgungslistener des Protokolls an die GetListeners-Funktion und zeigen Sie den Rückgabewert.

    Dim ListenerCollection As TraceListenerCollection
ListenerCollection = My.Application.Log.TraceSource.Listeners
Dim ListenersText As String = GetListeners(ListenerCollection)
MsgBox(ListenersText)

    Weitere Informationen finden Sie unter TraceSource.

Siehe auch