Créer des colonnes calculées

• 4 minutes

Vous pouvez écrire une formule DAX pour ajouter une colonne calculée à une table de votre modèle. Une formule de colonne calculée doit retourner une valeur scalaire ou unique.

Les colonnes calculées dans les modèles d’importation ont un coût : Elles augmentent la taille de stockage du modèle et peuvent allonger le délai d’actualisation des données. Cela est dû au fait que les colonnes calculées sont recalculées lorsqu’elles contiennent des dépendances de formules liées à des tables actualisées.

Dans la vue de données, dans le volet Champs, assurez-vous que la table Date d'échéance est sélectionnée. Avant de créer une colonne calculée, renommez la colonne Date en Due Date (Date d'échéance).

Vous pouvez maintenant ajouter une colonne calculée à la table Date d'échéance. Pour créer une colonne calculée, dans le ruban contextuel Outils de table, à l’intérieur du groupe Calculs, sélectionnez Nouvelle colonne.

Dans la barre de formule, entrez la définition de colonne calculée suivante, puis appuyez sur Entrée.

Due Fiscal Year =
"FY"
    & YEAR('Due Date'[Due Date])
        + IF(
            MONTH('Due Date'[Due Date]) > 6,
            1
        )

La définition de colonne calculée ajoute la colonne Due Fiscal Year (Année fiscale d’échéance) à la table Due Date (Date d’échéance). Les étapes suivantes décrivent comment Microsoft Power BI évalue la formule de colonne calculée :

1. L’opérateur d’addition (+) est évalué avant l’opérateur de concaténation de texte (&).
2. La fonction DAX YEAR retourne la valeur numérique entière de l’année d’échéance.
3. La fonction DAX IF retourne la valeur lorsque le numéro du mois de la date d’échéance est compris entre 7 et 12 (juillet et décembre) ; dans le cas contraire, elle retourne la valeur BLANK. (Par exemple, étant donné que l’année fiscale d’Adventure Works s’étend de juillet à juin, les six derniers mois de l’année civile utilisent la prochaine année civile comme année fiscale.)
4. La valeur Year (Année) est ajoutée à la valeur retournée par la fonction IF, soit la valeur 1 ou BLANK. Si la valeur est BLANK, elle est implicitement convertie en zéro (0) pour permettre l’ajout de la valeur de l’année fiscale.
5. La valeur littérale "FY" concaténée avec la valeur de l’année fiscale, implicitement convertie en texte.

Ajoutez une deuxième colonne calculée à l’aide de la définition suivante :

Due Fiscal Quarter =
'Due Date'[Due Fiscal Year] & " Q"
    & IF(
        MONTH('Due Date'[Due Date]) <= 3,
        3,
        IF(
            MONTH('Due Date'[Due Date]) <= 6,
            4,
            IF(
                MONTH('Due Date'[Due Date]) <= 9,
                1,
                2
            )
        )
    )

La définition de colonne calculée ajoute la colonne Due Fiscal Quarter (Trimestre fiscal d’échéance) à la table Due Date (Date d’échéance). La fonction IF retourne le numéro de trimestre (le trimestre 1 - Quarter 1- correspond à la période juillet-septembre), et le résultat est concaténé à la valeur Due Fiscal Quarter (Trimestre fiscal d’échéance) et au texte littéral Q.

Ajoutez une troisième colonne calculée à l’aide de la définition suivante :

Due Month =
FORMAT('Due Date'[Due Date], "yyyy mmm")

La définition de colonne calculée ajoute la colonne Due Month (Mois d’échéance) à la table Due Date (Date d’échéance). La fonction DAX FORMAT convertit la valeur de la colonne Due Date (Date d’échéance) en texte à l’aide d’une chaîne de format. Dans ce cas, la chaîne de format génère une étiquette qui décrit l’année et le nom du mois abrégé.

Ajoutez une quatrième colonne calculée à l’aide de la définition suivante :

Due Full Date =
FORMAT('Due Date'[Due Date], "yyyy mmm, dd")

Ajoutez une cinquième colonne calculée à l’aide de la définition suivante :

MonthKey =
(YEAR('Due Date'[Due Date]) * 100) + MONTH('Due Date'[Due Date])

La colonne calculée MonthKey multiplie l’année de la date d’échéance par la valeur 100, puis ajoute le numéro du mois de la date d’échéance. Elle génère une valeur numérique permettant de trier les valeurs texte Due Month (Mois d’échéance) par ordre chronologique.

Vérifiez que la table Date d’échéance comporte six colonnes. La première colonne a été ajoutée lors de la création de la table calculée, et les cinq autres colonnes ont été ajoutées en tant que colonnes calculées.

Pour terminer la conception de la table Date d’échéance, vous pouvez :

• Triez la colonne Due Full Date (Date complète d’échéance) par la colonne Due Date (Date d’échéance).
• Triez la colonne Due Month (Mois d’échéance) par la colonne MonthKey.
• Masquez la colonne MonthKey.
• Créez une hiérarchie nommée Fiscal, avec les niveaux suivants :
  • Due Fiscal Year (Année fiscale d’échéance)
  • Due Fiscal Quarter (Trimestre fiscal d’échéance)
  • Due Month (Mois d’échéance)
  • Due Full Date (Date complète d’échéance)
• Marquez la table Date d’échéance comme une table de dates à l’aide de la colonne Date d’échéance.