LocalMachineLockdown-wmi-multi.vbs
By The Scripting Guys, Microsoft Corporation
This script runs against multiple computers to turn on or off local machine lockdown for the iexplore.exe process. It makes this change by editing the registry using the WMI System Registry provider. You must edit the registry path to insert the correct CLSID of the add-on component to be disabled. To identify the CLSID of an add-on component, search the registry for the add-on name that is located in the Manage Add-ons interface.
LocalMachineLockdown-wmi-multi.vbs corresponds to LocalMachineLockdown.vbs, one of the scripts that ships with Application Compatibility Testing and Mitigation Guide for Windows XP Service Pack 2 and which are documented in the Appendix. You can download a Windows Installer (.msi) file that installs the Guide and its associated scripts from:
Input for this script comes from a comma-delimited text file, lockdown-hosts.csv, which contains the names of computers against which the script will run. This text file must be in the same folder as the script.
Each line of the input file must consist of a computer name followed by a comma, followed by either 0 or 1. Each computer must be accessible on the network and the credentials under which the script is run must have administrative privileges on it. For example (to turn on for client1 & server1, turn off for client2 and server2):
client1,1
client2,0
server1,1
server2,0
Valid values are as follows:
1 = Turns on local machine lockdown.
0 = Turns off local machine lockdown.
Be sure there is no line break after the final line, as this will be interpreted by the script as an empty string.
To use the script, copy the code, paste it into Notepad, and then save the script as LocalMachineLockdown-wmi-multi.vbs. To run the script, open a command prompt window to the directory of the script and type:
cscript localmachinelockdown-wmi-multi.vbs
If the default script host on the computer is Cscript.exe, the initial "cscript" may be omitted.
Script Code
'LocalMachineLockdown-wmi-multi.vbs
'Author: Peter Costantini, the Microsoft Scripting Guys
'Date: 8/25/04
'Revision 1.0
'System requirement: Windows XP Service Pack 2.
'This script edits the registry to turn on or off local machine
'lockdown for the iexplore.exe process.
'It can be run against multiple remote computers.
'The multiple computers must be specified in a comma-delimited
'text file, lockdown-hosts.csv, in the same directory as the script.
'Each line of lockdown-hosts.csv must have a computer name followed by a
'comma, followed by either 0 or 1.
'Do not add a newline to the end of the last line.
'Example (turn on for client1 & server1, turn off for client2 and server2):
'client1,1
'client2,0
'server1,1
'server2,0
'Valid iexplore.exe values are as follows:
'1 = Turns on local machine lockdown.
'0 = Turns off local machine lockdown.
'******************************************************************************
On Error Resume Next
'Global constants and variables
Const FOR_READING = 1
strFilename = "lockdown-hosts.csv"
'If text file exists, read list of hosts and operation for each.
Set objFSO = CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strFilename) Then
Set objFile = objFSO.OpenTextFile(strFilename, FOR_READING)
Else
WScript.Echo "Input file " & strFilename & " not found."
WScript.Quit
End If
Do Until objFile.AtEndOfStream
strHost = objFile.ReadLine
arrHost = Split(strHost, ",")
'Get name of computer
strComputer = arrHost(0)
'DWORD value of RestrictRemoteClients for this host.
g_intValue = arrHost(1)
Wscript.Echo VbCrLf & strComputer
Wscript.Echo String(Len(strComputer), "-")
'Connect with WMI service and StdRegProv class.
Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
strComputer & "\root\default:StdRegProv")
If Err = 0 Then
SetValue
Else
WScript.Echo "Unable to connect to WMI StdRegProv on " & strComputer & "."
WScript.Echo " Error Number:" & Err.Number
WScript.Echo " Source:" & Err.Source
WScript.Echo " Description:" & Err.Description
End If
Err.Clear
Loop
objFile.Close
'******************************************************************************
Sub SetValue
'Local constants and variables
Const HKEY_LOCAL_MACHINE = &H80000002
strKeyPath = "SOFTWARE\Microsoft\Internet Explorer\Main\FeatureControl" & _
"\FEATURE_LOCALMACHINE_LOCKDOWN"
strEntryName = "iexplore.exe"
intReturn = objReg.SetDWORDValue(HKEY_LOCAL_MACHINE, strKeyPath, _
strEntryName, g_intValue)
If intReturn = 0 Then
WScript.Echo "Changed value of " & strEntryName & " to " & g_intValue & "."
Else
WScript.Echo "ERROR: Unable to change value of " & strEntryName & "."
End If
End Sub
For online peer support, join The Official Scripting Guys Forum! To provide feedback or report bugs in sample scripts, please start a new discussion on the Discussions tab for this script.
Disclaimer
This sample script is not supported under any Microsoft standard support program or service. The sample script is provided AS IS without warranty of any kind. Microsoft further disclaims all implied warranties including, without limitation, any implied warranties of merchantability or of fitness for a particular purpose. The entire risk arising out of the use or performance of the sample scripts and documentation remains with you. In no event shall Microsoft, its authors, or anyone else involved in the creation, production, or delivery of the scripts be liable for any damages whatsoever (including, without limitation, damages for loss of business profits, business interruption, loss of business information, or other pecuniary loss) arising out of the use of or inability to use the sample scripts or documentation, even if Microsoft has been advised of the possibility of such damages.