Classe HandlersSection

Stocke les gestionnaires d'une URL.

Syntaxe

class HandlersSection : ConfigurationSectionWithCollection  

Méthodes

Le tableau suivant répertorie les méthodes exposées par la classe HandlersSection.

Propriétés

Le tableau suivant répertorie les propriétés exposées par la classe HandlersSection.

Sous-classes

Cette classe ne contient aucune sous-classe.

Notes

Cette classe correspond à la section <handlers> du fichier ApplicationHost.config.

Le tableau suivant répertorie les valeurs possibles pour la propriété AccessPolicy. La valeur par défaut est 1 (Read).

Exemple

Les exemples suivants ajoutent et suppriment un gestionnaire de la section <handlers>.

' ----------------------------------------------------------  
' The first example adds a handler to the <handlers> section.  
' ----------------------------------------------------------  
' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the <handlers> section.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
oSite.GetSection "HandlersSection", oHandlersSection  
  
' Display the old handler names.  
WScript.Echo "---[Old Handler List]---"  
Call DisplayHandlers  
  
' Create a new handler.  
Set oHandler = oWebAdmin.Get("HandlerAction").SpawnInstance_  
oHandler.Name = "NewHandler"   
oHandler.Path="*.stm"   
oHandler.Verb="GET,POST"   
oHandler.Modules="ServerSideIncludeModule"   
  
' Add the handler to the <handlers> section.  
oHandlersSection.Add "Handlers", oHandler  
  
' Call the WMI Refresh_ method to update the oHandlersSection object.  
oHandlersSection.Refresh_  
  
' Display the new handler names.   
WScript.Echo "---[New Handler List]---"  
Call DisplayHandlers  
  
' ----------------------------------------------------------------  
' The second example removes a handler by using the handler name.  
' ----------------------------------------------------------------  
' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the <handlers> section.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
oSite.GetSection "HandlersSection", oHandlersSection  
  
' Display the old handler names.  
WScript.Echo "---[Old Handler List]---"  
Call DisplayHandlers  
  
' Remove the CGI-exe handler by name.  
For Each oHandler In oHandlersSection.Handlers  
     If oHandler.Name = "CGI-exe" Then  
        oHandlersSection.Remove "Handlers", oHandler  
    End If   
Next  
  
' Call the WMI Refresh_ method to update the oHandlersSection object.  
oHandlersSection.Refresh_  
  
' Display the new list of handler names.   
WScript.Echo "---[New Handler List]---"  
Call DisplayHandlers  
  
' This is the sub that displays the handler names.  
Sub DisplayHandlers  
    WScript.Echo   
    For Each oHandler In oHandlersSection.Handlers  
        WScript.Echo "Handler Name: " & oHandler.Name  
    Next  
End Sub  
  

Hiérarchie d'héritage

ConfigurationSection

ConfigurationSectionWithCollection

HandlersSection

Spécifications

Voir aussi

Classe ConfigurationSectionWithCollection
Classe HandlerAction