AnonymousAuthenticationSection Class1

Article
03/16/2024

Configure l'authentification anonyme.

Syntaxe

class AnonymousAuthenticationSection : ConfigurationSection

Méthodes

Le tableau suivant répertorie les méthodes exposées par la classe AnonymousAuthenticationSection.

Nom	Description
GetAllowDefinition	(Hérité de ConfigurationSection.)
GetAllowLocation	(Hérité de `ConfigurationSection`.)
RevertToParent	(Hérité de `ConfigurationSection`.)
SetAllowDefinition	(Hérité de `ConfigurationSection`.)
SetAllowLocation	(Hérité de `ConfigurationSection`.)

Propriétés

Le tableau suivant répertorie les propriétés exposées par la classe AnonymousAuthenticationSection.

Nom	Description
`Enabled`	Une valeur `boolean` en lecture/écriture. `true` si l’authentification anonyme est activée ; sinon, `false`. Par défaut, il s’agit de `true`.
`Location`	(Hérité de `ConfigurationSection`.) Une propriété clé.
`LogonMethod`	Énumération `sint32` en lecture/écriture qui spécifie la méthode pour les connexions. Les valeurs possibles sont répertoriées plus loin dans la section Remarques.
`Password`	Une valeur `string` chiffrée en lecture/écriture qui contient un mot de passe.
`Path`	(Hérité de `ConfigurationSection`.) Une propriété clé.
`UserName`	Valeur `string` en lecture/écriture qui contient un nom d’utilisateur. La valeur par défaut est « IUSR ».
`SectionInformation`	(Hérité de `ConfigurationSection`.)

Sous-classes

Cette classe ne contient aucune sous-classe.

Notes

Le tableau suivant répertorie les valeurs possibles pour la propriété LogonMethod. La valeur par défaut est 3 (ClearText).

Valeur	Mot clé	Description
0	`Interactive`	Ce type de connexion est destiné aux utilisateurs qui utiliseront l’ordinateur de manière interactive.
1	`Batch`	Ce type de connexion est destiné aux serveurs batch, où les processus peuvent s’exécuter pour le compte d’un utilisateur sans leur intervention directe. Les informations d’identification ne sont pas mises en cache pour ce type de connexion.
2	`Network`	Ce type de connexion est destiné aux serveurs hautes performances pour authentifier les mots de passe en texte clair. Les informations d’identification ne sont pas mises en cache pour ce type de connexion.
3	`ClearText`	Ce type de connexions conserve le nom et le mot de passe dans le package d’authentification, ce qui permet au serveur d’établir des connexions à d’autres serveurs réseau lors de l’emprunt d’identité du client.

Exemple

L'exemple suivant affiche les valeurs AnonymousAuthenticationSection par défaut pour le site web par défaut.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = _  
    GetObject("winmgmts:root\WebAdministration")  
  
' Get the Anonymous authentication section for the default  
' Web site.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
oSite.GetSection "AnonymousAuthenticationSection", oAnonAuth  
  
' Display the path and location.  
WScript.Echo "Anonymous Authentication Settings"  
WScript.Echo "---------------------------------"  
WScript.Echo "Path: " & oAnonAuth.Path  
WScript.Echo "Location: " & oAnonAuth.Location  
WScript.Echo   
  
' Display the Enabled, LogonMethod, UserName, and Password  
' properties.  
WScript.Echo "Enabled: " & _  
    "[" & oAnonAuth.Enabled & "]"  
WScript.Echo "LogonMethod: " &  _  
    "[" & GetLogonMethodText(oAnonAuth.LogonMethod) & "]"  
WScript.Echo "UserName: " & "[" & oAnonAuth.UserName & "]"  
WScript.Echo "Password: " & "[" & oAnonAuth.Password & "]"  
  
' Translate the LogonMethod enumeration values to text.  
Function GetLogonMethodText(LogonMethodValue)  
  
    Select Case LogonMethodValue  
        Case 0  
            GetLogonMethodText = "Interactive"  
        Case 1  
            GetLogonMethodText = "Batch"  
        Case 2  
            GetLogonMethodText = "Network"  
        Case 3  
            GetLogonMethodText = "ClearText"  
        Case Else  
            GetLogonMethodText = "Undefined value."  
    End Select  
End Function

Hiérarchie d'héritage

ConfigurationSection

AnonymousAuthenticationSection

Spécifications

Type	Description
Client	- IIS 7.0 sur Windows Vista - IIS 7.5 sur Windows 7 - IIS 8.0 sur Windows 8 - IIS 10.0 sur Windows 10
Serveur	- IIS 7.0 sur Windows Server 2008 - IIS 7.5 sur Windows Server 2008 R2 - IIS 8.0 sur Windows Server 2012 - IIS 8.5 sur Windows Server 2012 R2 - IIS 10.0 sur Windows Server 2016
Produit	- IIS 7.0, IIS 7.5, IIS 8.0, IIS 8.5, IIS 10.0
Fichier MOF	WebAdministration.mof

Voir aussi

Classe AuthenticationSection
Classe BasicAuthenticationSection
Classe ClientCertificateMappingAuthenticationSection
Classe ConfigurationSection
Classe DigestAuthenticationSection
Classe FormsAuthenticationConfiguration
Classe FormsAuthenticationCredentials
Classe FormsAuthenticationUser
Classe IisClientCertificateMappingAuthenticationSection
Classe PassportAuthentication
Classe WindowsAuthenticationSection

Partager via