Classe HttpRedirectSection

Configure la redirection HTTP.

Syntaxe

class HttpRedirectSection : ConfigurationSectionWithCollection  

Méthodes

Le tableau suivant répertorie les méthodes exposées par la classe HttpRedirectSection.

Propriétés

Le tableau suivant répertorie les propriétés exposées par la classe HttpRedirectSection.

Sous-classes

Cette classe ne contient aucune sous-classe.

Notes

Le tableau suivant répertorie les valeurs possibles pour la propriété HttpResponseStatus. La valeur par défaut est 302 (Found).

Exemple

Le premier exemple affiche toutes les propriétés de la classe HttpRedirectSection, y compris les propriétés incorporées SectionInformation et HttpRedirect.

Le deuxième exemple crée quatre éléments de redirection à caractère générique et tente de les ajouter à la section du site web par défaut <httpRedirect>. S'il existe des doublons, le code le signale ; dans le cas contraire, il ajoute des entrées. Enfin, il affiche le nouveau nombre de toutes les entrées et le caractère générique et la destination pour chacun d'eux.

' 1) First example: Display the httpRedirect properties  
' for the default Web site.  
' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = _  
    GetObject("winmgmts:root\WebAdministration")  
  
' Get the httpRedirect section for the default Web site.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
oSite.GetSection "HttpRedirectSection", oSection  
  
' Display the nonembedded properties.  
WScript.Echo "=============================="  
WScript.Echo "HttpRedirectSection Properties"  
WScript.Echo "=============================="  
For Each vProp In oSection.Properties_  
    If (vProp.Name <> "HttpRedirect") And _  
    (vProp.Name <> "SectionInformation") Then  
        WScript.Echo vProp.Name & ": " & vProp.Value  
    End If  
Next  
  
' Display the contents of the SectionInformation property.  
WScript.Echo   
WScript.Echo "--------------------------------------"  
WScript.Echo "HttpRedirectSection.SectionInformation"  
WScript.Echo "--------------------------------------"  
For Each vProp In oSection.SectionInformation.Properties_  
    WScript.Echo vProp.Name & ": " & vProp.Value  
Next  
WScript.Echo   
  
' Display the WildcardRedirectElement instances in the  
' HttpRedirect array property.  
WScript.Echo "--------------------------------"  
WScript.Echo "HttpRedirectSection.HttpRedirect"  
WScript.Echo "--------------------------------"  
For Each oWildcardRedirectElement In oSection.HttpRedirect  
    For Each vProp In oWildcardRedirectElement.Properties_  
        WScript.Echo vProp.Name & ": " & vProp.Value  
    Next  
    WScript.Echo  
Next  
  
' 2) Second example: Add four WildcardRedirectElement  
' instances to the default Web site and display the result.  
' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = _  
    GetObject("winmgmts:root\WebAdministration")  
  
' Get the httpRedirect section for the default Web site.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
oSite.GetSection "HttpRedirectSection", oSection  
  
' Set up a loop to add four new redirects.  
For Counter = 1 To 4  
    ' Create a new instance of WildcardRedirectElement.  
    ' Note that you do not need to use SpawnInstance_.  
    Set oWildcardRedirect = _  
        oWebAdmin.Get("WildcardRedirectElement")  
  
    ' Specify the page to be redirected.  
    oWildcardRedirect.Wildcard = _  
        "Adatum.com/Page" & Counter & ".htm"  
  
    ' Specify the destination for the redirected page.  
    oWildcardRedirect.Destination = _  
        "Contoso.com/Page" & Counter & ".htm"  
  
    ' Prepare to catch duplicate entries.  
    On Error Resume Next  
  
    ' Attempt to add the wildcard entry to the collection.   
    ' (You do not need to use Put_ to save the change.)  
    oSection.Add "HttpRedirect", oWildcardRedirect  
  
    ' Catch duplicate entries.  
    If Err.Number = -2147024713 Then  
        WScript.Echo "Redirect entry for """ & _  
        oWildcardRedirect.Wildcard & """ already exists."  
        WScript.Echo  
    End If  
Next  
  
' Update the contents of the oSection variable.  
oSection.Refresh_  
  
' Display a header and the new number of entries.  
WScript.Echo "--------------------------------"  
WScript.Echo "HttpRedirectSection.HttpRedirect"  
WScript.Echo "--------------------------------"  
WScript.Echo "The number of redirect entries is now " & _  
    UBound(oSection.HttpRedirect) + 1 & "."  
WScript.Echo   
  
' Display the new set of wildcard redirect elements.  
For Each oWildcardRedirectElement In oSection.HttpRedirect  
    WScript.Echo "Wildcard: " & _  
        oWildcardRedirectElement.Wildcard & vbTab & _  
        "Destination: " & _  
        oWildcardRedirectElement.Destination  
    WScript.Echo  
Next  
  

Hiérarchie d'héritage

ConfigurationSection

ConfigurationSectionWithCollection

HttpRedirectSection

Spécifications

Voir aussi

Classe ConfigurationSectionWithCollection
Classe SectionInformation
Classe WildcardRedirectElement