Connect, exemple de méthode (VBScript)
Important
À compter de Windows 8 et Windows Server 2012, les composants serveur RDS ne sont plus inclus dans le système d’exploitation Windows (voir le Guide pratique sur la compatibilité de Windows Server 2012 et Windows 8 pour plus de détails). Les composants clients RDS seront supprimés dans une version ultérieure de Windows. Évitez d'utiliser cette fonctionnalité dans de nouveaux travaux de développement, et prévoyez de modifier les applications qui utilisent actuellement cette fonctionnalité. Les applications qui utilisent RDS doivent migrer vers WCF Data Service.
Ce code montre comment définir la propriété Connect au moment de la conception :
<OBJECT CLASSID="clsid:BD96C556-65A3-11D0-983A-00C04FC29E33" ID="ADC1">
.
<PARAM NAME="SQL" VALUE="Select * from Sales">
<PARAM NAME="CONNECT" VALUE="Provider=SQLOLEDB;Integrated Security=SSPI;Initial Catalog=Pubs">
<PARAM NAME="Server" VALUE="https://MyWebServer">
.
</OBJECT>
L’exemple suivant montre comment définir la propriété Connect lors de l’exécution dans le code VBScript.
Pour tester cet exemple, coupez et collez le code entre les balises <Body> et </Body> dans un document HTML normal et nommez-le ConnectVBS.asp. Le script ASP identifie votre serveur.
<!-- BeginConnectVBS -->
<%@ Language=VBScript %>
<HTML>
<HEAD>
<title>ADO Connect Property</title>
<%' local style sheet used for display%>
<STYLE>
<!--
BODY {
font-family: 'Verdana','Arial','Helvetica',sans-serif;
BACKGROUND-COLOR:white;
COLOR:black;
}
.tbody {
text-align: center;
background-color: #f7efde;
font-family: 'Verdana','Arial','Helvetica',sans-serif;
font-size: x-small;
}
-->
</STYLE>
</HEAD>
<BODY>
<h1>ADO Connect Property (RDS)</h1>
<HR>
<H3>Set Connect Property at Run Time</H3>
<% ' RDS.DataControl with no parameters set at design time %>
<OBJECT classid="clsid:BD96C556-65A3-11D0-983A-00C04FC29E33" ID=RDS HEIGHT=1 WIDTH=1></OBJECT>
<% ' Bind table to control for data display %>
<TABLE DATASRC=#RDS>
<TBODY>
<TR class="tbody">
<TD><SPAN DATAFLD="FirstName"></SPAN></TD>
<TD><SPAN DATAFLD="LastName"></SPAN></TD>
</TR>
</TBODY>
</TABLE>
<FORM name="frmInput">
SERVER: <INPUT Name="txtServer" Size="103" Value="https://<%=Request.ServerVariables("SERVER_NAME")%>"><BR>
DATA SOURCE: <INPUT Name="txtDataSource" Size="93" Value="<%=Request.ServerVariables("SERVER_NAME")%>"><BR>
CONNECT: <INPUT Name="txtConnect" Size="100"><BR>
SQL: <INPUT Name="txtSQL" Size="110" Value="Select FirstName, LastName from Employees">
<BR>
<INPUT TYPE=BUTTON NAME="Run" VALUE="Run">
<h4>
To make data grid appear, click 'Run' to see the connect string in text box above.
</h4>
</FORM>
<Script Language="VBScript">
' Set parameters of RDS.DataControl at Run Time
Sub Run_OnClick
Dim Cnxn
' build connection string
Cnxn = "Provider='sqloledb';"
Cnxn = Cnxn & "Data Source="
Cnxn = Cnxn & document.frmInput.txtDataSource.value & ";"
Cnxn = Cnxn & "Initial Catalog='Northwind';"
Cnxn = Cnxn & "Integrated Security='SSPI';"
' assign the value
document.frmInput.txtConnect.value = Cnxn
MsgBox "Here we go!"
' set RDS properties
RDS.Server = document.frmInput.txtServer.value
RDS.SQL = document.frmInput.txtSQL.value
RDS.Connect = document.frmInput.txtConnect.value
RDS.Refresh
End Sub
</Script>
</BODY>
</HTML>
<!-- EndConnectVBS -->