La Classe2 du WorkerProcessContainsAppDomain

Fournit une relation entre un processus de travail et ses domaines d'application.

Syntaxe

class WorkerProcessContainsAppDomain : ObjectContainerAssociation  

Méthodes

Cette classe ne contient pas de méthodes.

Propriétés

Le tableau suivant répertorie les propriétés exposées par la classe WorkerProcessContainsAppDomain.

Sous-classes

Cette classe ne contient aucune sous-classe.

Notes

Cette classe d’association est utile pour récupérer tous les domaines d’application chargés pour chaque processus de travail sur un serveur Web.

Exemple

L’exemple suivant affiche les domaines d’application chargés sur un serveur Web. La première partie utilise une requête WMI. La deuxième partie utilise la classe d’association WorkerProcessContainsAppDomain.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get application domains on the server by using a WMI query.  
Set AppDomains = oWebAdmin.ExecQuery ("Select * from AppDomain")  
  
WScript.Echo "AppDomain Count: " & AppDomains.Count  
WScript.Echo  
For Each AppDomain In AppDomains  
    WScript.Echo "AppDomain site name: " + AppDomain.SiteName  
    WScript.Echo "AppDomain process ID: " & AppDomain.ProcessID  
    WScript.Echo "AppDomain ID: " + AppDomain.Id  
    WScript.Echo "AppDomain application path: " & _  
        AppDomain.ApplicationPath  
    WScript.Echo       
Next  
  
WScript.Echo  
  
' Get the application domains for each worker process by using  
' the WorkerProcessContainsAppDomain association.  
Set oWorkerProcesses = oWebAdmin.InstancesOf("WorkerProcess")  
  
For Each oWorkerProcess In oWorkerProcesses  
    WScript.Echo "Worker Process Process ID: " & oWorkerProcess.ProcessID  
    Set oAppDomains = _  
    oWorkerProcess.Associators_("WorkerProcessContainsAppDomain")  
  
    WScript.Echo "AppDomainCount: " & oAppDomains.Count  
    WScript.Echo  
    WScript.Echo "List of AppDomains"  
    WScript.Echo "------------------"  
    For Each oAppDomain In oAppDomains  
        WScript.Echo "Application domain process ID: " & _  
            oAppDomain.ProcessId  
        WScript.Echo "Application domain application path:" & _  
            oAppDomain.ApplicationPath  
        WScript.Echo " Application domain physical path: " & _  
            oAppDomain.PhysicalPath  
        WScript.Echo  
    Next   
Next  

Remarque : la syntaxe suivante de l’exemple de code précédent.

Set oAppDomains = _

oWorkerProcess.Associators_("WorkerProcessContainsAppDomain")

Pour simplifier votre code, vous pouvez utiliser plutôt la syntaxe suivante, qui vous permet d’utiliser l’association sans avoir à mémoriser son nom exact.

Set oAppDomains = oWorkerProcess.Associators_(, "AppDomain")

Hiérarchie d'héritage

ObjectContainerAssociation

WorkerProcessContainsAppDomain

Spécifications

Voir aussi

Classe AppDomain
ObjectContainerAssociation Class
Classe WorkerProcess