Table.ConvertToText, méthode (Word)
Convertit un tableau en texte et renvoie un objet Range qui représente le texte délimité.
Syntaxe
expression.
ConvertToText( _Separator_ , _NestedTables_ )
expression Obligatoire. Variable qui représente un objet « Table ».
Paramètres
| Nom | Requis/Facultatif | Type de données | Description |
|---|---|---|---|
| Separator | Facultatif | Variant | Le caractère délimitant les colonnes converties (les lignes converties sont délimitées par des marques de paragraphe). Peut être des constantes WdTableFieldSeparator. |
| NestedTables | Facultatif | Variant | True si les tableaux imbriqués sont convertis en texte. Cet argument est ignoré si séparateur n'a pas pour valeur wdSeparateByParagraphs. La valeur par défaut est True. |
Remarques
Lorsque vous appliquez la méthode ConvertToText à un objet Table, l'objet est supprimé. Pour maintenir une référence au contenu converti du tableau, vous devez affecter l'objet Range renvoyé par la méthode ConvertToText à une nouvelle variable d'objet. Dans l'exemple suivant, le premier tableau du document actif est converti en texte et ensuite la mise en forme sous forme de liste à puces.
Dim tableTemp As Table
Dim rngTemp As Range
Set tableTemp = ActiveDocument.Tables(1)
Set rngTemp = _
tableTemp.ConvertToText(Separator:=wdSeparateByParagraphs)
rngTemp.ListFormat.ApplyListTemplate _
ListTemplate:=ListGalleries(wdBulletGallery).ListTemplates(1)
Exemple
Cet exemple montre comment créer un tableau et le convertir en texte en utilisant des tabulations comme caractères de séparation.
Dim docNew As Document
Dim tableNew As Table
Dim intTemp As Integer
Dim cellLoop As Cell
Dim rngTemp As Range
Set docNew = Documents.Add
Set tableNew = docNew.Tables.Add(Range:=Selection.Range, _
NumRows:=3, NumColumns:=3)
intTemp = 1
For Each cellLoop In tableNew.Range.Cells
cellLoop.Range.InsertAfter "Cell " & intTemp
intTemp = intTemp + 1
Next cellLoop
MsgBox "Click OK to convert table to text."
Set rngTemp = _
tableNew.ConvertToText(Separator:=wdSeparateByTabs)
Cet exemple montre comment convertir le tableau qui contient la sélection en texte, avec des espaces entre les colonnes.
If Selection.Information(wdWithInTable) = True Then
Selection.Tables(1).ConvertToText Separator:=" "
Else
MsgBox "The insertion point is not in a table."
End If
Voir aussi
Assistance et commentaires
Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.