Guide pratique : effectuer plusieurs requêtes web en parallèle avec Async et Await (Visual Basic)

Article
06/01/2023

Dans une méthode asynchrone, les tâches sont démarrées quand elles sont créées. L’opérateur Await est appliqué à la tâche au point dans la méthode où le traitement ne peut pas se poursuivre tant que la tâche n’est pas terminée. Souvent, une tâche est attendue dès sa création, comme le montre l’exemple suivant.

Dim result = Await someWebAccessMethodAsync(url)

Toutefois, vous pouvez séparer la création de la tâche de son attente si votre programme doit accomplir d’autres tâches qui ne dépendent pas de l’achèvement de la tâche.

' The following line creates and starts the task.
Dim myTask = someWebAccessMethodAsync(url)

' While the task is running, you can do other work that does not depend
' on the results of the task.
' . . . . .

' The application of Await suspends the rest of this method until the task is
' complete.
Dim result = Await myTask

Entre le démarrage d’une tâche et le moment où elle est attendue, vous pouvez démarrer d’autres tâches. Les tâches supplémentaires s’exécutent implicitement en parallèle, mais aucun thread supplémentaire n’est créé.

Le programme suivant démarre trois téléchargements web asynchrones, puis les attend dans l’ordre dans lequel ils sont appelés. Notez que quand vous exécutez le programme, les tâches ne se terminent pas toujours dans l’ordre dans lequel elles sont créées et attendues. Elles commencent à s’exécuter quand elles sont créées, et une ou plusieurs d’entre elles peuvent se terminer avant que la méthode n’atteigne les expressions await.

Notes

Pour mener à bien ce projet, Visual Studio 2012 ou version ultérieure et le .NET Framework 4.5 ou version ultérieure doivent être installés sur votre ordinateur.

Pour obtenir un autre exemple qui démarre plusieurs tâches en même temps, consultez Guide pratique pour étendre la procédure pas à pas Async à l’aide de Task.WhenAll (Visual Basic).

Vous pouvez télécharger le code de cet exemple à partir des exemples de code pour développeur.

Pour configurer le projet

Pour configurer une application WPF, effectuez les étapes suivantes. Vous trouverez des instructions détaillées pour ces étapes dans Procédure pas à pas : accès au web avec Async et Await (Visual Basic).
- Créez une application WPF qui contient une zone de texte et un bouton. Nommez le bouton startButton et la zone de texte resultsTextBox.
- Ajoutez une référence pour System.Net.Http.
- Dans le fichier MainWindow.xaml.vb, ajoutez une instruction Imports pour System.Net.Http.

Pour ajouter le code

Dans la fenêtre de conception, MainWindow.xaml, double-cliquez sur le bouton pour créer le gestionnaire d’événements startButton_Click dans MainWindow.xaml.vb.
Copiez le code suivant et collez-le dans le corps de startButton_Click dans MainWindow.xaml.vb.
```
resultsTextBox.Clear()
Await CreateMultipleTasksAsync()
resultsTextBox.Text &= vbCrLf & "Control returned to button1_Click."
```
Le code appelle une méthode asynchrone, CreateMultipleTasksAsync, qui pilote l’application.

Ajoutez les méthodes de prise en charge suivantes au projet :

ProcessURLAsync utilise une méthode HttpClient pour télécharger le contenu d’un site web sous la forme d’un tableau d’octets. La méthode de prise en charge, ProcessURLAsync, affiche et retourne ensuite la longueur du tableau.
DisplayResults affiche le nombre d’octets dans le tableau d’octets pour chaque URL. Cet affichage indique quand le téléchargement de chaque tâche est terminé.

Copiez les méthodes suivantes et collez-les après le gestionnaire d’événements startButton_Click dans MainWindow.xaml.vb.

Private Async Function ProcessURLAsync(url As String, client As HttpClient) As Task(Of Integer)

    Dim byteArray = Await client.GetByteArrayAsync(url)
    DisplayResults(url, byteArray)
    Return byteArray.Length
End Function

Private Sub DisplayResults(url As String, content As Byte())

    ' Display the length of each website. The string format
    ' is designed to be used with a monospaced font, such as
    ' Lucida Console or Global Monospace.
    Dim bytes = content.Length
    ' Strip off the "https://".
    Dim displayURL = url.Replace("https://", "")
    resultsTextBox.Text &= String.Format(vbCrLf & "{0,-58} {1,8}", displayURL, bytes)
End Sub

Pour finir, définissez la méthode CreateMultipleTasksAsync, qui effectue les étapes suivantes.

