Freigeben über

ipv4_is_in_any_range()

  • Artikel

Gilt für: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Überprüft, ob sich die IPv4-Zeichenfolgenadresse in einem der angegebenen IPv4-Adressbereiche befindet.

Leistungstipps

Hinweis

Wenn mehr als 128 Suchbegriffe verwendet werden, ist die Suchoptimierung für Textindex deaktiviert, was zu einer verringerten Abfrageleistung führen kann.

Syntax

ipv4_is_in_any_range(Ipv4Address , Ipv4Range [ , Ipv4Range ...] )

ipv4_is_in_any_range(Ipv4Address , Ipv4Ranges )

Erfahren Sie mehr über Syntaxkonventionen.

Parameter

Name Type Erforderlich Beschreibung
Ipv4Address string ✔️ Ein Ausdruck, der eine IPv4-Adresse darstellt.
Ipv4Range string ✔️ Ein IPv4-Bereich oder eine Liste von IPv4-Bereichen, die mit IP-Präfixnotation geschrieben wurden.
Ipv4Ranges dynamic ✔️ Ein dynamisches Array mit IPv4-Bereichen, die mit IP-Präfixnotation geschrieben wurden.

Hinweis

Es ist entweder eine oder mehrere IPv4Range-Zeichenfolgen oder ein dynamisches IPv4Ranges-Array erforderlich.

IP-Präfixnotation

Ip-Präfixnotation (auch als CIDR-Notation bezeichnet) ist eine präzise Möglichkeit, eine IP-Adresse und die zugehörige Netzwerkmaske darzustellen. Das Format ist <base IP>/<prefix length>, wobei die Präfixlänge die Anzahl der führenden 1 Bits in der Netzmaske ist. Die Präfixlänge bestimmt den Bereich der IP-Adressen, die zum Netzwerk gehören.

Bei IPv4 ist die Präfixlänge eine Zahl zwischen 0 und 32. Die Notation 192.168.2.0/24 stellt also die IP-Adresse 192.168.2.0 mit einer Netmask von 255.255.255.255.0 dar. Diese Netmaske hat 24 führende 1 Bit oder eine Präfixlänge von 24.

Bei IPv6 ist die Präfixlänge eine Zahl zwischen 0 und 128. Daher stellt die Notation fe80::85d:e82c:9446:7994/120 die IP-Adresse fe80::85d:e82c:9446:7994 mit einer Netmaske von ffff:ffff:ffff:ffff:ffff:ffff:ffff:ffff:ffff:ff00 dar. Diese Netmaske hat 120 führende 1 Bit oder eine Präfixlänge von 120.

Gibt zurück

  • true: Wenn sich die IPv4-Adresse im Bereich eines der angegebenen IPv4-Netzwerke befindet.
  • false:Sonst.
  • null: Wenn die Konvertierung für eine der beiden IPv4-Zeichenfolgen nicht erfolgreich war.

Beispiele

Syntax mithilfe einer Liste von Zeichenfolgen

print Result=ipv4_is_in_any_range('192.168.1.6', '192.168.1.1/24', '10.0.0.1/8', '127.1.0.1/16')

Ausgabe

Ergebnis
true

Syntax mit dynamischem Array

print Result=ipv4_is_in_any_range("127.0.0.1", dynamic(["127.0.0.1", "192.168.1.1"]))

Ausgabe

Ergebnis
true

Erweitern der Tabelle mit IPv4-Bereichsprüfung

let LocalNetworks=dynamic([
    "192.168.1.1/16",
    "127.0.0.1/8",
    "10.0.0.1/8"
]);
let IPs=datatable(IP:string) [
    "10.1.2.3",
    "192.168.1.5",
    "123.1.11.21",
    "1.1.1.1"
];
IPs
| extend IsLocal=ipv4_is_in_any_range(IP, LocalNetworks)

Output

IP IstLokal
10.1.2.3 true
192.168.1.5 true
123.1.11.21 false
1.1.1.1 false

Zugehöriger Inhalt