Afficher du contenu XML à partir des fichiers de personnalisation de l’outil de personnalisation Office

Vue d’ensemble de l’environnement d’exécution de scripts Windows

Pour exécuter le script, utilisez l’environnement d’exécution de scripts Microsoft Windows, environnement d’exécution de scripts indépendant de la langue pour les moteurs de script compatibles avec les scripts Windows. L’environnement d’exécution de scripts Windows vous permet d’exécuter des scripts depuis le bureau Windows et l’invite de commandes.

Pour l’exécution des scripts depuis Windows, WScript.exe fournit une boîte de dialogue Windows qui permet de définir les propriétés des scripts. Pour l’exécution des scripts depuis l’invite de commandes, CScript.exe fournit des commutateurs de ligne de commande qui permettent de définir les propriétés des scripts.

L’environnement d’exécution de scripts Windows prend en charge les opérations glisser-déplacer pour les scripts. Cela signifie que vous pouvez faire glisser les fichiers vers un script de l’environnement d’exécution de scripts Windows. Les noms de fichiers sont convertis en arguments sur la ligne de commande.

Pour plus d’informations sur l’environnement d’exécution de scripts Windows, voir les ressources suivantes sur le site Web MSDN :

• Concepts de base de l’environnement d’exécution de scripts Windows (en anglais) (https://go.microsoft.com/fwlink/?linkid=100317\&clcid=0x40C) (en anglais)

• Exécution des scripts (en anglais) (https://go.microsoft.com/fwlink/?linkid=100319\&clcid=0x40C) (en anglais)

Exemple de script ExtractOctXml.vbs

Les sections suivantes fournissent un exemple de script Visual Basic, ExtractOctXml.vbs, et des instructions indiquant comment extraire les métadonnées XML des fichiers de personnalisation MSP de l’OPO à l’aide du script.

Pour enregistrer l’exemple de script, ouvrez un éditeur de texte tel que le Bloc-notes, puis copiez le code du script contenu dans cette section et collez-le dans un fichier. Enregistrez le fichier du script sous le nom ExtractOctXml.vbs.

' Utility to extract the metadata from an Office 2007 customization patch 
' For use with Windows Scripting Host, CScript.exe or WScript.exe
' Copyright (c) Microsoft Corporation. All rights reserved.
'
Option Explicit

Const msiOpenDatabaseModePatchFile = 32
Const msiOpenDatabaseModeReadOnly     = 0
Const msiReadStreamBytes = 1

Const ForWriting = 2
Const TristateTrue = -1

Dim pathOCT_Patch 'As String
Dim pathMetadataXml 'As String
Dim sMetadata 'As String
Dim wshShell 'As Wscript.Shell
Dim fso 'As FileSystemObject
Dim fileOutput 'As File
Dim sErrSection ' As String


sErrSection = "ArgCheck"
' Check arg count, and display help if argument not present or contains ?
Dim argCount:argCount = Wscript.Arguments.Count
If argCount > 0 Then If InStr(1, Wscript.Arguments(0), "?", vbTextCompare) > 0 Then argCount = 0
If (argCount = 0) Then
    Wscript.Echo "Office 2007 OCT Metadata Extract utility" & _
        vbNewLine & " You must supply the location of the Office 2007 customization patch " & _
        vbNewLine & _
        vbNewLine & "Copyright (C) Microsoft Corporation.  All rights reserved."
    Wscript.Quit 1
Else
    pathOCT_Patch = Trim(Wscript.Arguments(0))
End If


sErrSection = "FSO"
' Create FileSystemObject and verify file exists
Set fso = CreateObject("Scripting.FileSystemObject") : CheckError
If Not fso.FileExists(pathOCT_Patch) Then Err = 2 : CheckError


sErrSection = "WI"
' Connect to Windows Installer object
On Error Resume Next
Dim wi : Set wi = Nothing
Set wi = Wscript.CreateObject("WindowsInstaller.Installer") : CheckError


sErrSection = "Read Metadata"
' Open OCT patch and read the metadata stream
Dim wiStorage, vw, rec
Set wiStorage = wi.OpenDatabase(pathOCT_Patch, msiOpenDatabaseModePatchFile) : CheckError
Set vw = wiStorage.OpenView("SELECT * FROM _Streams WHERE `Name`='metadata' ") : CheckError
vw.Execute
Set rec = vw.Fetch
If Not rec Is Nothing Then
    sMetadata = rec.ReadStream(2, rec.DataSize(2), msiReadStreamBytes)
Else
    Wscript.Echo "No Metadata stream was found in this file: " & pathOCT_Patch
    Wscript.Quit 2
End If

Set wiStorage = Nothing
Set rec = Nothing: Set vw = Nothing
Set wi = Nothing


sErrSection = "Write Metadata"
' Write the metadata stream to a temp file
Set wshShell = CreateObject("WScript.Shell") : CheckError
pathMetadataXml = wshShell.ExpandEnvironmentStrings("%temp%") & "\" & fso.GetFileName(pathOCT_Patch) & ".xml"
Set fileOutput = fso.OpenTextFile(pathMetadataXml, ForWriting, True, -1) : CheckError
fileOutput.WriteLine sMetadata 
fileOutput.Close

Set fileOutput = Nothing: Set fso = Nothing

sErrSection = "Show Metadata"
' Launch Metadata in IE
wshShell.Run "iexplore.exe " & pathMetadataXml 

    
    
Sub CheckError
Dim sMsg, errRec
    If Err = 0 Then Exit Sub
    sMsg = sErrSection & vbNewLine & Err.Source & " " & Hex(Err) & ": " & Err.Description
    If Not wi Is Nothing Then
    Set errRec = wi.LastErrorRecord
        If Not errRec Is Nothing Then sMsg = sMsg & vbNewLine & errRec.FormatText
    End If
    Wscript.Echo sMsg
    Wscript.Quit 2
End Sub

Sub NoMetadata
End Sub

Voir aussi

Concepts

Outil de personnalisation Office dans Office System 2007