CentralBinaryLogFile Class1

Article
03/19/2024

Configure les paramètres de journalisation binaire centralisée sur un serveur.

Syntaxe

class CentralBinaryLogFile : EmbeddedObject

Méthodes

Cette classe ne contient pas de méthodes.

Propriétés

Le tableau suivant répertorie les propriétés exposées par la classe CentralBinaryLogFile.

Nom	Description
`Directory`	Valeur de `string` en lecture/écriture qui spécifie le répertoire dans lequel les entrées de journal doivent être écrites. La valeur par défaut est « %SystemDrive%\inetpub\logs\LogFiles ».
`Enabled`	Une valeur de `boolean` en lecture/écriture. `true` si la journalisation binaire centralisée est activée; sinon, `false`. Par défaut, il s’agit de `true`.
`LocalTimeRollover`	Une valeur de `boolean` en lecture/écriture. `true` si un nouveau fichier journal est basé sur l’heure locale; `false` s’il est basé sur le temps universel coordonné (UTC). Par défaut, il s’agit de `false`.
`Period`	Une énumération de `sint32` en lecture/écriture qui spécifie la fréquence à laquelle le fichier journal actuel est fermé et un nouveau fichier journal est démarré. Les valeurs possibles sont répertoriées plus loin dans la section Remarques.
`TruncateSize`	Une valeur de `string` en lecture/écriture qui spécifie, en octets, la taille à laquelle le contenu du fichier journal doit être tronqué. Cet attribut doit être configuré quand `Period` est défini sur `MaxSize`. La taille doit être comprise entre 1048576 (1 mégaoctet) et 4294967295 (4 gigaoctets). La valeur par défaut est 20971520 (20 mégaoctets).

Sous-classes

Cette classe ne contient aucune sous-classe.

Notes

Les instances de cette classe sont contenues dans la propriété CentralBinaryLogFile de la classe LogSection.

Le tableau suivant répertorie les valeurs possibles pour la propriété Period. La valeur par défaut est 1 (Daily).

Valeur	Mot clé	Description
0	`MaxSize`	Le fichier journal est fermé et un nouveau fichier journal est démarré lorsque la valeur dans `TruncateSize` est atteinte.
1	`Daily`	Le fichier journal est fermé et un nouveau fichier journal est démarré une fois par jour.
2	`Weekly`	Le fichier journal est fermé et un nouveau fichier journal est démarré une fois par semaine.
3	`Monthly`	Le fichier journal est fermé et un nouveau fichier journal est démarré une fois par mois.
4	`Hourly`	Le fichier journal est fermé et un nouveau fichier journal est démarré une fois par heure.

Exemple

L’exemple de code suivant définit le mode fichier journal sur CentralBinary, active la journalisation binaire, définit la propriété Period sur Weekly, spécifie que les fichiers journaux utilisent l’heure locale et limite la taille du journal à 1 gigaoctet. Les fonctions d’assistance affichent les paramètres avant et après la modification.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the log configuration section.  
Set oSection = oWebAdmin.Get("LogSection.Path=" & _  
   "'MACHINE/WEBROOT/APPHOST',Location=''")  
  
' Show the initial settings.  
DisplaySettings("Initial Values")  
  
' Set the log file mode to CentralBinary.  
oSection.CentralLogFileMode = 1  
  
' Enable central binary logging.  
oSection.CentralBinaryLogFile.Enabled = True  
  
' Set local time rollover to true.  
oSection.CentralBinaryLogFile.LocalTimeRollover = True  
  
' Set the Period property to Weekly.  
oSection.CentralBinaryLogFile.Period = 2  
  
' Set the log truncate size to 1 gigabyte.  
oSection.CentralBinaryLogFile.TruncateSize = 1073741824  
  
' Save the values to configuration.  
oSection.Put_  
  
' Refresh the oSection object variable with the new values.  
oSection.Refresh_  
  
' Show the changed settings.  
Call DisplaySettings("New Values")  
  
' ==== This section contains helper functions. ====  
Function DisplaySettings(HeadingText)  
   WScript.Echo String(Len(HeadingText), "=")  
   WScript.Echo HeadingText  
   WScript.Echo String(Len(HeadingText), "=")  
  
   ' Display the current central log file mode.  
   WScript.Echo "CentralLogFileMode: " & _  
      oSection.CentralLogFileMode  
  
   ' Display the current binary log file properties.  
   Call ShowPropVals(oSection.CentralBinaryLogFile)  
  
End Function  
  
' Display the property values.  
Function ShowPropVals(oObject)  
  
   For Each Prop In oObject.Properties_  
      WScript.Echo Prop.Name & ": " & Prop.Value  
   Next  
  
   WScript.Echo  
  
End Function

Hiérarchie d'héritage

EmbeddedObject

CentralBinaryLogFile

Spécifications

Type	Description
Client	- IIS 7.0 sur Windows Vista - IIS 7.5 sous Windows 7 - IIS 8.0 sous Windows 8 - IIS 10.0 sous Windows 10
Serveur	- IIS 7.0 sur Windows Server 2008 - IIS 7.5 sur Windows Server 2008 R2 - IIS 8.0 sur Windows Server 2012 - IIS 8.5 sur Windows Server 2012 R2 - IIS 10.0 sous Windows Server 2016
Produit	- IIS 7.0, IIS 7.5, IIS 8.0, IIS 8.5, IIS 10.0
Fichier MOF	WebAdministration.mof

Voir aussi

Classe CentralW3CLogFile
Classe EmbeddedObject
Classe LogSection
Classe SiteLogFile

Partager via