Guide pratique pour créer un package à l’aide d’un modèle de fichier de définition de package

L’exemple suivant montre comment créer un package et un programme à l’aide d’un modèle de fichier de définition de package dans Configuration Manager. Le modèle de fichier de définition de package contient les valeurs par défaut utilisées pour créer SMS_Package des objets et SMS_Program . L’exemple suivant utilise la SMS_PDF_Package classe et la GetPDFData méthode pour charger les informations du modèle de fichier de définition de package et créer un package et les programmes associés.

Pour créer un package à l’aide d’un modèle de fichier de définition de package

1. Configurez une connexion au fournisseur SMS.

2. Créez le nouvel objet package à l’aide de la SMS_PDF_Package classe .

3. Renseignez toutes les propriétés de package supplémentaires.

4. Chargez les informations du programme et associez chaque programme au package.

Exemple

L’exemple de méthode suivant crée un package à l’aide d’un fichier de définition de package.

Pour plus d’informations sur l’appel de l’exemple de code, consultez Appel d’extraits de code Configuration Manager.

Sub SWDCreatePDFPackage(connection, existingPDF_ID, newPackageSourceFlag, newPackageSourcePath)  
    ' The PDF_ID must be passed in.  
    ' The PDF_ID can be identified through the SMS_PDF_Package class.  

    Dim newPDFPackage  
    Dim returnCode  
    Dim newPackage  
    Dim newPackagePath  
    Dim packageID  
    Dim program  
    Dim arrayOfPrograms  

    ' Package Creation  
    ' ----------------       
    ' Create new SMS_PDF_Package instance.  
    Set newPDFPackage = connection.Get("SMS_PDF_Package")  

    ' Load the Package Definition File data using the GetPDFData method.  
    returnCode = newPDFPackage.GetPDFData(existingPDF_ID, newPackage, arrayOfPrograms)  

    ' Assign any additional package properties.  
    newPackage.PkgSourceFlag = newPackageSourceFlag  
    newPackage.PkgSourcePath = newPackageSourcePath  

    ' Save the package path and get the Package ID.  
    Set newPackagePath = newPackage.Put_  
    packageID = newPackagePath.Keys("PackageID")  

    ' Program Creation   
    ' -----------------      
    ' Enumerate through the program array and create the programs.  
    For Each program In arrayOfPrograms  
        program.PackageID = packageID  
        program.Put_  
    Next  

End Sub  

L’exemple de méthode a les paramètres suivants :

Programmation robuste

Pour plus d’informations sur la gestion des erreurs, consultez À propos des erreurs Configuration Manager.

Voir aussi

Vue d’ensemble de la distribution de logicielsSMS_SCI_Component classe WMI server