Tâches WMI : Matériel informatique

Article
06/29/2023

Les tâches WMI pour matériel informatique obtiennent des informations sur la présence, l’état ou les propriétés des composants matériels. Par exemple, vous pouvez déterminer si un ordinateur est un ordinateur de bureau ou un ordinateur portable. Pour obtenir d’autres exemples, consultez TechNet ScriptCenter à https://www.microsoft.com/technet.

Les exemples de script présentés dans cette rubrique obtiennent les données uniquement à partir de l’ordinateur local. Pour plus d’informations sur l’utilisation du script en vue d’obtenir des données d’ordinateurs distants, consultez Connexion à WMI sur un ordinateur distant.

Pour exécuter un script

La procédure suivante décrit comment exécuter un script.

Copiez le code et enregistrez-le dans un fichier avec l’extension .vbs, par exemple nomdefichier.vbs. Vérifiez que votre éditeur de texte n’ajoute pas d’extension .txt au fichier.
Ouvrez une fenêtre d’invite de commandes, puis accédez au répertoire où vous avez enregistré le fichier.
Tapez cscript nomfichier.vbs à l’invite de commandes.
Si vous ne pouvez pas accéder à un journal des événements, vérifiez si vous exécutez la commande à partir d’une invite de commandes avec élévation de privilèges. Certains journaux des événements, par exemple le journal des événements de sécurité, peuvent être protégés par la fonctionnalité UAC (contrôle de compte d’utilisateur).

Notes

Par défaut, cscript affiche la sortie d’un script dans la fenêtre d’invite de commandes. Dans la mesure où les scripts WMI peuvent produire de grandes quantités de données en sortie, vous pouvez être amené à rediriger la sortie vers un fichier. Tapez cscript nomfichier.vbs > fichiersortie.txtà l’invite de commandes pour rediriger la sortie du scriptnomfichier.vbs vers fichiersortie.txt.

Le tableau suivant liste des exemples de script qui peuvent être utilisés pour obtenir divers types de données à partir de l’ordinateur local.

Comment puis-je... Classes ou méthodes WMI

... déterminer la quantité de mémoire libre d’un ordinateur ?

Utilisez la classe Win32_OperatingSystem et la propriété FreePhysicalMemory.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSettings = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colSettings 
    Wscript.Echo "Available Physical Memory: " & objOperatingSystem.FreePhysicalMemory
Next

PowerShell
`$mem = Get-WmiObject -Class Win32_OperatingSystem "System : {0}" -f $mem.csname "Free Memory: {0}" -f $mem.FreePhysicalMemory`

... déterminer si un ordinateur dispose d’un lecteur de DVD ?

Utilisez la classe Win32_CDROMDrive et vérifier l’acronyme DVD dans la propriété Nom ou DeviceID.

strComputer = "."
Set objWMIService = GetObject( "winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_CDROMDrive")
For Each objItem in colItems
    Wscript.Echo "Device ID: " & objItem.DeviceID
    Wscript.Echo "Description: " & objItem.Description
    Wscript.Echo "Name: " & objItem.Name 
Next

PowerShell
`$drives = Get-WmiObject -Class Win32_CDROMDrives $drives \| Format-Table DeviceID, Description, Name -autosize`

... déterminer la quantité de RAM installée sur un ordinateur ?

Utilisez la classe Win32_ComputerSystem et vérifiez la valeur de la propriété TotalPhysicalMemory.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSettings = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings 
    Wscript.Echo "System Name: " & objComputer.Name
    Wscript.Echo "Total Physical Memory: " & objComputer.TotalPhysicalMemory
Next

PowerShell
`$mem = Get-WmiObject -Class Win32_ComputerSystem`

... déterminer si un ordinateur a plusieurs processeurs ?

Utilisez la classe Win32_ComputerSystem et la propriété NumberOfProcessors.

strComputer = "."
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSettings = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings 
    Wscript.Echo "System Name: " & objComputer.Name
    Wscript.Echo "Number of Processors: " & objComputer.NumberOfProcessors
Next

PowerShell
`"System Name : {0}" -f $system.Name "Number of Processors: {0}" -f $system.NumberOfProcessors`

... déterminer si un ordinateur dispose d’un emplacement PCMCIA ?

Utilisez la classe Win32_PCMCIAController et vérifiez la valeur de la propriété Count. Si Count a la valeur 0, l’ordinateur n’a pas d’emplacements PCMCIA.

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_PCMCIAController")
Wscript.Echo "Number of PCMCIA slots: " & colItems.Count

PowerShell
`$Pcmcia = Get-WmiObject -Class Win32_PCMCIAController` `if (!$pcmcia.count) { "Number of PCMCIA Slots: {0}" -f 1 }else { "Number of PCMCIA Slots: {0}" -f $pcmcia.count }`

... identifier les appareils qui ne fonctionnent pas (ceux marqués par une icône de point d’exclamation dans Gestionnaire de périphériques) ?

