ConfigurationHistorySection-Klasse

Konfiguriert die Konfigurationsverlaufseinstellungen des ApplicationHost-Hilfsdiensts.

Syntax

class ConfigurationHistorySection : ConfigurationSection  

Methoden

In der folgenden Tabelle werden die Methoden aufgelistet, die von der ConfigurationHistorySection-Klasse verfügbar gemacht werden.

Eigenschaften

In der folgenden Tabelle werden die Eigenschaften aufgeführt, die von der ConfigurationHistorySection Klasse verfügbar gemacht werden.

Unterklassen

Diese Klasse enthält keine Unterklassen.

Hinweise

Diese Klasse bietet ein Feature für den Konfigurationsverlauf, mit dem Sie zu einem früheren Konfigurationsstatus zurückkehren können, wenn Sie den aktuellen Zustand nicht mehr wünschen.

Der ApplicationHost-Hilfsdienst ermöglicht die Funktionalität des Konfigurationsverlaufs, indem die ApplicationHost.config-Datei in den durch die Period-Eigenschaft angegebenen Intervallen in getrennten Konfigurationsverlaufsunterverzeichnissen gespeichert wird. Die Unterverzeichnisse befinden sich in dem verzeichnis, das von der HistoryPath-Eigenschaft angegeben wird.

Wenn Ihnen beim Ändern der Datei „ApplicationHost.config“ ein Fehler unterläuft, können Sie eine frühere Version der Datei aus einem Konfigurationsverlaufsunterverzeichnis wiederherstellen, indem Sie die frühere Version in das Verzeichnis %windir% \system32\inetsrv\config kopieren.

Das Feature für den Konfigurationsverlauf hängt vom ApplicationHost-Hilfsdienst ab. Der ApplicationHost-Hilfsdienst ist ein laufzeitunabhängiger Dienst, der den Windows Process Activation Service (WAS) oder den World Wide Web Publishing Service (WWW-Dienst) nicht für den Betrieb benötigt. Sie hängt nicht von einem anderen Dienst ab, und der Starttyp ist Automatic.

Beispiel

Im folgenden Codebeispiel wird die maximale Anzahl von Verlaufsunterverzeichnissen auf 20 festgelegt und angegeben, dass die ApplicationHost.config-Datei alle 4 Minuten auf Änderungen überprüft wird. Eine Hilfsfunktion zeigt die ConfigurationHistorySection-Werte vor und nach der Änderung an.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the configuration history section.  
Set oSection = oWebAdmin.Get( _  
    "ConfigurationHistorySection.Path=" & _  
    "'MACHINE/WEBROOT/APPHOST',Location=''")  
  
' Display the class name of the section.  
WScript.Echo "[ " & oSection.Path_.Class & " ]" & vbCrLf  
  
' Display the initial settings.  
Call DisplaySettings("Initial Values", oSection)  
  
' Set the maximum number of history subdirectories to 20.  
oSection.MaxHistories = 20  
  
' Check ApplicationHost.config for changes every 4 minutes.  
oSection.Period = "00000000000400.000000:000"  
  
' Save the values to configuration.  
oSection.Put_  
  
' Refresh the oSection object variable with the new values.  
oSection.Refresh_  
  
' Show the changed settings.  
Call DisplaySettings("New Values", oSection)  
  
' ==== DisplaySettings helper function. ====  
Function DisplaySettings(HeadingText, oSection)  
  
    ' Display a heading.  
    WScript.Echo String(Len(HeadingText), "-")  
    WScript.Echo HeadingText  
    WScript.Echo String(Len(HeadingText), "-")  
  
    ' Display configuration history section properties.  
    WScript.Echo "Path: " & oSection.Path  
    WScript.Echo "Location: " & oSection.Location  
    WScript.Echo "History Path: " & oSection.HistoryPath  
    WScript.Echo "Period: " & oSection.Period  
    WScript.Echo "MaxHistories: " & oSection.MaxHistories  
    WScript.Echo  
End Function  
  

Vererbungshierarchie

ConfigurationSection

ConfigurationHistorySection

Anforderungen

Weitere Informationen

ConfigurationSection-Klasse