Propriété Application.TemplatePaths (Visio)

Article
04/07/2023

Obtient ou définit les chemins d’accès dans lesquels Microsoft Visio recherche des modèles. Lecture-écriture.

Syntaxe

expression. TemplatePaths

expressionUne variable qui représente un objetApplication.

Valeur renvoyée

String

Remarques

La propriété TemplatePaths est définie sur une chaîne vide ("") par défaut.

La chaîne transmise à la propriété TemplatePaths et envoyée par celle-ci est identique à la chaîne figurant dans la boîte de dialogue Emplacements des fichiers. (Cliquez sur l’onglet Fichier , sur Options, sur Avancé, puis, sous Général, cliquez sur Emplacements des fichiers.) Cette chaîne est stockée dans la sous-cléHKEY_CURRENT_USER\Software\Microsoft\Office\14.0\Visio\Application\TemplatePath .

Lorsque Visio recherche les modèles, il consulte tous les chemins indiqués dans la propriété TemplatePaths et tous les sous-dossiers de ces chemins. Si vous transmettez la propriété TemplatePaths à la méthode EnumDirectories, la liste de tous les chemins d’accès complets des dossiers transmis est renvoyée.

La définition de la propriété TemplatePaths remplace les valeurs existantes des modèles dans la boîte de dialogue Emplacements des fichiers. Pour conserver les valeurs existantes, récupérez la chaîne existante, puis ajoutez le nouveau chemin d’accès à cette chaîne, comme indiqué par le code suivant :

Application.TemplatePaths = Application.TemplatePaths & ";" & "newpath".

Avertissement

La modification du Registre Windows de quelque manière que ce soit, que ce soit dans l’Éditeur du Registre ou par programme, comporte toujours un certain degré de risque. Une modification incorrecte peut entraîner de graves problèmes, pouvant nécessiter la réinstallation du système d’exploitation. Nous vous recommandons de toujours sauvegarder le registre d’un ordinateur avant de le modifier.

Exemple

Cette macro Microsoft Visual Basic pour Applications (VBA) indique comment utiliser la propriété TemplatePaths pour ajouter un chemin d’accès à la zone de chemins d’accès Modèles.

 
Public Sub TemplatePaths_Example()  
 
    Dim strMessage As String 
    Dim strNewPath As String 
    Dim strTemplatePath As String 
    Dim strTitle As String 
     
    'Get the path we want to add.  
    strTemplatePath = Application.TemplatePaths  
    strTitle = "TemplatePaths"  
    strMessage = "The current content of the Visio Templates path box is:"  
    strMessage = strMessage & vbCrLf & strTemplatePath  
    MsgBox strMessage, vbInformation + vbOKOnly, strTitle  
    strMessage = "Type in an additional path for Visio to look for templates."  
    strNewPath = InputBox$(strMessage, strTitle)  
 
    'Make sure the folder exists and that it's not 
    'already in the Templates path box.  
    strMessage = ""  
    If strNewPath = ""  Then 
        strMessage = "You did not enter a path." 
        ElseIf InStr(strTemplatePath, strNewPath)  Then 
            strMessage = "The path you specified is already in the Templates path box."  
        ElseIf Len(Dir$(strNewPath, vbDirectory)) = 0 And _  
                Len(Dir$(Application.Path & strNewPath, _  
                vbDirectory)) = 0 Then 
            strMessage = "The folder you typed does not exist (or is blank)."  
        Else 
            Application.TemplatePaths = strTemplatePath & ";" & strNewPath  
            strMessage = "We just added " & strNewPath & _  
                " to the Templates path box."  
    End If 
   
    If strMessage <> ""  Then 
        MsgBox strMessage, vbExclamation + vbOKOnly, strTitle  
    End If  
  
End Sub

Assistance et commentaires

Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.

Partager via