Utilisez la classe Win32_PnPEntity et utilisez la clause suivante dans votre requête WQL. WHERE ConfigManagerErrorCode <> 0 Notez que ce code peut ne pas détecter les périphériques USB manquants.

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_PnPEntity WHERE ConfigManagerErrorCode <> 0")
For Each objItem in colItems
    Wscript.Echo "Class GUID: " & objItem.ClassGuid
    Wscript.Echo "Description: " & objItem.Description
    Wscript.Echo "Device ID: " & objItem.DeviceID
    Wscript.Echo "Manufacturer: " & objItem.Manufacturer
    Wscript.Echo "Name: " & objItem.Name
    Wscript.Echo "PNP Device ID: " & objItem.PNPDeviceID
    Wscript.Echo "Service: " & objItem.Service
Next

PowerShell

$baddevices = Get-WmiObject Win32_PNPEntity | where {$_.ConfigManagerErrorcode -ne 0}
" Total Bad devices: {0}" -f $baddevices.count
foreach ($device in $baddevices) {
    "Name : {0}" -f $device.name
    "Class Guid : {0}" -f $device.Classguid
    "Description : {0}" -f $device.Description
    "Device ID : {0}" -f $device.deviceid
    "Manufacturer : {0}" -f $device.manufactuer
    "PNP Devcice Id : {0}" -f $device.PNPDeviceID
    "Service Name : {0}" -f $device.service
    ""
}

... déterminer les propriétés de la souris utilisée sur l’ordinateur ?

Utilisez la classe Win32_PointingDevice. Cela retourne les propriétés de tous les appareils de pointage, et pas seulement les souris.

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_PointingDevice")
For Each objItem in colItems
    Wscript.Echo "Description: " & objItem.Description
    Wscript.Echo "Device ID: " & objItem.DeviceID
    Wscript.Echo "Device Interface: " & objItem.DeviceInterface
    Wscript.Echo "Double Speed Threshold: " & objItem.DoubleSpeedThreshold
    Wscript.Echo "Handedness: " & objItem.Handedness
    Wscript.Echo "Hardware Type: " & objItem.HardwareType
    Wscript.Echo "INF File Name: " & objItem.InfFileName
    Wscript.Echo "INF Section: " & objItem.InfSection
    Wscript.Echo "Manufacturer: " & objItem.Manufacturer
    Wscript.Echo "Name: " & objItem.Name
    Wscript.Echo "Number Of Buttons: " & objItem.NumberOfButtons
    Wscript.Echo "PNP Device ID: " & objItem.PNPDeviceID
    Wscript.Echo "Pointing Type: " & objItem.PointingType
    Wscript.Echo "Quad Speed Threshold: " & objItem.QuadSpeedThreshold
    Wscript.Echo "Resolution: " & objItem.Resolution
    Wscript.Echo "Sample Rate: " & objItem.SampleRate
    Wscript.Echo "Synch: " & objItem.Synch
Next

PowerShell

              
              # Obtenir les informations liées à la souris$mouse = Get-WmiObject -Class Win32_PointingDevice

              <# Décodage des détails #>
fonction Deviceinterface { param ($value) switch ($value) { 0 {"Other"} 1 {"Unknown"} 3 {"Serial"} 4 {"PS/2"} 5 {"Infrared"} 6 {"HP-HIL"} 7 {"Bus Mouse"} 8 {"ADP (Apple Desktop Bus)"} 160 {"Bus Mouse DB-9"} 161 {"Bus Mouse Micro-DIN"} 162 {"USB"} } }
fonction Handedness { param ($value) switch ($value) { 0 {"Unknown"} 1 {"Not Applicable"} 2 {"Right-Handed Operation"} 3 {"Left-Handed Operation"} } }
fonction Pointingtype {
param ($value) switch ($value) { 1 {"Other"} 2 {"Unknown"} 3 {"Mouse"} 4 {"Track Ball"} 5 {"Track Point"} 6 {"Glide Point"} 7 {"Touch Pad"} 8 {"Touch Screen"} 9 {"Mouse - Optical Sensor"} } }

              <# Affichage des détails #>
"Mouse Information on System: {0}" -f $mouse.systemname
"Description : {0}" -f $mouse.Description
"Device ID : {0}" -f $mouse.DeviceID
"Device Interface : {0}" -f (Deviceinterface($mouse.DeviceInterface))
"Double Speed Threshold : {0}" -f $mouse.DoubleSpeedThreshold
"Handedness : {0}" -f (Handedness($mouse.handedness))
"Hardware Type : {0}" -f $mouse.Hardwaretype
"INF FIle Name : {0}" -f $mouse.InfFileName
"Inf Section : {0}" -f $mouse.InfSection
"Manufacturer : {0}" -f $mouse.Manufacturer
"Name : {0}" -f $mouse.Name
"Number of buttons : {0}" -f $mouse.NumberOfButtons
"PNP Device ID : {0}" -f $mouse.PNPDeviceID
"Pointing Type : {0}" -f (Pointingtype ($mouse.PointingType))
"Quad Speed Threshold : {0}" -f $mouse.QuadSpeedThreshold
"Resolution : {0}" -f $mouse.Resolution
"Sample Rate : {0}" -f $mouse.SampleRate
"Synch : {0}" -f $mouse.Synch

