Partager via

Exceptions : expression try...finally

  • Article

L’expression try...finally vous permet d’exécuter du code de nettoyage même si un bloc de code lève une exception.

Syntaxe

try
    expression1
finally
    expression2

Notes

L’expression try...finally peut être utilisée pour exécuter le code dans expression2 dans la syntaxe précédente, qu’une exception soit générée ou non pendant l’exécution d’expression1.

Le type d’expression2 ne contribue pas à la valeur de l’expression entière. Le type renvoyé quand aucune exception ne se produit est la dernière valeur dans expression1. Quand une exception se produit, aucune valeur n’est renvoyée et le flux de contrôle est transféré au gestionnaire d’exceptions correspondant suivant dans la pile des appels. Si aucun gestionnaire d’exceptions n’est trouvé, le programme s’arrête. Avant l’exécution du code dans un gestionnaire correspondant ou avant la fin du programme, le code de la branche finally est exécuté.

Le code suivant montre l’utilisation de l’expression try...finally.

let divide x y =
   let stream : System.IO.FileStream = System.IO.File.Create("test.txt")
   let writer : System.IO.StreamWriter = new System.IO.StreamWriter(stream)
   try
      writer.WriteLine("test1")
      Some( x / y )
   finally
      writer.Flush()
      printfn "Closing stream"
      stream.Close()

let result =
  try
     divide 100 0
  with
     | :? System.DivideByZeroException -> printfn "Exception handled."; None

La sortie de la console est la suivante.

Closing stream
Exception handled.

Comme vous pouvez le voir dans la sortie, le flux a été fermé avant la gestion de l’exception externe et le fichier test.txt contient le texte test1, qui indique que les mémoires tampons ont été vidées et écrites sur le disque même si l’exception a transféré le contrôle au gestionnaire d’exceptions externes.

Notez que la construction try...with est distincte de la construction try...finally. Par conséquent, si votre code nécessite à la fois un bloc with et un bloc finally, vous devez imbriquer les deux constructions, comme dans l’exemple de code suivant.

exception InnerError of string
exception OuterError of string

let function1 x y =
   try
     try
        if x = y then raise (InnerError("inner"))
        else raise (OuterError("outer"))
     with
      | InnerError(str) -> printfn "Error1 %s" str
   finally
      printfn "Always print this."


let function2 x y =
  try
     function1 x y
  with
     | OuterError(str) -> printfn "Error2 %s" str

function2 100 100
function2 100 10

Dans le contexte des expressions de calcul, y compris les expressions de séquence et les expressions asynchrones, les expressions try...finally peuvent avoir une implémentation personnalisée. Pour plus d’informations, consultez Expressions de calcul.

Voir aussi