sp_helptracertokens (Transact-SQL)

Renvoie une ligne pour chaque jeton de suivi inséré dans une publication afin de déterminer le temps de latence. Cette procédure stockée est exécutée sur la base de données de publication du serveur de publication ou sur la base de données de distribution du serveur de distribution.

Conventions de la syntaxe de Transact-SQL

Syntaxe

sp_helptracertokens [ @publication = ] 'publication' 
    [ , [ @publisher = ] 'publisher' ] 
    [ , [ @publisher_db = ] 'publisher_db' ]

Arguments

• [ @publication= ] 'publication'
  Nom de la publication dans laquelle les jetons de suivi ont été insérés. publication est de type sysname, sans valeur par défaut.

• [ @publisher= ] 'publisher'
  Nom du serveur de publication. publisher est de type sysname, avec NULL comme valeur par défaut.

  Remarque :
  Ce paramètre doit uniquement être fourni pour les serveurs de publication non-Microsoft SQL Server.

• [ @publisher_db= ] 'publisher_db'
  Nom de la base de données de publication. publisher_db est de type sysname, avec NULL comme valeur par défaut. Ce paramètre est ignoré si la procédure stockée s'exécute sur le serveur de publication.

Notes

sp_helptracertokens est utilisé au cours d'une réplication transactionnelle.

sp_helptracertokens permet d'obtenir les ID de jetons de suivi lors de l'exécution de sp_helptracertokenhistory (Transact-SQL).

Autorisations

Seuls les membres du rôle serveur fixe sysadmin, du rôle de base de données fixe db_owner dans la base de données de publication, ou du rôle de base de données fixe db_owner ou des rôles replmonitor dans la base de données de distribution peuvent exécuter sp_helptracertokenhistory.

Jeu de résultats

Valeurs des codes renvoyés

0 (succès) ou 1 (échec)

Exemple

DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

USE [AdventureWorks]

-- Insert a new tracer token in the publication database.
EXEC sys.sp_posttracertoken 
  @publication = @publication,
  @tracer_token_id = @tokenID OUTPUT;
SELECT 'The ID of the new tracer token is ''' + 
    CONVERT(varchar,@tokenID) + '''.'
GO

-- Wait 10 seconds for the token to make it to the Subscriber.
WAITFOR DELAY '00:00:10';
GO

-- Get latency information for the last inserted token.
DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

CREATE TABLE #tokens (tracer_id int, publisher_commit datetime)

-- Return tracer token information to a temp table.
INSERT #tokens (tracer_id, publisher_commit)
EXEC sys.sp_helptracertokens @publication = @publication;
SET @tokenID = (SELECT TOP 1 tracer_id FROM #tokens
ORDER BY publisher_commit DESC)
DROP TABLE #tokens

-- Get history for the tracer token.
EXEC sys.sp_helptracertokenhistory 
  @publication = @publication, 
  @tracer_id = @tokenID;
GO

Voir aussi

Référence

sp_deletetracertokenhistory (Transact-SQL)

Autres ressources

How to: Measure Latency and Validate Connections for Transactional Replication (Replication Transact-SQL Programming)
Mesure de la latence et validation des connexions pour la réplication transactionnelle

Aide et Informations

Assistance sur SQL Server 2005