Application.DStDevP Method (Access)

Article
10/12/2015

Estimates the standard deviation across a population in a specified set of records (a domain). .

Syntax

expression .DStDevP(Expr, Domain, Criteria)

expression A variable that represents an Application object.

Parameters

Name	Required/Optional	Data Type	Description
Expr	Required	String	An expression that identifies the numeric field on which you want to find the standard deviation. It can be a string expression identifying a field from a table or query, or it can be an expression that performs a calculation on data in that field. In expr, you can include the name of a field in a table, a control on a form, a constant, or a function. If expr includes a function, it can be either built-in or user-defined, but not another domain aggregate or SQL aggregate function.
Domain	Required	String	A string expression identifying the set of records that constitutes the domain. It can be a table name or a query name for a query that does not require a parameter.
Criteria	Optional	Variant	An optional string expression used to restrict the range of data on which the DStDevP function is performed. For example, criteria is often equivalent to the WHERE clause in an SQL expression, without the word WHERE. If criteria is omitted, the DStDevP function evaluates expr against the entire domain. Any field that is included in criteria must also be a field in domain; otherwise, the DStDevP function will return a Null.

Return Value

Variant

Remarks

If domain refers to fewer than two records or if fewer than two records satisfy criteria, the DStDevP function returns a Null, indicating that a standard deviation can't be calculated.

You can use the DStDevP function to specify criteria in the Criteria row of a select query. For example, you could create a query on an Orders table and a Products table to display all products for which the freight cost fell above the mean plus the standard deviation for freight cost.

You can use the DStDevP function in a calculated field expression of a query, or in the Update To row of an update query.

Note

You can use the DStDev and DStDevP functions or the StDev and StDevP functions in a calculated field expression of a totals query. If you use the DStDev or DStDevP function, values are calculated before data is grouped. If you use the StDev or StDevP function, the data is grouped before values in the field expression are evaluated.

Use the DStDev function in a calculated control when you need to specify criteria to restrict the range of data on which the function is performed.

If you simply want to find the standard deviation across all records in domain, use the StDev or StDevP function.

If the data type of the field from which expr is derived is a number, the DStDevP function returns a Double data type. If you use the DStDevP function in a calculated control, include a data type conversion function in the expression to improve performance.

Example

The following example returns estimates of the standard deviation for a population and a population sample for orders shipped to the United Kingdom. The domain is an Orders table. The criteria argument restricts the resulting set of records to those for which the ShipCountry value is UK.

Dim dblX As Double 
Dim dblY As Double 
 
' Sample estimate. 
dblX = DStDev("[Freight]", "Orders", "[ShipCountry] = 'UK'") 
 
' Population estimate. 
dblY = DStDevP("[Freight]", "Orders", "[ShipCountry] = 'UK'")

The next example calculates the same estimates by using a variable, strCountry, in the criteria argument. Note that single quotation marks (') are included in the string expression, so that when the strings are concatenated, the string literal UK will be enclosed in single quotation marks.

Dim strCountry As String 
Dim dblX As Double 
Dim dblY As Double 
 
strCountry = "UK" 
 
dblX = DStDev("[Freight]", "Orders", _ 
    "[ShipCountry] = '" & strCountry & "'") 
 
dblY = DStDevP("[Freight]", "Orders", _ 
    "[ShipCountry] = '" & strCountry & "'")

The following examples show how to use various types of criteria with the DStDevP function.

Sample code provided by: Community Member Icon The UtterAccess community | About the Contributors

    ' ***************************
    ' Typical Use
    ' Numerical values. Replace "number" with the number to use.
    variable = DStDevP("[FieldName]", "TableName", "[Criteria] = number")

    ' Strings.
    ' Numerical values. Replace "string" with the string to use.
    variable = DStDevP("[FieldName]", "TableName", "[Criteria]= 'string'")

    ' Dates. Replace "date" with the string to use.
    variable = DStDevP("[FieldName]", "TableName", "[Criteria]= #date#")
    ' ***************************

    ' ***************************
    ' Referring to a control on a form
    ' Numerical values
    variable = DStDevP("[FieldName]", "TableName", "[Criteria] = " & Forms!FormName!ControlName)

    ' Strings
    variable = DStDevP("[FieldName]", "TableName", "[Criteria] = '" & Forms!FormName!ControlName & "'")

    ' Dates
    variable = DStDevP("[FieldName]", "TableName", "[Criteria] = #" & Forms!FormName!ControlName & "#")
    ' ***************************

    ' ***************************
    ' Combinations
    ' Multiple types of criteria
    variable = DStDevP("[FieldName]", "TableName", "[Criteria1] = " & Forms![FormName]![Control1] _
             & " AND [Criteria2] = '" & Forms![FormName]![Control2] & "'" _
            & " AND [Criteria3] =#" & Forms![FormName]![Control3] & "#")
    
    ' Use two fields from a single record.
    variable = DStDevP("[LastName] & ', ' & [FirstName]", "tblPeople", "[PrimaryKey] = 7")
            
    ' Expressions
    variable = DStDevP("[Field1] + [Field2]", "tableName", "[PrimaryKey] = 7")
    
    ' Control Structures
    variable = DStDevP("IIf([LastName] Like 'Smith', 'True', 'False')", "tableName", "[PrimaryKey] = 7")
    ' ***************************

About the Contributors

UtterAccess is the premier Microsoft Access wiki and help forum. Click here to join.

Share via