Propriété Session.Timeout

Définit et obtient la durée maximale, en millisecondes, pendant laquelle l’application cliente attend que Windows Remote Management termine ses opérations.

Cette propriété est en lecture/écriture.

Syntaxe

Session.Timeout As long

Valeur de la propriété

Valeur de délai d’attente, en millisecondes. Lorsque la valeur du délai d’attente est dépassée, une erreur d’exécution se produit.

Notes

La valeur de délai d’attente peut être définie avant chaque opération effectuée par l’agent. Si aucune valeur de délai d’attente n’est spécifiée, l’agent définit la valeur de délai d’attente.

Pendant une opération d’énumération, la valeur du délai d’attente ne peut pas être réinitialisée pendant l’énumération de la ressource.

Exemples

L’exemple de code VBScript suivant démarre un processus Calc.exe à l’aide de la méthode Create de la classe Win32_Process WMI. Le paramètre strInputParameters contient les paramètres d’entrée au format XML. Le script spécifie un délai d’attente pour la session.

Set objWsman = CreateObject( "WSMan.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" & _
    "wmi/root/cimv2/Win32_Process"

'Reset timeout to 10,000 milliseconds
objSession.Timeout = 10000     

strInputParameters = "<p:Create_INPUT " & _
    "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/wmi/root/cimv2/Win32_Process"">" & _
    "<p:CommandLine>" & "calc.exe" & _
    "</p:CommandLine>" & _
    "</p:Create_INPUT>"

strOutputParameters = objSession.Invoke( "Create", _
    strResource, strInputParameters )

DisplayOutput( strOutputParameters )

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Spécifications

Voir aussi

session