Conversion simplifiée des délégués

Article
09/12/2008

Mise à jour : novembre 2007

La conversion simplifiée des délégués, introduite dans Visual Basic 2008, vous permet d'assigner des subs et des fonctions aux délégués ou aux gestionnaires même lorsque leurs signatures ne sont pas identiques. Par conséquent, la liaison aux délégués devient cohérente avec la liaison déjà autorisée pour les appels de méthodes.

Paramètres et type de retour

À la place d'une correspondance de signature exacte, la conversion simplifiée requiert que les conditions suivantes soient réunies lorsque Option Strict a la valeur On :

Une conversion étendue doit avoir lieu, du type de données de chaque paramètre de délégué en type de données du paramètre correspondant de la fonction ou du Sub assigné. Dans l'exemple suivant, le délégué Del1 possède un seul paramètre, un Integer. Le paramètre m dans les expressions lambda assignées doit présenter un type de données pour lequel il existe une conversion étendue de Integer, tel que Long ou Double.
```
' Definition of delegate Del1.
Delegate Function Del1(ByVal arg As Integer) As Integer
```
```
' Valid lambda expression assignments with Option Strict on or off:

' Integer matches Integer.
Dim d1 As Del1 = Function(m As Integer) 3

' Integer widens to Long
Dim d2 As Del1 = Function(m As Long) 3

' Integer widens to Double
Dim d3 As Del1 = Function(m As Double) 3
```
Les conversions restrictives sont autorisées uniquement lorsque Option Strict a la valeur Off.
```
' Valid only when Option Strict is off:

Dim d4 As Del1 = Function(m As String) CInt(m)
Dim d5 As Del1 = Function(m As Short) m
```
Une conversion étendue doit avoir lieu dans le sens opposé, du type de retour de la fonction ou du Sub assigné en type de retour du délégué. Dans les exemples suivants, le corps de chaque expression lambda assignée doit avoir la valeur d'un type de données qui s'étend à Integer étant donné que le type de retour de del1 est Integer.
```
' Valid return types with Option Strict on:

' Integer matches Integer.
Dim d6 As Del1 = Function(m As Integer) m

' Short widens to Integer.
Dim d7 As Del1 = Function(m As Long) CShort(m)

' Byte widens to Integer.
Dim d8 As Del1 = Function(m As Double) CByte(m)
```

Si Option Strict a la valeur Off, la restriction étendue est supprimée dans les deux directions.

' Valid only when Option Strict is set to Off.

' Integer does not widen to Short in the parameter.
Dim d9 As Del1 = Function(n As Short) n

' Long does not widen to Integer in the return type.
Dim d10 As Del1 = Function(n As Integer) CLng(n)

Omission des spécifications de paramètres

Les délégués simplifiés vous permettent également d'omettre complètement les spécifications de paramètres dans la méthode assignée :

' Definition of delegate Del2, which has two parameters.
Delegate Function Del2(ByVal arg1 As Integer, ByVal arg2 As String) As Integer

' The assigned lambda expression specifies no parameters, even though
' Del2 has two parameters. Because the assigned function in this 
' example is a lambda expression, Option Strict can be on or off.
' Compare the declaration of d16, where a standard function is assigned.
Dim d11 As Del2 = Function() 3

' The parameters are still there, however, as defined in the delegate.
Console.WriteLine(d11(5, "five"))

' Not valid.
' Console.WriteLine(d11())
' Console.WriteLine(d11(5))

Notez que vous ne pouvez pas spécifier certains paramètres et en omettre d'autres.

' Not valid.
'Dim d12 As Del2 = Function(p As Integer) p

L'omission des paramètres est utile par exemple lors de la définition d'un gestionnaire d'événements, où plusieurs paramètres complexes sont impliqués. Les arguments de certains gestionnaires d'événements ne sont pas utilisés. À la place, le gestionnaire accède directement à l'état du contrôle dans lequel l'événement est enregistré et ignore les arguments. Les délégués simplifiés vous permettent d'omettre les arguments dans les déclarations qui ne comprennent aucune ambiguïté. Dans l'exemple suivant, la méthode OnClick intégralement spécifiée peut être réécrite en tant que RelaxedOnClick.

Sub OnClick(ByVal sender As Object, ByVal e As EventArgs) Handles b.Click
    MessageBox.Show("Hello World from" + b.Text)
End Sub

Sub RelaxedOnClick() Handles b.Click
    MessageBox.Show("Hello World from" + b.Text)
End Sub

Exemples d'AddressOf

Les expressions lambda sont utilisées dans les exemples précédents de manière à simplifier l'affichage des relations des types. Toutefois, les mêmes simplifications sont autorisées pour les assignations de délégués qui utilisent AddressOf, Handles ou AddHandler.

Dans l'exemple suivant, les fonctions f1, f2, f3 et f4 peuvent toutes être assignées à Del1.

' Definition of delegate Del1.
Delegate Function Del1(ByVal arg As Integer) As Integer

' Definitions of f1, f2, f3, and f4.
Function f1(ByVal m As Integer) As Integer
End Function

Function f2(ByVal m As Long) As Integer
End Function

Function f3(ByVal m As Integer) As Short
End Function

Function f4() As Integer
End Function

' Assignments to function delegate Del1.

' Valid AddressOf assignments with Option Strict on or off:

' Integer parameters of delegate and function match.
Dim d13 As Del1 = AddressOf f1

' Integer delegate parameter widens to Long.
Dim d14 As Del1 = AddressOf f2

' Short return in f3 widens to Integer.
Dim d15 As Del1 = AddressOf f3

L'exemple suivant est valide uniquement lorsque Option Strict a la valeur Off.

' If Option Strict is Off, parameter specifications for f4 can be omitted.
Dim d16 As Del1 = AddressOf f4

' Function d16 still requires a single argument, however, as specified
' by Del1.
Console.WriteLine(d16(5))

' Not valid.
'Console.WriteLine(d16())
'Console.WriteLine(d16(5, 3))

Déplacement des retours de la fonction

La conversion simplifiée des délégués vous permet d'assigner une fonction à un délégué Sub, en ignorant la valeur de retour de la fonction. Toutefois, vous ne pouvez pas assigner un Sub à un délégué de fonction. Dans l'exemple suivant, l'adresse de la fonction doubler est assignée au délégué SubDel3.

' Definition of Sub delegate Del3.
Delegate Sub Del3(ByVal arg1 As Integer)

' Definition of function doubler, which both displays and returns the
' value of its integer parameter.
Function doubler(ByVal p As Integer) As Integer
    Dim times2 = 2 * p
    Console.WriteLine("Value of p: " & p)
    Console.WriteLine("Double p:   " & times2)
    Return times2
End Function

' You can assign the function to the Sub delegate:
Dim d17 As Del3 = AddressOf doubler

' You can then call d17 like a regular Sub procedure.
d17(5)

' You cannot call d17 as a function. It is a Sub, and has no 
' return value.
' Not valid.
'Console.WriteLine(d17(5))

Voir aussi

Partager via

Conversion simplifiée des délégués

Paramètres et type de retour

Omission des spécifications de paramètres

Exemples d'AddressOf

Déplacement des retours de la fonction

Voir aussi

Tâches

Concepts

Référence

Ressources supplémentaires