Démarrage rapide : Créer une instance d’Azure Database pour MySQL – Serveur flexible à l’aide de Terraform

Ce guide de démarrage rapide a été testé avec les versions de Terraform et de fournisseur Terraform suivantes :

• Terraform v1.2.7
• AzureRM Provider v.3.20.0

Azure Database pour MySQL – Serveur flexible est un service géré qui vous permet d’exécuter, de gérer et de mettre à l’échelle des bases de données MySQL hautement disponibles dans le cloud. Vous pouvez utiliser un modèle Azure Resource Manager (modèle ARM) pour approvisionner Azure Database pour MySQL – Serveur flexible afin de déployer plusieurs serveurs ou plusieurs bases de données sur un serveur.

Cet article explique comment utiliser Terraform pour déployer une instance d’Azure Database pour MySQL – Serveur flexible et une base de données dans un réseau virtuel.

Dans cet article, vous apprendrez comment :

Prérequis

• Si vous n’en avez pas, créez un compte gratuit Azure avant de commencer. Actuellement, avec un compte gratuit Azure, vous pouvez essayer gratuitement Azure Database pour MySQL – Serveur flexible pendant 12 mois. Pour plus d’informations, consultez Utilisez un compte gratuit Azure pour essayer gratuitement le serveur flexible Azure Database pour MySQL.

• Installer et configurer Terraform

Implémenter le code Terraform

1. Créez un répertoire que vous pouvez utiliser pour tester l’exemple de code Terraform. Faites du répertoire Terraform le répertoire actif.

