Méthode ConfiguredObject.GetSection

Article
03/20/2024

Récupère le contenu d’une section de configuration pour un objet configuré.

Syntaxe

ConfiguredObject.GetSection(SectionName, Section);

ConfiguredObject.GetSection SectionName, Section

Paramètres

Nom	Description
`SectionName`	Variable `string` qui contient le nom de la section de configuration à récupérer (par exemple, « BasicAuthenticationSection »).
`Section`	Variable ConfigurationSection dans laquelle le contenu de la section de configuration est placé.

Valeur de retour

Cette méthode ne retourne pas de valeur.

Notes

Vous pouvez utiliser la méthode GetSection pour récupérer le contenu d’une section de configuration souhaitée et définir ses propriétés configurables.

Remarque

La signature de la méthode GetSection contient un paramètre [IN] pour le nom de section et un paramètre [OUT] pour l’objet section retourné par la méthode.

Exemple

L’exemple suivant récupère la section erreurs HTTP pour le site internet par défaut et affiche ses propriétés de tableau et de non-tableau.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
' Get the default Web site.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
  
' Get the HTTP errors section by using the GetSection method.  
oSite.GetSection "HttpErrorsSection", oSection  
  
' Display a heading.  
WScript.Echo "=============================="  
WScript.Echo "Http Errors Section Properties"  
WScript.Echo "=============================="  
  
' Display the HttpErrorsSection non-array properties.  
For Each vProp In oSection.Properties_  
    If (vProp.Name <> "HttpErrors") And _  
        (vProp.Name <> "SectionInformation") Then  
        WScript.Echo vProp.Name & ": " & vProp.Value  
    End If  
Next  
WScript.Echo   
  
' Display the HttpErrorsSection SectionInformation properties.  
WScript.Echo "HttpErrorsSection.SectionInformation"  
WScript.Echo "------------------------------------"  
For Each vProp In oSection.SectionInformation.Properties_  
    WScript.Echo vProp.Name & ": " & vProp.Value  
Next  
WScript.Echo  
  
' Display the contents of the HttpErrors array property.  
WScript.Echo "HttpErrorsSection.HttpErrors"  
WScript.Echo "----------------------------"  
For Each oHttpErrorElement In oSection.HttpErrors  
    For Each vProp In oHttpErrorElement.Properties_  
        WScript.Echo vProp.Name & ": " & vProp.Value  
    Next  
    WScript.Echo  
Next

Spécifications

Type	Description
Client	- IIS 7.0 sous Windows Vista - IIS 7.5 sous Windows 7 - IIS 8.0 sous Windows 8 - IIS 10.0 sous Windows 10
Serveur	- IIS 7.0 sous Windows Server 2008 - IIS 7.5 sous Windows Server 2008 R2 - IIS 8.0 sous Windows Server 2012 - IIS 8.5 sous Windows Server 2012 R2 - IIS 10.0 sous Windows Server 2016
Produit	- IIS 7.0, IIS 7.5, IIS 8.0, IIS 8.5, IIS 10.0
Fichier MOF	WebAdministration.mof

Voir aussi

Classe ConfigurationSection
Classe ConfiguredObject
Classe HttpErrorElement
Classe HttpErrorsSection

Partager via