ConnectorFormat-Objekt (PowerPoint)

Enthält Eigenschaften und Methoden, die für Verbindungen gelten.

Hinweise

Eine Verbindung ist eine Linie, die zwei andere Formen mit als "Verbindungsseiten" bezeichneten Punkten zusammenfügt. Wenn Sie die verbundenen Formen neu anordnen, wird die Geometrie der Verbindung automatisch angepasst, sodass die Formen verbunden bleiben.

Verwenden Sie die ConnectorFormat -Eigenschaft, um ein ConnectorFormat -Objekt zurückzugeben. Verwenden Sie die Methoden BeginConnect und EndConnect, die am Ende der Verbindung mit anderen Formen im Dokument anfügen. Verwenden Sie die RerouteConnections -Methode, um automatisch den kürzesten Pfad zwischen den beiden Formen, die durch die Verbindung verbundenen finden. Verwenden Sie die Connector -Eigenschaft, um festzustellen, ob eine Form eine Verbindung ist.

Beachten Sie, dass Sie eine Größe und Position zuweisen, wenn Sie eine Verbindung zu der Shapes -Auflistung hinzufügen. Wenn Sie eine Verbindung mit anderen Formen verbinden möchten, sind die ursprüngliche Größe und Position die von Ihnen angegebenen nicht relevant. Ebenso Sie festlegen, welche Verbindungsseiten einer Form mit der Verbindung, wenn Sie die Verbindung verbinden, aber die RerouteConnections -Methode verwenden, nachdem die Verbindung verbunden ist möglicherweise die Verbindungsseiten die Verbindung, und Ihre ursprüngliche Auswahl von Verbindungsseiten irrelevant machen ändern.

Verbindungsseiten werden nach den Regeln nummeriert, die in der folgenden Tabelle verzeichnet sind.

Beispiel

Im folgenden Beispiel werden myDocument zwei Rechtecke hinzugefügt und die Rechtecke durch eine gekrümmte Verbindung miteinander verbunden.

Set myDocument = ActivePresentation.Slides(1)

Set s = myDocument.Shapes

Set firstRect = s.AddShape(msoShapeRectangle, 100, 50, 200, 100)

Set secondRect = s.AddShape(msoShapeRectangle, 300, 300, 200, 100)

With s.AddConnector(msoConnectorCurve, 0, 0, 0, 0).ConnectorFormat

    .BeginConnect ConnectedShape:=firstRect, ConnectionSite:=1

    .EndConnect ConnectedShape:=secondRect, ConnectionSite:=1

    .Parent.RerouteConnections

End With

Um herauszufinden, welche Zahl welcher Verbindungsstelle auf einer komplexen Form entspricht, können Sie mit der Form experimentieren, während die Makroaufzeichnung aktiviert ist, und dann den aufgezeichneten Code untersuchen. Oder Sie können eine Form erstellen, auswählen und dann das folgende Beispiel ausführen. Dieser Code nummerieren jeden Verbindungsstandort und fügt einen Connector an ihn an.

Set mainshape = ActiveWindow.Selection.ShapeRange(1)

With mainshape

    bx = .Left + .Width + 50

    by = .Top + .Height + 50

End With

With ActiveWindow.View.Slide

    For j = 1 To mainshape.ConnectionSiteCount

        With .Shapes.AddConnector(msoConnectorStraight, bx, by, bx + 50, by + 50)

            .ConnectorFormat.EndConnect mainshape, j

            .ConnectorFormat.Type = msoConnectorElbow

            .Line.ForeColor.RGB = RGB(255, 0, 0)

            l = .Left

            t = .Top

        End With

        With .Shapes.AddTextbox(msoTextOrientationHorizontal, l, t, 36, 14)

            .Fill.Visible = False

            .Line.Visible = False

            .TextFrame.TextRange.Text = j

        End With

    Next j

End With

Siehe auch

PowerPoint-Objektmodellreferenz

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.