Guide pratique : interroger une arrayList avec LINQ (Visual Basic)
Quand vous utilisez LINQ pour interroger des collections IEnumerable non génériques telles que ArrayList, vous devez déclarer explicitement le type de la variable de portée pour qu’il reflète le type spécifique des objets de la collection. Par exemple, si vous avez une ArrayList d’objets Student, votre clause From doit ressembler à ceci :
Dim query = From student As Student In arrList
'...
En spécifiant le type de la variable de portée, vous effectuez un cast de chaque élément du Student en ArrayList.
L’utilisation d’une variable de portée explicitement typée dans une expression de requête équivaut à appeler la méthode Cast. Cast lève une exception si le cast spécifié ne peut pas être effectué. Cast et OfType sont les deux méthodes d’opérateur de requête standard qui fonctionnent sur les types IEnumerable non génériques. En Visual Basic, vous devez appeler explicitement la méthode Cast sur la source de données pour garantir un type de variable de portée spécifique. Pour plus d’informations, consultez Relations des types dans des opérations de requête (Visual Basic).
Exemple
L’exemple suivant montre une requête simple sur un ArrayList. Notez que cet exemple utilise des initialiseurs d’objets quand le code appelle la méthode Add, mais cela n’est pas une obligation.
Imports System.Collections
Imports System.Linq
Module Module1
Public Class Student
Public Property FirstName As String
Public Property LastName As String
Public Property Scores As Integer()
End Class
Sub Main()
Dim student1 As New Student With {.FirstName = "Svetlana",
.LastName = "Omelchenko",
.Scores = New Integer() {98, 92, 81, 60}}
Dim student2 As New Student With {.FirstName = "Claire",
.LastName = "O'Donnell",
.Scores = New Integer() {75, 84, 91, 39}}
Dim student3 As New Student With {.FirstName = "Cesar",
.LastName = "Garcia",
.Scores = New Integer() {97, 89, 85, 82}}
Dim student4 As New Student With {.FirstName = "Sven",
.LastName = "Mortensen",
.Scores = New Integer() {88, 94, 65, 91}}
Dim arrList As New ArrayList()
arrList.Add(student1)
arrList.Add(student2)
arrList.Add(student3)
arrList.Add(student4)
' Use an explicit type for non-generic collections
Dim query = From student As Student In arrList
Where student.Scores(0) > 95
Select student
For Each student As Student In query
Console.WriteLine(student.LastName & ": " & student.Scores(0))
Next
' Keep the console window open in debug mode.
Console.WriteLine("Press any key to exit.")
Console.ReadKey()
End Sub
End Module
' Output:
' Omelchenko: 98
' Garcia: 97
