MouseEvent.Button-Eigenschaft (Visio)

Artikel
10/16/2024

Gibt die Maustaste zurück, die ausgewählt wurde, um ein MouseDown- oder MouseUp-Ereignis auszulösen. Schreibgeschützt.

Syntax

Ausdruck. Knopf

Ausdruck Ein Ausdruck, der ein MouseEvent-Objekt zurückgibt.

Rückgabewert

Long

Hinweise

Mögliche Werte für die Button-Eigenschaft können alle Konstanten sein, die in der VisKeyButtonFlags-Enumeration in der Visio-Typbibliothek deklariert sind.

Beispiel

Dieses Klassenmodul zeigt, wie eine Empfängerklasse mit der Bezeichnung MouseListener definiert wird, die von Mausaktionen im aktiven Fenster ausgelöste Ereignisse überwacht. Es deklariert die vsoWindow-Objektvariable unter Verwendung des Schlüsselworts WithEvents. Das Klassenmodul enthält auch Ereignishandler für die MouseDown-, MouseMove- und MouseUp-Ereignisse .

Um dieses Beispiel auszuführen, fügen Sie ein neues Klassenmodul in Ihr Vba-Projekt (Microsoft Visual Basic for Applications) ein, nennen Sie es MouseListener, und fügen Sie den folgenden Code in das Modul ein.

Dim WithEvents vsoWindow As Window 
 
Private Sub Class_Initialize() 
 
 Set vsoWindow = ActiveWindow 
 
End Sub 
 
Private Sub Class_Terminate() 
 
 Set vsoWindow = Nothing 
 
End Sub 
 
Private Sub vsoWindow_MouseDown(ByVal Button As Long, ByVal KeyButtonState As Long, ByVal x As Double, ByVal y As Double, CancelDefault As Boolean) 
 
 Debug.Print "Button is: "; Button 
 
End Sub 
 
Private Sub vsoWindow_MouseMove(ByVal Button As Long, ByVal KeyButtonState As Long, ByVal x As Double, ByVal y As Double, CancelDefault As Boolean) 
 
 Debug.Print "x-position is "; x 
 Debug.Print "y-position is "; y 
 
End Sub 
 
Private Sub vsoWindow_MouseUp(ByVal Button As Long, ByVal KeyButtonState As Long, ByVal x As Double, ByVal y As Double, CancelDefault As Boolean) 
 
 If Button = 1 Then 
 
 Debug.Print "Left mouse button released" 
 
 ElseIf Button = 2 Then 
 
 Debug.Print "Right mouse button released" 
 
 ElseIf Button = 16 Then 
 
 Debug.Print "Center mouse button released" 
 
 End If 
 
End Sub

Fügen Sie dann den folgenden Code in das ThisDocument-Projekt ein.

Dim myMouseListener As MouseListener 
 
Private Sub Document_DocumentSaved(ByVal doc As IVDocument) 
 
 Set myMouseListener = New MouseListener 
 
End Sub 
 
Private Sub Document_BeforeDocumentClose(ByVal doc As IVDocument) 
 
 Set myMouseListener = Nothing 
 
End Sub

Speichern Sie das Dokument, um die Klasse zu initialisieren, und klicken Sie dann auf eine beliebige Stelle im aktiven Fenster, um ein MouseDown-Ereignis auszulösen . Im Direktfenster gibt der Handler den Wert aus, der die Maustaste darstellt, auf die zum Auslösen des Ereignisses geklickt wurde.

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.

Freigeben über