Objet StoryRanges (Word)

Une collection de plage objets qui représentent les articles d'un document.

Remarques

Utilisez la propriété StoryRanges pour renvoyer la collection StoryRanges. L'exemple suivant supprime le caractère manuelle de la mise en forme du texte de tous les articles autres que l'article principal du document actif.

For Each aStory In ActiveDocument.StoryRanges 
 If aStory.StoryType <> wdMainTextStory Then aStory.Font.Reset 
Next aStory

La méthode Add n'est pas disponible pour la collection StoryRanges. Le nombre d'articles de la collection StoryRanges est fini.

Utilisez StoryRanges (Index), où Index est une constante WdStoryType , pour renvoyer un seul article en tant qu’objet Range . L'exemple suivant ajoute du texte à l'article en-tête principal et affiche ensuite le texte.

ActiveDocument.Sections(1).Headers(wdHeaderFooterPrimary).Range _ 
 .Text = "Header text" 
MsgBox ActiveDocument.StoryRanges(wdPrimaryHeaderStory).Text

Cet exemple montre comment copier le texte des pieds de page du document actif vers un nouveau document.

If ActiveDocument.Footnotes.Count >= 1 Then 
 ActiveDocument.StoryRanges(wdFootnotesStory).Copy 
 Documents.Add.Content.Paste 
End If

Si vous essayez de renvoyer un article qui n'est pas disponible dans le document spécifié, une erreur se produit. L'exemple suivant montre comment déterminer si un article de note de bas de page est disponible dans le document actif.

On Error GoTo errhandler 
Set MyRange = ActiveDocument.StoryRanges(wdFootnotesStory) 
errhandler: 
If Err = 5941 Then MsgBox "The footnotes story is not available."

Utilisez la propriété NextStoryRange pour parcourir en boucle tous les articles d'un document. L’exemple suivant recherche le texte « Microsoft Word » dans chaque article du document actif. Lorsque le texte est trouvé, il est mis en forme en italique.

For Each myStoryRange In ActiveDocument.StoryRanges 
 myStoryRange.Find.Execute _ 
 FindText:="Microsoft Word", Forward:=True 
 While myStoryRange.Find.Found 
 myStoryRange.Italic = True 
 myStoryRange.Find.Execute _ 
 FindText:="Microsoft Word", Forward:=True 
 Wend 
 While Not (myStoryRange.NextStoryRange Is Nothing) 
 Set myStoryRange = myStoryRange.NextStoryRange 
 myStoryRange.Find.Execute _ 
 FindText:="Microsoft Word", Forward:=True 
 While myStoryRange.Find.Found 
 myStoryRange.Italic = True 
 myStoryRange.Find.Execute _ 
 FindText:="Microsoft Word", Forward:=True 
 Wend 
 Wend 
Next myStoryRange

Méthodes

Propriétés

Voir aussi

Référence du modèle objet Word

Assistance et commentaires

Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.