Méthode Module.DeleteLines (Access)

La méthode DeleteLines supprime les lignes d'un module standard ou un module de classe.

Syntaxe

expression. DeleteLines (StartLine, Count)

Expression Variable qui représente un objet Module .

Parameters

Valeur renvoyée

Aucune

Remarques

Les lignes dans un module sont numérotées en commençant par 1. Pour déterminer le nombre de lignes dans un module, utilisez la propriété CountOfLines.

Pour remplacer une ligne par une autre ligne, utilisez la méthode ReplaceLine.

Exemple

L'exemple suivant supprime une ligne spécifique d'un module.

Function DeleteWholeLine(strModuleName, strText As String) _ 
 As Boolean 
 Dim mdl As Module, lngNumLines As Long 
 Dim lngSLine As Long, lngSCol As Long 
 Dim lngELine As Long, lngECol As Long 
 Dim strTemp As String 
 
 On Error GoTo Error_DeleteWholeLine 
 DoCmd.OpenModule strModuleName 
 Set mdl = Modules(strModuleName) 
 
 If mdl.Find(strText, lngSLine, lngSCol, lngELine, lngECol) Then 
 lngNumLines = Abs(lngELine - lngSLine) + 1 
 strTemp = LTrim$(mdl.Lines(lngSLine, lngNumLines)) 
 strTemp = RTrim$(strTemp) 
 If strTemp = strText Then 
 mdl.DeleteLines lngSLine, lngNumLines 
 Else 
 MsgBox "Line contains text in addition to '" _ 
 & strText & "'." 
 End If 
 Else 
 MsgBox "Text '" & strText & "' not found." 
 End If 
 DeleteWholeLine = True 
 
Exit_DeleteWholeLine: 
 Exit Function 
 
Error_DeleteWholeLine: 
 MsgBox Err & " :" & Err.Description 
 DeleteWholeLine = False 
 Resume Exit_DeleteWholeLine 
End Function

Vous pouvez appeler cette fonction à partir d'une procédure semblable à la suivante, qui recherche une constante de déclaration dans le module Module1 et qui l'y supprime.

Sub DeletePiConst() 
 If DeleteWholeLine("Module1", "Const conPi = 3.14") Then 
 Debug.Print "Constant declaration deleted successfully." 
 Else 
 Debug.Print "Constant declaration not deleted." 
 End If 
End Sub

Voir aussi

• Méthode DeleteLines (modèle objet VBA Add-In)

Assistance et commentaires

Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.