Guide pratique pour configurer IIS 5.0 et IIS 6.0 pour déployer des applications WPF

Vous pouvez déployer une application Windows Presentation Foundation (WPF) à partir de la plupart des serveurs Web, tant qu’ils sont configurés avec les types MIME (Multipurpose Internet Mail Extensions) appropriés. Par défaut, Microsoft Internet Information Services (IIS) 7.0 est configuré avec ces types MIME, mais les services IIS (Microsoft Internet Information Services) 5.0 et Microsoft Internet Information Services (IIS) 6.0 ne sont pas.

Cette rubrique explique comment configurer Microsoft Internet Information Services (IIS) 5.0 et Microsoft Internet Information Services (IIS) 6.0 pour déployer des applications WPF.

Régler le paramètre d’expiration du contenu

Vous devez régler le paramètre d’expiration du contenu sur 1 minute. La procédure suivante décrit comment procéder avec IIS.

1. Cliquez sur le menu Démarrer, pointez sur Outils d’administration, puis cliquez sur Gestionnaire des services Internet (IIS). Vous pouvez également lancer cette application à partir de la ligne de commande avec « %SystemRoot%\system32\inetsrv\iis.msc ».

2. Développez l’arborescence IIS jusqu’à ce que vous trouviez le nœud de site web par défaut.

3. Cliquez avec le bouton droit sur Site Web par défaut et sélectionnez Propriétés dans le menu contextuel.

4. Sélectionnez l’onglet En-têtes HTTP et cliquez sur « Activer l’expiration de contenu ».

5. Paramétrez le contenu pour qu’il expire après une minute.

Inscrire des types MIME et des extensions de fichiers

Vous devez inscrire plusieurs types MIME et extensions de fichier afin que le navigateur sur le système du client puisse charger le gestionnaire approprié. Vous devez ajouter les types suivants :

L’exemple Microsoft Visual Basic Scripting Edition (VBScript) suivant ajoute automatiquement les types MIME nécessaires à IIS. Pour utiliser le script, copiez le code dans un fichier .vbs sur votre serveur. Ensuite, exécutez le script en exécutant le fichier à partir de la ligne de commande ou en double-cliquant sur le fichier dans l’Explorateur Microsoft Windows.

' This script adds the necessary Windows Presentation Foundation MIME types
' to an IIS Server.
' To use this script, just double-click or execute it from a command line.
' Running this script multiple times results in multiple entries in the IIS MimeMap.

Dim MimeMapObj, MimeMapArray, MimeTypesToAddArray, WshShell, oExec
Const ADS_PROPERTY_UPDATE = 2

' Set the MIME types to be added
MimeTypesToAddArray = Array(".manifest", "application/manifest", ".xaml", _
    "application/xaml+xml", ".application", "application/x-ms-application", _
    ".deploy", "application/octet-stream", ".xbap", "application/x-ms-xbap", _
    ".xps", "application/vnd.ms-xpsdocument")

' Get the MimeMap object
Set MimeMapObj = GetObject("IIS://LocalHost/MimeMap")

' Call AddMimeType for every pair of extension/MIME type
For counter = 0 to UBound(MimeTypesToAddArray) Step 2
    AddMimeType MimeTypesToAddArray(counter), MimeTypesToAddArray(counter+1)
Next

' Create a Shell object
Set WshShell = CreateObject("WScript.Shell")

' Stop and Start the IIS Service
Set oExec = WshShell.Exec("net stop w3svc")
Do While oExec.Status = 0
    WScript.Sleep 100
Loop

Set oExec = WshShell.Exec("net start w3svc")
Do While oExec.Status = 0
    WScript.Sleep 100
Loop

Set oExec = Nothing

' Report status to user
WScript.Echo "Windows Presentation Foundation MIME types have been registered."

' AddMimeType Sub
Sub AddMimeType (Ext, MType)

    ' Get the mappings from the MimeMap property.
    MimeMapArray = MimeMapObj.GetEx("MimeMap")

    ' Add a new mapping.
    i = UBound(MimeMapArray) + 1
    ReDim Preserve MimeMapArray(i)
    Set MimeMapArray(i) = CreateObject("MimeMap")
    MimeMapArray(i).Extension = Ext
    MimeMapArray(i).MimeType = MType
    MimeMapObj.PutEx ADS_PROPERTY_UPDATE, "MimeMap", MimeMapArray
    MimeMapObj.SetInfo

End Sub

Une fois que vous avez exécuté ce script, vous ne voyez peut-être pas d’autres types MIME à partir de Microsoft Internet Information Services (IIS) 5.0 ou Microsoft Internet Information Services (IIS) 6.0 Microsoft Management Console (MMC). Toutefois, ces types MIME ont été ajoutés au métabase Microsoft Internet Information Services (IIS) 5.0 ou Microsoft Internet Information Services (IIS) 6.0. Le script suivant affiche tous les types MIME dans la métabase Microsoft Internet Information Services (IIS) 5.0 ou Microsoft Internet Information Services (IIS) 6.0.

' This script lists the MIME types for an IIS Server.
' To use this script, just double-click or execute it from a command line
' by calling cscript.exe

dim mimeMapEntry, allMimeMaps

' Get the MimeMap object.
Set mimeMapEntry = GetObject("IIS://localhost/MimeMap")
allMimeMaps = mimeMapEntry.GetEx("MimeMap")

' Display the mappings in the table.
For Each mimeMap In allMimeMaps
    WScript.Echo(mimeMap.MimeType & " (" & mimeMap.Extension + ")")
Next

Enregistrez le script en tant que fichier .vbs (par exemple, DiscoverIISMimeTypes.vbs) et exécutez-le à partir de l’invite de commandes à l’aide de la commande suivante :

cscript DiscoverIISMimeTypes.vbs