Exemples de requêtes Azure Resource Graph pour accéder aux données d’opérations du Gestionnaire de mise à jour Azure

Voici quelques exemples de requêtes pour vous aider à interroger l’évaluation des mises à jour et les informations de déploiement collectées à partir de vos machines gérées. Pour plus d’informations sur les journaux créés à partir d’opérations telles que les évaluations et les installations de mise à jour, consultez Vue d’ensemble des journaux de requête.

Lister les mises à jour disponibles pour toutes vos machines, regroupées par catégorie de mise à jour

La requête suivante retourne une liste de mises à jour en attente pour votre ordinateur avec l’heure à laquelle l’évaluation a été effectuée, l’ID de ressource de l’évaluation, le type de système d’exploitation sur l’ordinateur et les mises à jour du système d’exploitation disponibles en fonction de la classification des mises à jour.

patchassessmentresources
| where type !has "softwarepatches"
| extend prop = parse_json(properties)
| extend lastTime = properties.lastModifiedDateTime
| extend updateRollupCount = prop.availablePatchCountByClassification.updateRollup, featurePackCount = prop.availablePatchCountByClassification.featurePack, servicePackCount = prop.availablePatchCountByClassification.servicePack, definitionCount = prop.availablePatchCountByClassification.definition, securityCount = prop.availablePatchCountByClassification.security, criticalCount = prop.availablePatchCountByClassification.critical, updatesCount = prop.availablePatchCountByClassification.updates, toolsCount = prop.availablePatchCountByClassification.tools, otherCount = prop.availablePatchCountByClassification.other, OS = prop.osType
| project lastTime, id, OS, updateRollupCount, featurePackCount, servicePackCount, definitionCount, securityCount, criticalCount, updatesCount, toolsCount, otherCount

Nombre d’installations de mise à jour

La requête suivante retourne une liste d’installations de mises à jour avec leur état pour vos ordinateurs depuis les sept derniers jours. Les résultats incluent l’heure à laquelle le déploiement de mise à jour a été exécuté, l’ID de ressource de l’installation, les détails de l’ordinateur et le nombre de mises à jour du système d’exploitation installées en fonction de leur état et de votre sélection.

patchinstallationresources
| where type !has "softwarepatches"
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), OS = tostring(prop.osType), installedPatchCount = tostring(prop.installedPatchCount), failedPatchCount = tostring(prop.failedPatchCount), pendingPatchCount = tostring(prop.pendingPatchCount), excludedPatchCount = tostring(prop.excludedPatchCount), notSelectedPatchCount = tostring(prop.notSelectedPatchCount)
| where lTime > ago(7d)
| project lTime, RunID=name,machineName, rgName, resourceType, OS, installedPatchCount, failedPatchCount, pendingPatchCount, excludedPatchCount, notSelectedPatchCount

Liste d’installations de mises à jour du système d’exploitation Windows Server terminées

La requête suivante retourne une liste d’installations de mises à jour pour le serveur Windows avec leur état pour vos ordinateurs depuis les sept derniers jours. Les résultats incluent l’heure à laquelle le déploiement de mise à jour a été exécuté, l’ID de ressource de l’installation, les détails de l’ordinateur et d’autres détails de déploiement associés.

patchinstallationresources
| where type has "softwarepatches" and isnull(properties.version)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), kbId = tostring(prop.kbId), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, kbId, classifications, installationState
| sort by RunID

Liste d’installations de mises à jour du système d’exploitation Linux

La requête suivante retourne une liste d’installations de mises à jour pour Linux avec leur état pour vos ordinateurs depuis les sept derniers jours. Les résultats incluent l’heure à laquelle le déploiement de mise à jour a été exécuté, l’ID de ressource de l’installation, les détails de l’ordinateur et d’autres détails de déploiement associés.

patchinstallationresources
| where type has "softwarepatches" and isnotnull(properties.version) and isnull(properties.kbId)
| extend machineName = tostring(split(id, "/", 8)), resourceType = tostring(split(type, "/", 0)), tostring(rgName = split(id, "/", 4)), tostring(RunID = split(id, "/", 10))
| extend prop = parse_json(properties)
| extend lTime = todatetime(prop.lastModifiedDateTime), patchName = tostring(prop.patchName), version = tostring(prop.version), installationState = tostring(prop.installationState), classifications = tostring(prop.classifications)
| where lTime > ago(7d)
| project lTime, RunID, machineName, rgName, resourceType, patchName, version, classifications, installationState
| sort by RunID

Liste des enregistrements d’exécution de maintenance au niveau de la machine virtuelle

La requête suivante retourne une liste de tous les enregistrements d’exécution de maintenance d’une machine virtuelle

maintenanceresources 
| where ['id'] contains "/subscriptions/<subscription-id>/resourcegroups/<resource-group>/providers/microsoft.compute/virtualmachines/<vm-name>" //VM Id here
| where ['type'] == "microsoft.maintenance/applyupdates" 
| where properties.maintenanceScope == "InGuestPatch"

Étapes suivantes

• Passez en revue les journaux et les résultats de la recherche du Gestionnaire de mise à jour Azure dans Azure à l’aide d’Azure Resource Graph.
• Pour résoudre les problèmes dans le Gestionnaire de mise à jour Azure, consultez Résoudre les problèmes.