2. Créez un fichier nommé providers.tf et insérez le code suivant :

   terraform {
     required_version = ">=1.0"
   
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
   
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

3. Créez un fichier nommé main.tf et insérez le code suivant :

   # Generate random resource group name
   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   # Generate random value for the name
   resource "random_string" "name" {
     length  = 8
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   # Generate random value for the login password
   resource "random_password" "password" {
     length           = 8
     lower            = true
     min_lower        = 1
     min_numeric      = 1
     min_special      = 1
     min_upper        = 1
     numeric          = true
     override_special = "_"
     special          = true
     upper            = true
   }
   
   # Manages the Virtual Network
   resource "azurerm_virtual_network" "default" {
     address_space       = ["10.0.0.0/16"]
     location            = azurerm_resource_group.rg.location
     name                = "vnet-${random_string.name.result}"
     resource_group_name = azurerm_resource_group.rg.name
   }
   
   # Manages the Subnet
   resource "azurerm_subnet" "default" {
     address_prefixes     = ["10.0.2.0/24"]
     name                 = "subnet-${random_string.name.result}"
     resource_group_name  = azurerm_resource_group.rg.name
     virtual_network_name = azurerm_virtual_network.default.name
     service_endpoints    = ["Microsoft.Storage"]
   
     delegation {
       name = "fs"
   
       service_delegation {
         name = "Microsoft.DBforMySQL/flexibleServers"
         actions = [
           "Microsoft.Network/virtualNetworks/subnets/join/action",
         ]
       }
     }
   }
   
   # Enables you to manage Private DNS zones within Azure DNS
   resource "azurerm_private_dns_zone" "default" {
     name                = "${random_string.name.result}.mysql.database.azure.com"
     resource_group_name = azurerm_resource_group.rg.name
   }
   
   # Enables you to manage Private DNS zone Virtual Network Links
   resource "azurerm_private_dns_zone_virtual_network_link" "default" {
     name                  = "mysqlfsVnetZone${random_string.name.result}.com"
     private_dns_zone_name = azurerm_private_dns_zone.default.name
     resource_group_name   = azurerm_resource_group.rg.name
     virtual_network_id    = azurerm_virtual_network.default.id
   
     depends_on = [azurerm_subnet.default]
   }
   
   # Manages the MySQL Flexible Server
   resource "azurerm_mysql_flexible_server" "default" {
     location                     = azurerm_resource_group.rg.location
     name                         = "mysqlfs-${random_string.name.result}"
     resource_group_name          = azurerm_resource_group.rg.name
     administrator_login          = random_string.name.result
     administrator_password       = random_password.password.result
     backup_retention_days        = 7
     delegated_subnet_id          = azurerm_subnet.default.id
     geo_redundant_backup_enabled = false
     private_dns_zone_id          = azurerm_private_dns_zone.default.id
     sku_name                     = "GP_Standard_D2ds_v4"
     version                      = "8.0.21"
   
     high_availability {
       mode                      = "SameZone"
     }
     maintenance_window {
       day_of_week  = 0
       start_hour   = 8
       start_minute = 0
     }
     storage {
       iops    = 360
       size_gb = 20
     }
   
     depends_on = [azurerm_private_dns_zone_virtual_network_link.default]
   }
   

4. Créez un fichier nommé mysql-fs-db.tf et insérez le code suivant :

   # Manages the MySQL Flexible Server Database
   resource "azurerm_mysql_flexible_database" "main" {
     charset             = "utf8mb4"
     collation           = "utf8mb4_unicode_ci"
     name                = "mysqlfsdb_${random_string.name.result}"
     resource_group_name = azurerm_resource_group.rg.name
     server_name         = azurerm_mysql_flexible_server.default.name
   }
   

5. Créez un fichier nommé variables.tf et insérez le code suivant :

   variable "resource_group_location" {
     type        = string
     default     = "westeurope"
     description = "Location of the resource group."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "mysql-fs-db-rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   

6. Créez un fichier nommé outputs.tf et insérez le code suivant :

   output "azurerm_mysql_flexible_server" {
     value = azurerm_mysql_flexible_server.default.name
   }
   
   output "admin_login" {
     value = azurerm_mysql_flexible_server.default.administrator_login
   }
   
   output "admin_password" {
     sensitive = true
     value     = azurerm_mysql_flexible_server.default.administrator_password
   }
   
   output "mysql_flexible_server_database_name" {
     value = azurerm_mysql_flexible_database.main.name
   }
   
   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   

Initialiser Terraform

Exécutez terraform init pour initialiser le déploiement Terraform. Cette commande télécharge le fournisseur Azure à utiliser pour la gestion de vos ressources Azure.

terraform init -upgrade

Points essentiels :

• Le paramètre -upgrade met à niveau les plug-ins de fournisseur nécessaires vers la version la plus récente qui est conforme aux contraintes de version de la configuration.

Créer un plan d’exécution Terraform

Exécutez terraform plan pour créer un plan d’exécution.

terraform plan -out main.tfplan

Points essentiels :

• La commande terraform plan crée un plan d’exécution, mais ne l’exécute pas. Au lieu de cela, elle détermine les actions nécessaires pour créer la configuration spécifiée dans vos fichiers de configuration. Ce modèle vous permet de vérifier si le plan d’exécution répond à vos attentes avant d’apporter des modifications aux ressources réelles.
• Le paramètre facultatif -out vous permet de spécifier un fichier de sortie pour le plan. L’utilisation du paramètre -out garantit que le plan que vous avez examiné correspond exactement à ce qui est appliqué.

Appliquer un plan d’exécution Terraform

Exécutez terraform apply pour appliquer le plan d’exécution à votre infrastructure cloud.

terraform apply main.tfplan

Points essentiels :

• La commande exemple terraform apply part du principe que vous avez préalablement exécuté terraform plan -out main.tfplan.
• Si vous avez spécifié un autre nom de fichier pour le paramètre -out, utilisez ce même nom dans l’appel à terraform apply.
• Si vous n’avez pas utilisé le paramètre -out, appelez terraform apply sans aucun paramètre.

Vérifier les résultats

az mysql flexible-server db show \
    --resource-group <resource_group_name> \
    --server-name <azurerm_mysql_flexible_server> \
    --database-name <mysql_flexible_server_database_name>

Get-AzMySqlFlexibleServerDatabase `
    -ResourceGroupName <resource_group_name> `
    -ServerName <azurerm_mysql_flexible_server> `
    -Name <mysql_flexible_server_database_name>

Nettoyer les ressources

Quand vous n’avez plus besoin des ressources créées par le biais de Terraform, effectuez les étapes suivantes :

1. Exécutez le plan Terraform et spécifiez l’indicateur destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Points essentiels :

   • La commande terraform plan crée un plan d’exécution, mais ne l’exécute pas. Au lieu de cela, elle détermine les actions nécessaires pour créer la configuration spécifiée dans vos fichiers de configuration. Ce modèle vous permet de vérifier si le plan d’exécution répond à vos attentes avant d’apporter des modifications aux ressources réelles.
   • Le paramètre facultatif -out vous permet de spécifier un fichier de sortie pour le plan. L’utilisation du paramètre -out garantit que le plan que vous avez examiné correspond exactement à ce qui est appliqué.

2. Exécutez terraform apply pour appliquer le plan d’exécution.

   terraform apply main.destroy.tfplan
   

Résoudre les problèmes liés à Terraform sur Azure

Explorez comment résoudre les problèmes courants liés à l’utilisation de Terraform sur Azure.

Étape suivante