WorkerProcess.GetState Method2

Retourne l’état d’exécution d’un processus worker.

Syntaxe

oWorkerProcess.GetState  

var workerProcessState = objWorkerProcess.GetState();  

Paramètres

Cette méthode ne prend aucun paramètre.

Valeur de retour

Qui uint32 identifie l’état du pool d’applications. Les valeurs de retour sont indiquées dans le tableau suivant.

Notes

Cette méthode est nouvelle pour le fournisseur WMI IIS 7 et n’a pas d’équivalent dans IIS 6.0.

Exemple

L’exemple suivant retourne l’état de chaque processus de travail dans chaque pool d’applications sur un serveur.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Return all application pools that are present on the server.  
Set colAppPools = oWebAdmin.ExecQuery("SELECT * FROM ApplicationPool")  
  
' Return each application pool name.  
For Each oAppPool In colAppPools  
    WScript.Echo oAppPool.Name  
    WScript.Echo String(Len(oAppPool.Name), "-")  
  
    ' Get all worker processes in the application pool.  
    Set oWorkerProcesses = _  
        oAppPool.Associators_("ApplicationPoolContainsProcess")  
  
    ' Return each worker process ID and report its state by using  
    ' the GetStateDescription helper function.  
    For Each oWorkerProcess In oWorkerProcesses  
        WScript.Echo "Process ID " & oWorkerProcess.ID & _  
            " is " & GetStateDescription(oWorkerProcess.GetState) & "."  
    Next  
    WScript.Echo  
Next  
  
' Return the text string that corresponds to the state code.  
Function GetStateDescription(StateCode)  
    Select Case StateCode  
        Case 0  
            GetStateDescription = "starting"  
        Case 1  
            GetStateDescription = "running"  
        Case 2  
            GetStateDescription = "stopping"  
        Case 3  
            GetStateDescription = "unknown"  
        Case Else  
            GetStateDescription = _  
                "Attempt to retrieve worker process state failed."  
    End Select  
End Function  

Étant donné que WorkerProcess est un objet temporaire, l’état signalé par WMI lorsque le script est exécuté peut ne plus être valide après un certain temps.

Spécifications

Voir aussi

Classe ApplicationPool
Classe ApplicationPoolContainsProcess
Classe WorkerProcess