Classe TraceFailedRequestsSection

Représente une section de configuration de suivi des requêtes ayant échoué.

Syntaxe

class TraceFailedRequestsSection : ConfigurationSectionWithCollection  

Méthodes

Le tableau suivant répertorie les méthodes exposées par la classe TraceFailedRequestsSection.

Propriétés

Le tableau suivant répertorie les propriétés exposées par la classe TraceFailedRequestsSection.

Sous-classes

Cette classe ne contient aucune sous-classe.

Notes

Cette classe correspond à la section <traceFailedRequests> dans ApplicationHost.config.

Exemple

L’exemple suivant répertorie les propriétés Location, Path et TraceFailedRequest du site Web par défaut.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the default Web site.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
  
' Place the TraceFailedRequestsSection object into a variable by  
' using the GetSection method on the Site object.  
oSite.GetSection "TraceFailedRequestsSection", oTFRSection  
  
' Echo the path and location information.  
WScript.Echo "Path: " & oTFRSection.Path  
WScript.Echo "Location: " & oTFRSection.Location  
WScript.Echo vbCRLF  
  
' Retrieve and display the values for the TraceFailedRequests property.  
For Each oTFR In oTFRSection.TraceFailedRequests  
    WScript.Echo "Trace URL path: " & oTFR.Path  
    WScript.Echo String(16 + Len(oTFR.Path), "=")  
  
    Set oFD = oTFR.FailureDefinitions  
    WScript.Echo "Failure Definition Status Codes: " & oFD.StatusCodes  
    WScript.Echo "Failure Definition TimeTaken: " & oFD.TimeTaken  
    WScript.Echo "Failure Definition Verbosity Level: " & _  
            GetVerbosityText(oFD.Verbosity)  
    WScript.Echo   
  
    For Each oTA In oTFR.TraceAreas.TraceAreas  
        WScript.Echo "Trace Provider: " & oTA.Provider  
        WScript.Echo "Trace Verbosity Level: " & _  
            GetVerbosityText(oTA.Verbosity)  
        If Not (oTA.Provider = "ASP" Or _  
                oTA.Provider = "ISAPI Extension") Then  
            WScript.Echo "Trace Areas: " & oTA.Areas  
        End If  
        WScript.Echo   
    Next  
    WScript.Echo  
Next  
  
' Provide text for the verbosity enumeration values.  
Function GetVerbosityText(sint32Value)  
    Select Case sint32Value  
        Case 0  
            GetVerbosityText="General"  
        Case 1  
            GetVerbosityText="Critical Error"  
        Case 2  
            GetVerbosityText="Error"  
        Case 3  
            GetVerbosityText="Warning"  
        Case 4  
            GetVerbosityText="Information"  
        Case 5  
            GetVerbosityText="Verbose"  
        Case Else  
            GetVerbosityText ="Undefined Verbosity Level"  
    End Select  
End Function  
  

Hiérarchie d'héritage

ConfigurationSection

ConfigurationSectionWithCollection

TraceFailedRequestsSection

Spécifications

Voir aussi

Classe ConfigurationSectionWithCollection
Classe HttpTracingSection
Classe TraceAreaElement
Classe TraceAreaDefinition
Classe TraceProviderDefinition
Classe TraceProviderDefinitionsSection
Classe TraceUrl
Classe TraceUrlAreaSettings
Créer une règle de suivi pour les requêtes ayant échoué