Partager via

Comment : trier les éléments ListView

  • Article

Mise à jour : novembre 2007

Le .NET Compact Framework ne prend pas en charge la méthode Sort pour ListView, mais vous pouvez trier des éléments à l'aide de l'interface IComparer et utiliser la méthode Sort sur ArrayList.

Le tableau suivant définit trois classes.

Classe

Description

ColHeader

Cette classe, qui est dérivée de la classe ColumnHeader, est utilisée pour ajouter des colonnes au contrôle ListView et trier la colonne sur laquelle le clic a été effectué. Elle inclut la propriété ascending pour spécifier le sens du tri : true spécifie l'ordre croissant et false l'ordre décroissant.

SortWrapper

Lorsque vous cliquez sur une colonne, une instance de cette classe est créée pour chaque ListItem et ajoutée à ArrayList. Chaque élément encapsulé inclut une propriété qui contient l'index de la colonne sur laquelle le clic a été effectué.

Cette classe contient la classe SortComparer.

SortComparer

Dans la classe SortWrapper, cette classe définit une implémentation de l'interface IComparer dont la méthode Compare compare des objets, deux par deux, lorsque ArrayList est trié.

Le gestionnaire d'événements de l'événement ColumnClick exécute l'opération de tri comme suit :

  1. Crée une instance de la classe ColHeader pour déterminer quelle colonne a fait l'objet d'un clic.

  2. Définit la propriété croissante de l'objet ColHeader pour effectuer le tri dans le sens inverse.

  3. Obtient le nombre d'éléments de la liste.

  4. Désactive le dessin de l'affichage pendant le tri à l'aide de la méthode BeginUpdate.

  5. Ajoute SortWrapper pour chaque élément ListView à ArrayList.

  6. Trie les éléments de ArrayList à l'aide d'une nouvelle instance de la classe SortComparer dont l'implémentation de l'interface IComparer contient la logique du tri dans sa méthode Compare.

  7. Efface le contrôle ListView d'éléments et remplit à nouveau le contrôle avec les éléments triés de ArrayList.

  8. Active le dessin de l'affichage avec la méthode EndUpdate.

Notez que la méthode Sort sur ArrayList exécute un tri instable ; en d'autres termes, si deux éléments sont égaux, leur ordre peut ne pas être conservé. Au contraire, un tri stable conserve l'ordre des éléments qui sont égaux.

Pour créer l'application

  1. Ajoutez la classe SortWrapper à votre projet, qui contient également la classe SortComparer.

    ' An instance of the SortWrapper class is created for 
' each item and added to the ArrayList for sorting.
Public Class SortWrapper
    Friend sortItem As ListViewItem
    Friend sortColumn As Integer

    ' A SortWrapper requires the item and the index of the clicked column.
    Public Sub New(ByVal Item As ListViewItem, ByVal iColumn As Integer)
        sortItem = Item
        sortColumn = iColumn
    End Sub

    ' Text property for getting the text of an item.
    Public ReadOnly Property [Text]() As String
        Get
            Return sortItem.SubItems(sortColumn).Text
        End Get
    End Property

    ' Implementation of the IComparer 
    ' interface for sorting ArrayList items.
    Public Class SortComparer
        Implements IComparer
        Private ascending As Boolean


        ' Constructor requires the sort order;
        ' true if ascending, otherwise descending.
        Public Sub New(ByVal asc As Boolean)
            Me.ascending = asc
        End Sub


        ' Implemnentation of the IComparer:Compare 
        ' method for comparing two objects.
        Public Function [Compare](ByVal x As Object, ByVal y As Object) As Integer Implements IComparer.Compare
            Dim xItem As SortWrapper = CType(x, SortWrapper)
            Dim yItem As SortWrapper = CType(y, SortWrapper)

            Dim xText As String = xItem.sortItem.SubItems(xItem.sortColumn).Text
            Dim yText As String = yItem.sortItem.SubItems(yItem.sortColumn).Text
            Return xText.CompareTo(yText) * IIf(Me.ascending, 1, -1)
        End Function
    End Class
End Class

    // An instance of the SortWrapper class is created for
// each item and added to the ArrayList for sorting.
public class SortWrapper
{
    internal ListViewItem sortItem;
    internal int sortColumn;


