Objet SWbemRefresher

Article
06/29/2023

L'objet SWbemRefresher est un objet conteneur qui peut rafraîchir les données de tous les objets qui lui sont ajoutés. Des instances uniques et des énumérateurs instance peuvent être ajoutés ou supprimés du conteneur. Ensemble d’objets ajoutés, chaque élément représenté par un instance SWbemRefreshableItem peut être traité comme une collection et énuméré. Les instances WMI de n’importe quelle classe peuvent être ajoutées à l’objet SWbemRefresher . Même si le fournisseur des données instance n’est pas un fournisseur hautes performances, l’objet d’actualisation peut toujours mettre à jour les données lors de l’appel d’actualisation. Si les données sont fournies par un fournisseur performant et que la propriété AutoReconnect est TRUE , l'objet SWbemRefresher tente de rétablir une connexion interrompue avec le fournisseur de données. Cet objet ne peut pas être créé par l’appel VBScript CreateObject.

L'opération de rafraîchissement peut être effectuée en appelant la méthode SWbemRefresher.Refresh ou la méthode SWbemObjectEx.Refresh_.

Membres

L'objet SWbemRefresher possède ces types de membres :

Méthodes
Propriétés

Méthodes

L'objet SWbemRefresher possède les méthodes suivantes.

Méthode	Description
Ajouter	Ajoute un nouvel objet actualisable à la collection dans l’objet d’actualisation.
AddEnum	Ajoute un nouvel énumérateur à l’objet d’actualisation.
DeleteAll	Supprime tous les éléments de la collection dans l'objet d’actualisation.
Élément	Retourne un élément d’actualisation spécifié de la collection.
Actualiser	Met à jour tous les éléments contenus dans l'objet d’actualisation.
Supprimer	Supprime l’objet d’élément d’actualisation ou le jeu d’objets avec un index spécifié de l’actualisation.

Propriétés

L'objet SWbemRefresher possède les méthodes suivantes.

Propriété	Type d’accès	Description
AutoReconnect	Lecture seule	Indique si l’actualisation se reconnecte automatiquement à un fournisseur distant si la connexion est interrompue.
Count	Lecture seule	Contient le nombre d’éléments dans l’objet d’actualisation.

Exemples

L’exemple suivant illustre la création d’un objet SWbemRefresher, l’utilisation des méthodes Add et AddEnum pour stocker un seul instance et une énumération instance, l’actualisation des données et l’utilisation de la propriété Item pour obtenir les objets SWbemRefreshableItem.

' Get namespace connections
set objServicesCimv2 = GetObject("winmgmts:root\cimv2")
set objServicesDefault = GetObject("winmgmts:root\default")

' Create a refresher object
set objRefresher = CreateObject("WbemScripting.SWbemRefresher")

' Add a single object (SWbemObjectEx) to the refresher. The "@"
' is used because _CIMOMIdentification is a singleton class- only 
' one instance exists. Note that the
' SWbemRefreshableItem.Object property must 
' be specified or the SWbemRefresher.Refresh call will fail.

set objRefreshableItem1 = objRefresher. _
    Add (objServicesDefault, "__CIMOMIdentification=@").Object

' Add an enumerator (SWbemObjectSet object)
' to the refresher. Note that the
' SWbemRefreshableItem.ObjectSet property
' must be specified or the SWbemRefresher.Refresh call will fail. 
set objRefreshableItem2 = objRefresher. _
    AddEnum (objServicesCimv2, "Win32_Process").ObjectSet

' Display number of items in refresher and update the data.
MsgBox "Number of items in refresher = " & objRefresher.Count
objRefresher.Refresh

' Iterate through the refresher. SWbemRefreshable
' Item.IsSet checks for whether the item is an enumerator.
for each RefreshableItem in objRefresher
 if RefreshableItem.IsSet then  
    MsgBox "Item with index " & RefreshableItem.Index &_
    " is an enumerator containing "_
    & RefreshableItem.ObjectSet.Count & " processes"
 else  
      MsgBox "Item with index " & RefreshableItem.Index _
          & " is a single object containing WMI version "_
          &  objRefreshableItem1.VersionCurrentlyRunning
 end if
next

Spécifications

Condition requise	Valeur
Client minimal pris en charge	Windows Vista
Serveur minimal pris en charge	Windows Server 2008
En-tête	Wbemdisp.h
Bibliothèque de types	Wbemdisp.tlb
DLL	Wbemdisp.dll
CLSID	CLSID_SWbemRefresher
IID	IID_ISWbemRefresher

Voir aussi

SWbemRefreshableItem
SWbemObjectEx
Objets de l'API de script

Partager via