Gestion des messages incohérents

Exemple : détection d'un message incohérent

Cet exemple Transact-SQL illustre un service simple et sans état qui inclut la logique de gestion des messages incohérents. Avant que la procédure stockée reçoive un message, la procédure enregistre la transaction. Lorsque la procédure ne parvient pas à traiter un message, elle restaure la transaction au point d'enregistrement. La restauration partielle retourne le message à la file d'attente tout en maintenant toujours un verrou sur le groupe de conversations pour le message. Dans la mesure où le programme préserve le verrouillage du groupe de conversations, il peut mettre à jour une table qui conserve une liste de messages ayant échoué sans risque qu'un autre agent de lecture de file d'attente puisse traiter le message.

L'exemple suivant définit la procédure stockée d'activation pour l'application :

CREATE PROCEDURE ProcessExpenseReport
AS
BEGIN
  WHILE (1 = 1)
    BEGIN
      BEGIN TRANSACTION ;
      DECLARE @conversationHandle UNIQUEIDENTIFIER ;
      DECLARE @messageBody VARBINARY(MAX) ;
      DECLARE @messageTypeName NVARCHAR(256) ;

      SAVE TRANSACTION UndoReceive ;

        WAITFOR ( 
                  RECEIVE TOP(1)
                    @messageTypeName = message_type_name,
                    @messageBody = message_body,
                    @conversationHandle = conversation_handle
                    FROM ExpenseQueue
                 ), TIMEOUT 500 ;

        IF @@ROWCOUNT = 0
        BEGIN
          ROLLBACK TRANSACTION ;
          BREAK ;
        END ;

        -- Typical message processing loop: dispatch to a stored
        -- procedure based on the message type name.  End conversation
        -- with an error for unknown message types.

        -- Process expense report messages. If processing fails,
        -- roll back to the save point and track the failed message.

        IF (@messageTypeName =
              '//Adventure-Works.com/AccountsPayable/ExpenseReport')
          BEGIN
            DECLARE @expenseReport NVARCHAR(MAX) ;
            SET @expenseReport = CAST(@messageBody AS NVARCHAR(MAX)) ;
            EXEC AdventureWorks.dbo.AddExpenseReport
              @report = @expenseReport ;
            IF @@ERROR <> 0
             BEGIN
               ROLLBACK TRANSACTION UndoReceive ;
               EXEC TrackMessage @conversationHandle ;
             END ;
            ELSE
             BEGIN
               EXEC AdventureWorks.dbo.ClearMessageTracking
                 @conversationHandle ;
             END ;
           END ;
        ELSE

        -- For error messages and end dialog messages, end the
        -- conversation.

        IF (@messageTypeName =
              'https://schemas.microsoft.com/SQL/ServiceBroker/Error' OR
             @messageTypeName =
              'https://schemas.microsoft.com/SQL/ServiceBroker/EndDialog')
          BEGIN
            END CONVERSATION @conversationHandle ;
            EXEC dbo.ClearMessageTracking @conversationHandle ;
          END ;


         COMMIT TRANSACTION ;
    END ;
END ;

La procédure stockée TrackMessage assure le suivi du nombre d'échecs d'un message. Lorsqu'il s'agit du premier échec du message, la procédure insère un nouveau compteur pour le message dans la table ExpenseServiceFailedMessages. Sinon, la procédure contrôle le compteur pour connaître le nombre d'échecs du message. La procédure incrémente le compteur lorsque sa valeur est inférieure à un nombre prédéfini. Lorsque la valeur du compteur est supérieure au nombre prédéfini, la procédure met fin à la conversation par le biais d'une erreur et supprime de la table le compteur de la conversation.

CREATE PROCEDURE TrackMessage
@conversationHandle uniqueidentifier
AS
BEGIN
  IF @conversationHandle IS NULL
    RETURN ;

  DECLARE @count INT ;
  SET @count = NULL ;
  SET @count = (SELECT count FROM dbo.ExpenseServiceFailedMessages
                  WHERE conversation_handle = @conversationHandle) ;

  IF @count IS NULL
    BEGIN
      INSERT INTO dbo.ExpenseServiceFailedMessages
        (count, conversation_handle)
        VALUES (1, @conversationHandle) ;
    END ;
  IF @count > 3
    BEGIN
      EXEC dbo.ClearMessageTracking @conversationHandle ;
      END CONVERSATION @conversationHandle
        WITH ERROR = 500
        DESCRIPTION = 'Unable to process message.' ;
    END ;
  ELSE
    BEGIN
      UPDATE dbo.ExpenseServiceFailedMessages
        SET count=count+1
        WHERE conversation_handle = @conversationHandle ;
    END ;
END ;
GO

La définition de table ExpenseServiceFailedMessages contient simplement une colonne conversation_handle et une colonne count, comme illustré dans l'exemple suivant :

CREATE TABLE ExpenseServiceFailedMessages (
  conversation_handle uniqueidentifier PRIMARY KEY,
  count smallint
) ;

La procédure ClearMessageTracking supprime le compteur pour une conversation de la table ExpenseServiceFailedMessages, comme illustré dans l'exemple suivant :

CREATE PROCEDURE ClearMessageTracking
  @conversationHandle uniqueidentifier
AS
BEGIN
   DELETE FROM dbo.ExpenseServiceFailedMessages
     WHERE conversation_handle = @conversationHandle ;
END ;
GO

La stratégie présentée ici est délibérément simple. Vous devez vous inspirer des idées de cette rubrique pour créer une application qui correspond à vos besoins. Par exemple, si votre application gère l'état, il peut être plus efficace d'inclure les informations de suivi des messages ayant échoué dans les tables d'état de l'application.

Les procédures stockées présentées ci-avant ne gèrent pas les erreurs qui provoquent l'échec d'une transaction. Si ce service reçoit un message qui provoque l'échec de l'intégralité de la transaction, la transaction est restaurée. Si cette situation se produit cinq fois, la détection automatique des messages incohérents définit l'état de la file d'attente sur OFF. Dans ce cas, le message incohérent doit être supprimé par une autre application ou par un administrateur.

Si vous pensez que le traitement que vous effectuez sur le message peut provoquer l'échec d'une transaction, vous pouvez utiliser les instructions TRY et CATCH pour gérer l'erreur. Pour plus d'informations sur la gestion des erreurs, consultez Gestion des erreurs du moteur de base de données.

Voir aussi

Référence

Concepts

Autres ressources