Propiedad Application.StartupPaths (Visio)

Obtiene o establece las rutas de acceso donde Microsoft Visio busca los complementos de otro fabricante y del usuario que se deben ejecutar al iniciarse la aplicación. Lectura y escritura.

Sintaxis

expresión. StartupPaths

expresión Variable que representa un objeto Application.

Valor devuelto

Cadena

Comentarios

De forma predeterminada, la propiedad StartupPaths está establecida en una cadena vacía ("").

La cadena pasada a la propiedad StartupPaths y recibida de ésta es la misma cadena que se muestra en el cuadro de diálogo Ubicaciones de archivos. (Haga clic en la pestaña Archivo , en Opciones, en Opciones avanzadasy, a continuación, en General, haga clic en Ubicaciones de archivo). Esta cadena se almacena en la subclave HKEY_CURRENT_USER\Software\Microsoft\Office\14.0\Visio\Application\StartupPath .

Cuando la aplicación busca archivos de complemento de inicio de usuario y de terceros, busca en todas las rutas de acceso denominadas en la propiedad StartupPaths , así como en las rutas de acceso de los complementos de inicio instalados en la instalación y en todas las subcarpetas de esas rutas de acceso. Si pasa la propiedad StartupPaths al método EnumDirectories, éste devolverá una lista de todas las rutas de acceso completas de las carpetas que se le han pasado.

Al establecer la propiedad StartupPaths , se reemplazan los valores existentes para StartupPaths en el cuadro de diálogo Ubicaciones de archivo. Si desea conservar los valores existentes, obtenga la cadena existente y, a continuación, anexe la nueva ruta de acceso a dicha cadena, como se muestra en el código siguiente:

Application.StartupPaths = Application.StartupPaths & ";" & "newpath ".

Ejemplo:

Esta macro de Microsoft Visual Basic para Aplicaciones (VBA) muestra cómo utilizar la propiedad StartupPaths para agregar una ruta a la lista de rutas de acceso de Inicio.

Public Sub StartupPaths_Example() 
  
    Dim strMessage As String 
    Dim strNewPath As String 
    Dim strStartupPath As String 
    Dim strTitle As String  
 
    'Get the path we want to add.  
    strStartupPath = Application.StartupPaths  
    strTitle = "StartupPaths"  
    strMessage = "The current content of the Visio Start-up paths box is:"  
    strMessage = strMessage & vbCrLf & strStartupPath  
    MsgBox strMessage, vbInformation + vbOKOnly, strTitle  
    strMessage = "Type in an additional path for Visio to look for add-ons. "  
         
    strNewPath = InputBox$(strMessage, strTitle)  
 
    'Make sure the folder exists and that it's not 
    'already in the Start-up paths box.  
    strMessage = ""  
 
    If strNewPath = ""  Then 
        strMessage = "You did not enter a path." 
    ElseIf InStr(strStartupPath, strNewPath)  Then 
        strMessage = "The path you specified is already in the Start-up paths box." 
    ElseIf Len(Dir$(strNewPath, vbDirectory)) = 0 And _  
                Len(Dir$(Application.Path & strNewPath, _  
                vbDirectory)) = 0 Then 
        strMessage = "The folder you typed does not exist (or is empty)." 
    Else 
        Application.StartupPaths = strStartupPath & ";" & strNewPath 
        strMessage = "We just added " & strNewPath & _  
                " to the startup paths." 
    End If 
       
    If strMessage <> ""  Then 
        MsgBox strMessage, vbExclamation + vbOKOnly, strTitle  
    End If 
  
End Sub

Soporte técnico y comentarios

¿Tiene preguntas o comentarios sobre VBA para Office o esta documentación? Vea Soporte técnico y comentarios sobre VBA para Office para obtener ayuda sobre las formas en las que puede recibir soporte técnico y enviar comentarios.