partition-Operator

Gilt für: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Der Partitionsoperator partitioniert die Datensätze seiner Eingabetabelle in mehrere Untertabellen gemäß Werten in einer Schlüsselspalte. Der Operator führt eine Unterabfrage für jede Untertabelle aus und erzeugt eine einzelne Ausgabetabelle, die die Vereinigung der Ergebnisse aller Unterabfragen darstellt.

Dieser Operator ist nützlich, wenn Sie eine Unterabfrage nur für eine Teilmenge von Zeilen ausführen müssen, die zum gleichen Partitionsschlüssel gehören, und nicht das gesamte Dataset abfragen. Diese Unterabfragen können Aggregatfunktionen, Fensterfunktionen, top N und andere umfassen.

Der Partitionsoperator unterstützt mehrere Strategien des Unterabfragevorgangs:

• Systemeigene Verwendung mit einer impliziten Datenquelle mit Tausenden von Schlüsselpartitionswerten.
• Shuffle – Wird mit einer impliziten Quelle mit Millionen von Schlüsselpartitionswerten verwendet.
• Legacy – Wird mit einer impliziten oder expliziten Quelle für 64 oder weniger Schlüsselpartitionswerte verwendet.

Syntax

T partition | [ Strategie ] [ hint.strategy=Hinweise ] by SpaltentransformationSubQuery ( )

T | partition [ ] [ hint.strategy=legacy Hinweise ] by Column { SubQueryWithSource }

Erfahren Sie mehr über Syntaxkonventionen.

Parameter

Unterstützte Hinweise

Gibt zurück

Der Operator gibt eine Vereinigung der Ergebnisse der einzelnen Unterabfragen zurück.

Strategien

Der Partitionsoperator unterstützt mehrere Strategien des Unterabfragevorgangs: systemeigene, shuffle und legacy.

Systemeigene Strategie

Diese Strategie sollte angewendet werden, wenn die Anzahl der unterschiedlichen Werte des Partitionsschlüssels nicht groß ist, etwa in den Tausenden.

Die Unterabfrage muss eine tabellarische Transformation sein, die keine tabellarische Quelle angibt. Die Quelle ist implizit und wird entsprechend den Untertabellenpartitionen zugewiesen. Nur bestimmte unterstützte Operatoren können in der Unterabfrage verwendet werden. Es gibt keine Einschränkung für die Anzahl der Partitionen.

Um diese Strategie zu verwenden, geben Sie hint.strategy=nativean.

Shuffle-Strategie

Diese Strategie sollte angewendet werden, wenn die Anzahl der unterschiedlichen Werte des Partitionsschlüssels in den Millionen groß ist.

Die Unterabfrage muss eine tabellarische Transformation sein, die keine tabellarische Quelle angibt. Die Quelle ist implizit und wird entsprechend den Untertabellenpartitionen zugewiesen. Nur bestimmte unterstützte Operatoren können in der Unterabfrage verwendet werden. Es gibt keine Einschränkung für die Anzahl der Partitionen.

Um diese Strategie zu verwenden, geben Sie hint.strategy=shufflean. Weitere Informationen zur Shuffle-Strategie und -Leistung finden Sie in der Shuffle-Abfrage.

Unterstützte Operatoren für die systemeigenen und shuffle-Strategien

Die folgende Liste der Operatoren kann in Unterabfragen mit den systemeigenen oder shuffle-Strategien verwendet werden:

• count
• distinct
• extend
• make-series
• mv-apply
• mv-expand
• parse
• parse-where
• project
• project-away
• project-keep
• project-rename
• project-reorder
• reduce
• Beispiel
• sample-distinct
• scan
• search
• serialize
• sort
• summarize
• take
• top
• top-hitters
• top-nested
• where

Legacystrategie

Aus historischen Gründen ist die Strategie die legacy Standardstrategie. Es wird jedoch empfohlen, die systemeigenen oder shuffle-Strategien zu bevorzugen, da der legacy Ansatz auf 64 Partitionen beschränkt ist und weniger effizient ist.

In einigen Szenarien kann die legacy Strategie aufgrund der Unterstützung für die Aufnahme einer tabellarischen Quelle in die Unterabfrage erforderlich sein. In solchen Fällen kann die Unterabfrage nur auf die Schlüsselspalte "Spalte" aus der Tabellarischen Eingabequelle T verweisen. Verwenden Sie die Syntaxspaltetoscalar(), um auf die Spalte zu verweisen.

Wenn es sich bei der Unterabfrage um eine tabellarische Transformation ohne tabellarische Quelle handelt, ist die Quelle implizit und basiert auf den Untertabellenpartitionen.

Um diese Strategie zu verwenden, geben Oder weglassen Sie hint.strategy=legacy andere Strategieanzeigen.

Beispiele

Auffinden der obersten Werte

In einigen Fällen ist es leistungsfähiger und einfacher, eine Abfrage mit dem partition Operator zu schreiben, als den top-nested Operator zu verwenden. Die folgende Abfrage führt eine Berechnete summarize Unterabfrage aus und top beginnt mit State W: "WYOMING", "WASHINGTON", "WEST VIRGINIA" und "WISCONSIN".

StormEvents
| where State startswith 'W'
| partition hint.strategy=native by State 
    (
    summarize Events=count(), Injuries=sum(InjuriesDirect) by EventType, State
    | top 3 by Events 
    ) 

Ausgabe

Systemeigene Strategie

Die folgende Abfrage gibt die obersten 2 EventType Werte TotalInjuries für jede State zurück, die mit "W" beginnt:

StormEvents
| where State startswith 'W'
| partition hint.strategy = native by State
    (
    summarize TotalInjueries = sum(InjuriesDirect) by EventType
    | top 2 by TotalInjueries
    )

Ausgabe

Shuffle-Strategie

Die folgende Abfrage gibt die obersten 3 DamagedProperty Werte foreach EpisodeId und die Spalten EpisodeId und State.

StormEvents
| partition hint.strategy=shuffle by EpisodeId
    (
    top 3 by DamageProperty
    | project EpisodeId, State, DamageProperty
    )
| count

Ausgabe

Legacystrategie mit expliziter Quelle

Die folgende Abfrage führt zwei Unterabfragen aus:

• Wenn x == 1die Abfrage alle Zeilen zurückgibt, aus StormEvents denen dies der Wert ist InjuriesIndirect == 1.
• Wenn x == 2die Abfrage alle Zeilen zurückgibt, aus StormEvents denen dies der Wert ist InjuriesIndirect == 2.

Das Endergebnis ist die Vereinigung dieser beiden Unterabfragen.

range x from 1 to 2 step 1
| partition hint.strategy=legacy by x {StormEvents | where x == InjuriesIndirect}
| count 

Ausgabe

Partitionsreferenz

Im folgenden Beispiel wird gezeigt, wie Sie den Operator als Operator verwenden, um jeder Datenpartition einen "Namen" zuzuweisen und diesen Namen dann innerhalb der Unterabfrage wiederzuverwenden. Dieser Ansatz ist nur für die legacy Strategie relevant.

T
| partition by Dim
(
    as Partition
    | extend MetricPct = Metric * 100.0 / toscalar(Partition | summarize sum(Metric))
)