Connecter une base de données Azure Cosmos DB à votre application dans Azure Spring Apps

1. Ajoutez l’une des dépendances suivantes dans le fichier pom.xml de votre application. Choisissez la dépendance qui convient à votre type d’API.

   • Type d’API : NoSQL

     <dependency>
         <groupId>com.azure.spring</groupId>
         <artifactId>spring-cloud-azure-starter-data-cosmos</artifactId>
     </dependency>
     

   • Type d’API : MongoDB

     <dependency>
         <groupId>org.springframework.boot</groupId>
         <artifactId>spring-boot-starter-data-mongodb</artifactId>
     </dependency>
     

   • Type d’API : Cassandra

     <dependency>
         <groupId>org.springframework.boot</groupId>
         <artifactId>spring-boot-starter-data-cassandra</artifactId>
     </dependency>
     

2. Mettez à jour l’application actuelle en exécutant az spring app deploy ou créez un déploiement pour ce changement en exécutant az spring app deployment create.

Toutes les chaînes de connexion et informations d’identification sont injectées en tant que variables d’environnement que vous pouvez référencer dans le code de votre application.

Pour connaître les noms des variables d’environnement par défaut, consultez les articles suivants :

• Azure Cosmos DB for Table
• Azure Cosmos DB pour NoSQL
• Azure Cosmos DB for MongoDB
• Azure Cosmos DB pour Gremlin
• Azure Cosmos DB pour Cassandra

Utilisation de l’interface de ligne de commande Microsoft Azure

Utilisez Azure CLI pour configurer votre application Spring afin qu’elle se connecte à une base de données Cosmos NoSQL à l’aide de la commande az spring connection create, comme illustré dans l’exemple suivant. Veillez à remplacer les variables de l’exemple par vos valeurs.

az spring connection create cosmos-sql \
    --resource-group $AZURE_SPRING_APPS_RESOURCE_GROUP \
    --service $AZURE_SPRING_APPS_SERVICE_INSTANCE_NAME \
    --app $APP_NAME \
    --target-resource-group $COSMOSDB_RESOURCE_GROUP \
    --account $COSMOSDB_ACCOUNT_NAME \
    --database $DATABASE_NAME \
    --secret

Utilisation du portail Azure

Vous pouvez également utiliser le portail Azure pour configurer cette connexion en effectuant les étapes suivantes. Le Portail Microsoft Azure fournit les mêmes fonctionnalités qu’Azure CLI, et offre une expérience interactive.

1. Sélectionnez votre instance d’applications Azure Spring Apps dans le Portail Microsoft Azure et sélectionnez Applications dans le menu de navigation. Choisissez l’application que vous souhaitez connecter et sélectionnez Service Connector dans le menu de navigation.

2. Sélectionnez Créer.

3. Sous l’onglet Informations de base, pour type de service, sélectionnez Cosmos DB, puis choisissez un abonnement. Pour Type d’API, sélectionnez Core (SQL), choisissez un compte Cosmos DB et une base de données. Pour type de client, sélectionnez Java, puis Suivant : Authentification. Si vous n’avez pas encore créé votre base de données, consultez Démarrage rapide : Créer un compte, une base de données, un conteneur et des éléments Azure Cosmos DB à partir du Portail Azure.

4. Sous l’onglet Authentification, choisissez Chaîne de connexion. Service Connector récupère automatiquement la clé d’accès à partir de votre compte Cosmos DB. Sélectionnez Suivant : Réseau.

5. Sous l’onglet Réseau, sélectionnez Configurer les règles de pare-feu pour activer l’accès au service cible, puis Vérifier + créer.

6. Sous l’onglet Vérifier + créer, attendez la validation, puis sélectionnez Créer. La création peut prendre quelques minutes.

7. Une fois la connexion entre vos applications Spring et votre base de données Cosmos DB générée, vous pouvez la voir dans la page Connecteur de services et sélectionner le bouton de développement pour afficher les variables de connexion configurées.

Le script Terraform suivant montre comment configurer une application déployée sur Azure Spring Apps avec un compte Azure Cosmos DB.

provider "azurerm" {
  features {}
}

variable "application_name" {
  type        = string
  description = "The name of your application"
  default     = "demo-cosmosdb"
}

resource "azurerm_resource_group" "example" {
  name     = "example-resources"
  location = "West Europe"
}

resource "azurerm_cosmosdb_account" "cosmosdb" {
  name                = "cosmosacct-${var.application_name}-001"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
  offer_type          = "Standard"
  kind                = "GlobalDocumentDB"

  consistency_policy {
    consistency_level = "Session"
  }

  geo_location {
    failover_priority = 0
    location          = azurerm_resource_group.example.location
  }
}

resource "azurerm_cosmosdb_sql_database" "cosmosdb" {
  name                = "cosmos-${var.application_name}-001"
  resource_group_name = azurerm_cosmosdb_account.cosmosdb.resource_group_name
  account_name        = azurerm_cosmosdb_account.cosmosdb.name
}

resource "azurerm_spring_cloud_service" "example" {
  name                = "${var.application_name}"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
}

resource "azurerm_spring_cloud_app" "example" {
  name                = "${var.application_name}-app"
  resource_group_name = azurerm_resource_group.example.name
  service_name        = azurerm_spring_cloud_service.example.name
  is_public           = true
  https_only          = true
}

resource "azurerm_spring_cloud_java_deployment" "example" {
  name                = "default"
  spring_cloud_app_id = azurerm_spring_cloud_app.example.id
  quota {
    cpu    = "2"
    memory = "4Gi"
  }
  instance_count      = 1
  jvm_options         = "-XX:+PrintGC"
  runtime_version     = "Java_11"

  environment_variables = {
    "spring.cloud.azure.cosmos.endpoint" : azurerm_cosmosdb_account.cosmosdb.endpoint
    "spring.cloud.azure.cosmos.key" : azurerm_cosmosdb_account.cosmosdb.primary_key
    "spring.cloud.azure.cosmos.database" : azurerm_cosmosdb_sql_database.cosmosdb.name
  }
}

resource "azurerm_spring_cloud_active_deployment" "example" {
  spring_cloud_app_id = azurerm_spring_cloud_app.example.id
  deployment_name     = azurerm_spring_cloud_java_deployment.example.name
}