La méthode déclare un objet HttpClient, dont vous avez besoin pour accéder à la méthode GetByteArrayAsync dans ProcessURLAsync.
La méthode crée et démarre trois tâches de type Task<TResult>, où TResult est un entier. À mesure que chaque tâche se termine, DisplayResults affiche son URL et la longueur du contenu téléchargé. Les tâches s’exécutant de façon asynchrone, l’ordre d’affichage des résultats peut différer de celui dans lequel les tâches ont été déclarées.
La méthode attend l’achèvement de chaque tâche. Chaque opérateur Await suspend l’exécution de CreateMultipleTasksAsync jusqu’à la fin de la tâche attendue. L’opérateur récupère également la valeur de retour de l’appel à ProcessURLAsync à partir de chaque tâche terminée.
Une fois les tâches terminées et les valeurs entières récupérées, la méthode additionne les longueurs des sites web et affiche le résultat.

Copiez la méthode suivante et collez-la dans votre solution.

Private Async Function CreateMultipleTasksAsync() As Task

    ' Declare an HttpClient object, and increase the buffer size. The
    ' default buffer size is 65,536.
    Dim client As HttpClient =
        New HttpClient() With {.MaxResponseContentBufferSize = 1000000}

    ' Create and start the tasks. As each task finishes, DisplayResults
    ' displays its length.
    Dim download1 As Task(Of Integer) =
        ProcessURLAsync("https://msdn.microsoft.com", client)
    Dim download2 As Task(Of Integer) =
        ProcessURLAsync("https://msdn.microsoft.com/library/hh156528(VS.110).aspx", client)
    Dim download3 As Task(Of Integer) =
        ProcessURLAsync("https://msdn.microsoft.com/library/67w7t67f.aspx", client)

    ' Await each task.
    Dim length1 As Integer = Await download1
    Dim length2 As Integer = Await download2
    Dim length3 As Integer = Await download3

    Dim total As Integer = length1 + length2 + length3

    ' Display the total count for all of the websites.
    resultsTextBox.Text &= String.Format(vbCrLf & vbCrLf &
                                         "Total bytes returned:  {0}" & vbCrLf, total)
End Function

Appuyez sur la touche F5 pour exécuter le programme, puis choisissez le bouton Démarrer.

Exécutez le programme plusieurs fois pour vérifier que les trois tâches ne se terminent pas toujours dans le même ordre, et que l’ordre dans lequel elles se terminent n’est pas nécessairement celui dans lequel elles sont créées et attendues.

Exemple

Le code suivant contient l’exemple complet.

' Add the following Imports statements, and add a reference for System.Net.Http.
Imports System.Net.Http

Class MainWindow

    Async Sub startButton_Click(sender As Object, e As RoutedEventArgs) Handles startButton.Click
        resultsTextBox.Clear()
        Await CreateMultipleTasksAsync()
        resultsTextBox.Text &= vbCrLf & "Control returned to button1_Click."
    End Sub

    Private Async Function CreateMultipleTasksAsync() As Task

        ' Declare an HttpClient object, and increase the buffer size. The
        ' default buffer size is 65,536.
        Dim client As HttpClient =
            New HttpClient() With {.MaxResponseContentBufferSize = 1000000}

        ' Create and start the tasks. As each task finishes, DisplayResults
        ' displays its length.
        Dim download1 As Task(Of Integer) =
            ProcessURLAsync("https://msdn.microsoft.com", client)
        Dim download2 As Task(Of Integer) =
            ProcessURLAsync("https://msdn.microsoft.com/library/hh156528(VS.110).aspx", client)
        Dim download3 As Task(Of Integer) =
            ProcessURLAsync("https://msdn.microsoft.com/library/67w7t67f.aspx", client)

        ' Await each task.
        Dim length1 As Integer = Await download1
        Dim length2 As Integer = Await download2
        Dim length3 As Integer = Await download3

        Dim total As Integer = length1 + length2 + length3

        ' Display the total count for all of the websites.
        resultsTextBox.Text &= String.Format(vbCrLf & vbCrLf &
                                             "Total bytes returned:  {0}" & vbCrLf, total)
    End Function

    Private Async Function ProcessURLAsync(url As String, client As HttpClient) As Task(Of Integer)

        Dim byteArray = Await client.GetByteArrayAsync(url)
        DisplayResults(url, byteArray)
        Return byteArray.Length
    End Function

    Private Sub DisplayResults(url As String, content As Byte())

        ' Display the length of each website. The string format
        ' is designed to be used with a monospaced font, such as
        ' Lucida Console or Global Monospace.
        Dim bytes = content.Length
        ' Strip off the "https://".
        Dim displayURL = url.Replace("https://", "")
        resultsTextBox.Text &= String.Format(vbCrLf & "{0,-58} {1,8}", displayURL, bytes)
    End Sub
End Class

Partager via

Guide pratique : effectuer plusieurs requêtes web en parallèle avec Async et Await (Visual Basic)

Pour configurer le projet

Pour ajouter le code

Exemple

Voir aussi

Ressources supplémentaires