Application.FileDialog property (Access)

Returns a FileDialog object that represents a single instance of a file dialog box. Read-only.

Syntax

expression.FileDialog (dialogType)

expression A variable that represents an Application object.

Parameters

Remarks

The msoFileDialogOpen and msoFileDialogSaveAs constants are not supported in Microsoft Access.

Note that when a file is selected using the File open Dialog, the directory containing the selected file will become the current directory for the process. This means that the directory will be locked until the current diectory is changed, or the process terminates. This will prevent the directory from being deleted, moved, or renamed.

Example

This example illustrates how to use the FileDialog object to display a dialog box that allows the user to select one or more files. The selected files are then added to a listbox named FileList.

Private Sub cmdFileDialog_Click() 
  
   ' Requires reference to Microsoft Office 11.0 Object Library. 
 
   Dim fDialog As Office.FileDialog 
   Dim varFile As Variant 
 
   ' Clear listbox contents. 
   Me.FileList.RowSource = "" 
 
   ' Set up the File Dialog. 
   Set fDialog = Application.FileDialog(msoFileDialogFilePicker) 
 
   With fDialog 
 
      ' Allow user to make multiple selections in dialog box 
      .AllowMultiSelect = True 
             
      ' Set the title of the dialog box. 
      .Title = "Please select one or more files" 
 
      ' Clear out the current filters, and add our own. 
      .Filters.Clear 
      .Filters.Add "Access Databases", "*.MDB" 
      .Filters.Add "Access Projects", "*.ADP" 
      .Filters.Add "All Files", "*.*" 
 
      ' Show the dialog box. If the .Show method returns True, the 
      ' user picked at least one file. If the .Show method returns 
      ' False, the user clicked Cancel. 
      If .Show = True Then 
 
         'Loop through each file selected and add it to our list box. 
         For Each varFile In .SelectedItems 
            Me.FileList.AddItem varFile 
         Next 
 
      Else 
         MsgBox "You clicked Cancel in the file dialog box." 
      End If 
   End With 
End Sub

Support and feedback

Have questions or feedback about Office VBA or this documentation? Please see Office VBA support and feedback for guidance about the ways you can receive support and provide feedback.