Utilisation de tableaux

Article
04/07/2023

Vous pouvez déclarer un tableau pour manipuler un ensemble de valeurs du même type de données. Un tableau est une variable unique disposant de nombreux compartiments pour conserver des valeurs, alors qu’une variable ordinaire dispose d’un seul compartiment de stockage dans lequel elle peut stocker une seule valeur. Faites référence au tableau dans son ensemble pour faire référence à toutes les valeurs qu’il contient ; vous pouvez également faire référence à ses éléments individuels.

Par exemple, pour stocker des frais journaliers pour chaque jour de l’année, vous pouvez déclarer une variable tableau de 365 éléments au lieu de déclarer 365 variables. Chaque élément d’un tableau contient une seule valeur. L’instruction suivante déclare la variable de tableau avec 365 éléments. Par défaut, un tableau est indexé en commençant par zéro, donc la limite supérieure du tableau est 364 au lieu de 365.

Dim curExpense(364) As Currency

Pour définir la valeur d’un élément individuel, vous spécifiez l’index de l’élément. L’exemple suivant affecte une valeur initiale de 20 à chaque élément du tableau.

Sub FillArray() 
    Dim curExpense(364) As Currency 
    Dim intI As Integer 
    For intI = 0 to 364 
        curExpense(intI) = 20 
    Next 
End Sub

Modification de la limite inférieure

Utilisez l’instruction Option Base en haut d’un module pour modifier l’index par défaut du premier élément de 0 à 1. Dans l’exemple suivant, l’instruction Option Base modifie l’index du premier élément, et l’instruction Dim déclare la variable de tableau avec 365 éléments.

Option Base 1 
Dim curExpense(365) As Currency

Vous pouvez définir explicitement la limite inférieure d’un tableau en utilisant la clause To, comme illustré dans l’exemple suivant.

Dim curExpense(1 To 365) As Currency 
Dim strWeekday(7 To 13) As String

Stockage de valeurs variant dans des tableaux

Il existe deux façons de créer des tableaux de valeurs Variant . L’une consiste à déclarer un tableau de type de données Variant, comme illustré dans l’exemple suivant :

Dim varData(3) As Variant 
varData(0) = "Claudia Bendel" 
varData(1) = "4242 Maple Blvd" 
varData(2) = 38 
varData(3) = Format("06-09-1952", "General Date")

L’autre méthode consiste à affecter le tableau renvoyé par la fonction Array à une variable Variant, comme illustré dans l’exemple suivant.

Dim varData As Variant 
varData = Array("Ron Bendel", "4242 Maple Blvd", 38, _ 
Format("06-09-1952", "General Date"))

Vous identifiez les éléments d’un tableau de valeurs Variant par leur index, quelle que soit la technique employée pour créer le tableau. Par exemple, l’instruction suivante peut être ajoutée à l’un ou l’autre des exemples précédents.

MsgBox "Data for " & varData(0) & " has been recorded."

Utilisation de tableaux multidimensionnels

Dans Visual Basic, vous pouvez déclarer des tableaux comprenant jusqu’à 60 dimensions. Par exemple, l’instruction suivante déclare un tableau bidimensionnel de 5 par 10

Dim sngMulti(1 To 5, 1 To 10) As Single

Si vous considérez le tableau comme une matrice, le premier argument représente les lignes et le deuxième les colonnes.

Utiliser imbriqué pour... Instructions suivantes pour traiter les tableaux multidimensionnels. La procédure suivante remplit un tableau à deux dimensions de valeurs Single.

Sub FillArrayMulti() 
    Dim intI As Integer, intJ As Integer 
    Dim sngMulti(1 To 5, 1 To 10) As Single 
 
    ' Fill array with values. 
    For intI = 1 To 5 
        For intJ = 1 To 10 
            sngMulti(intI, intJ) = intI * intJ 
            Debug.Print sngMulti(intI, intJ) 
        Next intJ 
    Next intI 
End Sub

Voir aussi

Rubriques conceptuelles de Visual Basic

Assistance et commentaires

Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.

Partager via