    // A SortWrapper requires the item and the index of the clicked column.
    public SortWrapper (ListViewItem Item, int iColumn)
    {
        sortItem = Item;
        sortColumn = iColumn;
    }

    // Text property for getting the text of an item.
    public string Text
    {
        get
        {
            return sortItem.SubItems[sortColumn].Text;
        }
    }

    // Implementation of the IComparer
    // interface for sorting ArrayList items.
    public class SortComparer : IComparer
    {
        bool ascending;

        // Constructor requires the sort order;
        // true if ascending, otherwise descending.
        public SortComparer(bool asc)
        {
            this.ascending = asc;
        }

        // Implemnentation of the IComparer:Compare
        // method for comparing two objects.
        public int Compare(object x, object y)
        {
            SortWrapper xItem = (SortWrapper) x;
            SortWrapper yItem = (SortWrapper) y;

            string xText = xItem.sortItem.SubItems[xItem.sortColumn].Text;
            string yText = yItem.sortItem.SubItems[yItem.sortColumn].Text;
            return xText.CompareTo(yText) * (this.ascending ? 1 : -1);
        }
    }
}

  2. Ajoutez la classe ColHeader à votre projet :

    ' The ColHeader class is a ColumnHeader object with an 
' added property for determining an ascending or descending sort.
' True specifies an ascending order, false specifies a descending order.
Public Class ColHeader
    Inherits ColumnHeader
    Public ascending As Boolean

    Public Sub New(ByVal [text] As String, ByVal width As Integer, ByVal align As HorizontalAlignment, ByVal asc As Boolean)
        Me.Text = [text]
        Me.Width = width
        Me.TextAlign = align
        Me.ascending = asc
    End Sub
End Class

    // The ColHeader class is a ColumnHeader object with an
// added property for determining an ascending or descending sort.
// True specifies an ascending order, false specifies a descending order.
public class ColHeader : ColumnHeader
{
    public bool ascending;
    public ColHeader(string text, int width,  HorizontalAlignment align, bool asc)
    {
        this.Text = text;
        this.Width = width;
        this.TextAlign = align;
        this.ascending = asc;
    }
}

  3. Ajoutez des colonnes avec la classe ColHeader et ajoutez des éléments ListView.

    ' Set to Details view.
Me.listView1.View = View.Details

' Add columns using the ColHeader class. The fourth    
' parameter specifies true for an ascending sort order.
listView1.Columns.Add(New ColHeader("Name", 110, HorizontalAlignment.Left, True))
listView1.Columns.Add(New ColHeader("Region", 50, HorizontalAlignment.Left, True))
listView1.Columns.Add(New ColHeader("Sales", 70, HorizontalAlignment.Left, True))

' Add the data.
listView1.Items.Add(New ListViewItem(New String() {"Archer, Karen", "4", "0521.28"}))
listView1.Items.Add(New ListViewItem(New String() {"Benson, Max", "8", "0828.54"}))
listView1.Items.Add(New ListViewItem(New String() {"Bezio, Marin", "3", "0535.22"}))
listView1.Items.Add(New ListViewItem(New String() {"Higa, Sidney", "2", "0987.50"}))
listView1.Items.Add(New ListViewItem(New String() {"Martin, Linda", "6", "1122.12"}))
listView1.Items.Add(New ListViewItem(New String() {"Nash, Mike", "7", "1030.11"}))
listView1.Items.Add(New ListViewItem(New String() {"Sanchez, Ken", "1", "0958.78"}))
listView1.Items.Add(New ListViewItem(New String() {"Smith, Ben", "5", "0763.25"}))

' Connect the ListView.ColumnClick event to the ColumnClick event handler.
AddHandler Me.listView1.ColumnClick, AddressOf listView1_ColumnClick

    this.listView1.View = View.Details;

// Add columns using the ColHeader class. The fourth
// parameter specifies true for an ascending sort order.
listView1.Columns.Add(new ColHeader("Name", 110, HorizontalAlignment.Left, true));
listView1.Columns.Add(new ColHeader("Region", 50, HorizontalAlignment.Left, true));
listView1.Columns.Add(new ColHeader("Sales", 70, HorizontalAlignment.Left, true));

