Résumé des déclarations

declaration:
 declaration-specifiers attribute-seq_opt¹ init-declarator-list_opt ;
 static_assert-declaration

declaration-specifiers:
 storage-class-specifier declaration-specifiers_opt
 type-specifier declaration-specifiers_opt
 type-qualifier declaration-specifiers_opt
 function-specifier declaration-specifiers_opt
 alignment-specifier declaration-specifiers_opt

attribute-seq¹ :
 attribute¹ attribute-seq_opt¹

attribute^{1, 2} : un des deux
 __asm __based __cdecl __clrcall __fastcall __inline __stdcall __thiscall __vectorcall

init-declarator-list:
 init-declarator
 init-declarator-list , init-declarator

init-declarator:
 declarator
 declarator = initializer

storage-class-specifier:
 auto
 extern
 register
 static
 _Thread_local
 typedef
 __declspec ( extended-decl-modifier-seq )¹

extended-decl-modifier-seq¹ :
 extended-decl-modifier_opt
 extended-decl-modifier-seq extended-decl-modifier

extended-decl-modifier¹ :
 thread
 naked
 dllimport
 dllexport

type-specifier:
 void
 char
 short
 int
 __int8¹
 __int16¹
 __int32¹
 __int64¹
 long
 float
 double
 signed
 unsigned
 _Bool
 _Complex
 atomic-type-specifier
 struct-or-union-specifier
 enum-specifier
 typedef-name

struct-or-union-specifier:
 struct-or-union identifier_opt { struct-declaration-list }
 struct-or-union identifier

struct-or-union:
 struct
 union

struct-declaration-list:
 struct-declaration
 struct-declaration-list struct-declaration

struct-declaration:
 specifier-qualifier-list struct-declarator-list_opt ;
 static_assert-declaration

specifier-qualifier-list:
 type-specifier specifier-qualifier-list_opt
 type-qualifier specifier-qualifier-list_opt
 alignment-specifier specifier-qualifier-list_opt

struct-declarator-list:
 struct-declarator
 struct-declarator-list , struct-declarator

struct-declarator:
 declarator
 declarator_opt : constant-expression

enum-specifier:
 enum identifier_opt { enumerator-list }
 enum identifier_opt { enumerator-list , }
 enum identifier

enumerator-list:
 enumerator
 enumerator-list , enumerator

enumerator:
 enumeration-constant
 enumeration-constant = constant-expression

atomic-type-specifier:
 _Atomic ( type-name )

type-qualifier:
 const
 restrict
 volatile
 _Atomic

function-specifier:
 inline
 _Noreturn

alignment-specifier:
 _Alignas ( type-name )
 _Alignas ( constant-expression )

declarator:
 pointer_opt direct-declarator

direct-declarator:
 identifier
 ( declarator )
 direct-declarator [ type-qualifier-list_opt assignment-expression_opt ]
 direct-declarator [ static type-qualifier-list_opt assignment-expression ]
 direct-declarator [ type-qualifier-list static assignment-expression ]
 direct-declarator [ type-qualifier-list_opt * ]
 direct-declarator ( parameter-type-list )
 direct-declarator ( identifier-list_opt )³

pointer:
 * type-qualifier-list_opt
 * type-qualifier-list_opt pointer

type-qualifier-list:
 type-qualifier
 type-qualifier-list type-qualifier

parameter-type-list:
 parameter-list
 parameter-list , ...

parameter-list:
 parameter-declaration
 parameter-list , parameter-declaration

parameter-declaration:
 declaration-specifiers declarator
 declaration-specifiers abstract-declarator_opt

identifier-list : /* Pour le déclarateur de style ancien */
 identifier
 identifier-list , identifier

type-name:
 specifier-qualifier-list abstract-declarator_opt

abstract-declarator:
 pointer
 pointer_opt direct-abstract-declarator

direct-abstract-declarator:
 ( abstract-declarator )
 direct-abstract-declarator [ type-qualifier-list_opt assignment-expression_opt ]
 direct-abstract-declarator [ static type-qualifier-list_opt assignment-expression ]
 direct-abstract-declarator [ type-qualifier-list static assignment-expression ]
 direct-abstract-declarator [ type-qualifier-list_opt * ]
 direct-abstract-declarator_opt ( parameter-type-list_opt )

typedef-name:
 identifier

initializer:
 assignment-expression
 { initializer-list }
 { initializer-list , }

initializer-list:
 designation_opt initializer
 initializer-list , designation_opt initializer

designation:
 designator-list =

designator-list:
 designator
 designator-list designator

designator:
 [ constant-expression ]
 . identifier

static_assert-declaration:
 _Static_assert ( constant-expression , string-literal ) ;

¹ Cet élément de grammaire est spécifique à Microsoft.
² Pour plus d’informations sur ces éléments, consultez __asm, __clrcall, __stdcall, __based, __fastcall, __thiscall, __cdecl, __inline et __vectorcall.
³ Ce style est obsolète.

Voir aussi

Conventions d’appel
Grammaire de la structure des phrases
Conventions d’appel obsolètes