... déterminer la vitesse d’un processeur installé sur un ordinateur ?

Utilisez la classe Win32_Processor et vérifier la valeur de la propriété MaxClockSpeed.

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_Processor")
For Each objItem in colItems
    Wscript.Echo "Processor Id: " & objItem.ProcessorId
    Wscript.Echo "Maximum Clock Speed: " & objItem.MaxClockSpeed
Next

... déterminer si un ordinateur est une tour, une mini-tour, un ordinateur portable, etc. ?

Utilisez la classe Win32_SystemEnclosure et vérifiez la valeur de la propriété ChassisType.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colChassis = objWMIService.ExecQuery("Select * from Win32_SystemEnclosure")
For Each objChassis in colChassis
    For Each objItem in objChassis.ChassisTypes
        Wscript.Echo "Chassis Type: " & objItem
    Next
Next

PowerShell
`$processors = Get-WmiObject -Class Win32_Processor foreach ($proc in $processors) { "Processor ID: " + $proc.ProcessorID "Maximum Clock Speed: " + $proc.MaxClockSpeed }`

... obtenir le numéro de série et la balise de ressource d’un ordinateur ?

Utilisez la classe Win32_SystemEnclosure et les propriétés SerialNumber et SMBIOSAssetTag.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSMBIOS = objWMIService.ExecQuery("Select * from Win32_SystemEnclosure")
For Each objSMBIOS in colSMBIOS
    Wscript.Echo "Part Number: " & objSMBIOS.PartNumber
    Wscript.Echo "Serial Number: " & objSMBIOS.SerialNumber
    Wscript.Echo "Asset Tag: " & objSMBIOS.SMBIOSAssetTag
Next

PowerShell

$colSMBIOS = Get-WmiObject -Class Win32_SystemEnclosure

foreach ($objSMBIOS in $colSMBIOS) { "Part Number: " + $objSMBIOS.PartNumber "Serial Number: " + $objSMBIOS.SerialNumber "Asset Tag: " + $objSMBIOS.SMBIOSAssetTag }

... déterminer quel type d’appareil est branché sur un port USB ?

Utilisez la classe Win32_USBHub et vérifiez la propriété Description. Cette propriété peut avoir une valeur telle que « Appareil de stockage de masse » ou « Support d’impression ».

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_USBHub")
For Each objItem in colItems
    Wscript.Echo "Device ID: " & objItem.DeviceID
    Wscript.Echo "PNP Device ID: " & objItem.PNPDeviceID
    Wscript.Echo "Description: " & objItem.Description
    Wscript.Echo
Next

PowerShell
`$colItems = Get-WmiObject -Class Win32_USBHub` `foreach ($objItem in $colItems) { "Device ID: " + $objItem.DeviceID "PNP Device ID: " + $objItem.PNPDeviceID "Description: " + $objItem.Description }`

... déterminer le nombre de lecteurs de bande installés sur un ordinateur ?

Utilisez la classe Win32_TapeDrive classe, puis utilisez la méthode SWbemObjectSet.Count . Si Count = 0, aucun lecteur de bande n’est installé sur l’ordinateur.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_TapeDrive")
Wscript.Echo "Number of tape drives: " & colItems.Count

PowerShell
`$colItems = Get-WmiObject -Class Win32_TapeDrive` `foreach ($objItem in $colItems) { "Number of Drives: " + $colItems.Count }`

Exemples

L’exemple de code TechNet Gallery suivant décrit comment répertorier l’espace libre de tous les lecteurs pour plusieurs ordinateurs.

L’exemple PowerShell Obtenir des informations sur l'ordinateur - Interroger des informations sur l'ordinateur à partir d'ordinateurs locaux ou distants - (WMI) sur TechNet Gallery utilise un certain nombre d’appels au matériel et aux logiciels pour afficher des informations sur un système local ou distant.

L’exemple Collecte de données système multithread avec PowerShell sur TechNetGallery rassemble une pléthore d’informations système utiles via WMI et le multithreading avec PowerShell.

Tâches WMI pour les scripts et les applications
Exemples d’applications WMI C++
TechNet ScriptCenter

Partager via

Tâches WMI : Matériel informatique

Pour exécuter un script

Exemples

Commentaires

Ressources supplémentaires

Partager via

Tâches WMI : Matériel informatique

Pour exécuter un script

Exemples

Rubriques connexes

Commentaires

Ressources supplémentaires