// Add the data.
listView1.Items.Add(new ListViewItem(new string[] {"Archer, Karen","4","0521.28"}));
listView1.Items.Add(new ListViewItem(new string[] {"Benson, Max","8","0828.54"}));
listView1.Items.Add(new ListViewItem(new string[] {"Bezio, Marin","3","0535.22"}));
listView1.Items.Add(new ListViewItem(new string[] {"Higa, Sidney","2","0987.50"}));
listView1.Items.Add(new ListViewItem(new string[] {"Martin, Linda","6","1122.12"}));
listView1.Items.Add(new ListViewItem(new string[] {"Nash, Mike","7","1030.11"}));
listView1.Items.Add(new ListViewItem(new string[] {"Sanchez, Ken","1","0958.78"}));
listView1.Items.Add(new ListViewItem(new string[] {"Smith, Ben","5","0763.25"}));

// Connect the ListView.ColumnClick event to the ColumnClick event handler.
this.listView1.ColumnClick += new ColumnClickEventHandler(listView1_ColumnClick);

  4. Ajoutez du code pour exécuter le tri.

    Private Sub listView1_ColumnClick(ByVal sender As Object, ByVal e As ColumnClickEventArgs)

    ' Create an instance of the ColHeader class. 
    Dim clickedCol As ColHeader = CType(Me.listView1.Columns(e.Column), ColHeader)

    ' Set the ascending property to sort in the opposite order.
    clickedCol.ascending = Not clickedCol.ascending

    ' Get the number of items in the list.
    Dim numItems As Integer = Me.listView1.Items.Count

    ' Turn off display while data is repoplulated.
    Me.listView1.BeginUpdate()

    ' Populate an ArrayList with a SortWrapper of each list item.
    Dim SortArray As New ArrayList
    Dim i As Integer
    For i = 0 To numItems - 1
        SortArray.Add(New SortWrapper(Me.listView1.Items(i), e.Column))
    Next i

    ' Sort the elements in the ArrayList using a new instance of the SortComparer
    ' class. The parameters are the starting index, the length of the range to sort,
    ' and the IComparer implementation to use for comparing elements. Note that
    ' the IComparer implementation (SortComparer) requires the sort  
    ' direction for its constructor; true if ascending, othwise false.
    SortArray.Sort(0, SortArray.Count, New SortWrapper.SortComparer(clickedCol.ascending))

    ' Clear the list, and repopulate with the sorted items.
    Me.listView1.Items.Clear()
    Dim z As Integer
    For z = 0 To numItems - 1
        Me.listView1.Items.Add(CType(SortArray(z), SortWrapper).sortItem)
    Next z
    ' Turn display back on.
    Me.listView1.EndUpdate()
End Sub

    private void listView1_ColumnClick(object sender, ColumnClickEventArgs e)
{

    // Create an instance of the ColHeader class.
    ColHeader clickedCol = (ColHeader)this.listView1.Columns[e.Column];

    // Set the ascending property to sort in the opposite order.
    clickedCol.ascending = !clickedCol.ascending;

    // Get the number of items in the list.
    int numItems = this.listView1.Items.Count;

    // Turn off display while data is repoplulated.
    this.listView1.BeginUpdate();

    // Populate an ArrayList with a SortWrapper of each list item.
    ArrayList SortArray = new ArrayList();
    for (int i = 0; i < numItems; i++)
    {
        SortArray.Add(new SortWrapper(this.listView1.Items[i], e.Column));
    }

    // Sort the elements in the ArrayList using a new instance of the SortComparer
    // class. The parameters are the starting index, the length of the range to sort,
    // and the IComparer implementation to use for comparing elements. Note that
    // the IComparer implementation (SortComparer) requires the sort
    // direction for its constructor; true if ascending, othwise false.
    SortArray.Sort(0, SortArray.Count, new SortWrapper.SortComparer(clickedCol.ascending));

    // Clear the list, and repopulate with the sorted items.
    this.listView1.Items.Clear();
    for  (int i = 0; i < numItems; i++)
        this.listView1.Items.Add(((SortWrapper)SortArray[i]).sortItem);

    // Turn display back on.
    this.listView1.EndUpdate();
}

Compilation du code

Cet exemple nécessite des références aux espaces de noms suivants :

Voir aussi

Concepts

Développement de contrôle personnalisé

.Rubriques Comment relatives au .NET Compact Framework

Autres ressources

Contrôles Windows Forms dans le .NET Compact Framework