Condividi tramite

Query per la tabella AzureMetrics

  • Articolo

Per informazioni sull'uso di queste query nella portale di Azure, vedere Esercitazione su Log Analytics. Per l'API REST, vedere Query.

Grafico a torta dei codici di risposta HTTP

Suddivisione dei codici di risposta per ogni metrica, nelle ultime 12 ore.

AzureMetrics 
| where TimeGenerated > ago(12h)  
| where MetricName in ("Http2xx", "Http3xx", "Http4xx", "Http5xx") 
| summarize sum(Total) by MetricName  
| render piechart

Grafico a linee dei tempi di risposta

Serie temporale del tempo di risposta medio (oltre 5 minuti).

AzureMetrics 
| extend timeBin = bin(TimeGenerated, 5m) 
| summarize ResponseTime = sumif(Average, MetricName=="AverageResponseTime") by timeBin, bin(TimeGenerated, 1h) 
| sort by TimeGenerated desc 
| render timechart

[Classico] Trovare in AzureMetrics

[Classico] Trovare in AzureMetrics per cercare un valore specifico nella tabella AzureMetrics./nNote che questa query richiede l'aggiornamento del <parametro SeachValue> per produrre risultati

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
AzureMetrics
| where * contains tostring(SearchValue)
| take 1000

Metriche più recenti

Mostra i report delle metriche più recenti per ogni metrica segnalata.

AzureMetrics 
| summarize arg_max(TimeGenerated, UnitName, Total, Count, Maximum, Minimum, Average) by MetricName

Trovare in AzureMetrics

Trovare in AzureMetrics per cercare un valore specifico nella tabella AzureMetrics./nNote che questa query richiede l'aggiornamento del <parametro SeachValue> per produrre risultati

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
AzureMetrics
| where * contains tostring(SearchValue)
| take 1000

Grafico del traffico ExpressRoute Circuit BitsInPerSecond

Grafico del traffico BitsInPerSecond (ultima ora).

AzureMetrics
| where MetricName == "BitsInPerSecond"
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Grafico del traffico ExpressRoute Circuit BitsOutPerSecond

Grafico del traffico BitsOutPerSecond (ultima ora).

AzureMetrics
| where MetricName == "BitsOutPerSecond"
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Grafico ArpAvailablility del circuito ExpressRoute

Grafico del traffico per ArpAvailability (5 minuti).

AzureMetrics
| where MetricName == "ArpAvailability"
| summarize by Average, bin(TimeGenerated, 5m), Resource
| render timechart

Disponibilità BGP del circuito ExpressRoute

Grafico del traffico per BgpAvailability (5 minuti).

AzureMetrics
| where MetricName == "BgpAvailability"
| summarize by Average, bin(TimeGenerated, 5m), Resource
| render timechart

Utilizzo medio della CPU

Utilizzo medio della CPU nell'ultima ora in base al nome della risorsa.

//consistently high averages could indicate a customer needs to move to a larger SKU
AzureMetrics
| where ResourceProvider == "MICROSOFT.SQL" // /DATABASES
| where TimeGenerated >= ago(60min)
| where MetricName in ('cpu_percent') 
| parse _ResourceId with * "/microsoft.sql/servers/" Resource  // subtract Resource name for _ResourceId
| summarize CPU_Maximum_last15mins = max(Maximum), CPU_Minimum_last15mins = min(Minimum), CPU_Average_last15mins = avg(Average) by Resource , MetricName

Risoluzione dei problemi di prestazioni

Potenzialmente eseguire query o deadlock nel sistema che potrebbe causare prestazioni scarse.

//potentially a query or deadlock on the system that could lead to poor performance
AzureMetrics
| where ResourceProvider == "MICROSOFT.SQL"
| where TimeGenerated >=ago(60min)
| where MetricName in ('deadlock')
| parse _ResourceId with * "/microsoft.sql/servers/" Resource // subtract Resource name for _ResourceId
| summarize Deadlock_max_60Mins = max(Maximum) by Resource, MetricName

Caricamento di dati

Monitorare il caricamento dei dati nell'ultima ora.

AzureMetrics
| where ResourceProvider == "MICROSOFT.SQL"
| where TimeGenerated >= ago(60min)
| where MetricName in ('log_write_percent')
| parse _ResourceId with * "/microsoft.sql/servers/" Resource// subtract Resource name for _ResourceId
| summarize Log_Maximum_last60mins = max(Maximum), Log_Minimum_last60mins = min(Minimum), Log_Average_last60mins = avg(Average) by Resource, MetricName

Numero di connessioni da sito a sito

Numero di connessioni da sito a sito attivo per gli ultimi 30 giorni.

AzureMetrics 
| where TimeGenerated > ago(30d)
| where MetricName == "P2SConnectionCount"
| summarize by Maximum, bin(TimeGenerated,1h), Resource
| render timechart

Utilizzo della larghezza di banda da sito a sito

Utilizzo medio della larghezza di banda da punto a sito nelle ultime 12 ore in bit al secondo.

AzureMetrics
| where TimeGenerated > ago(24h)
| where MetricName == "P2SBandwidth" 
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Velocità effettiva del gateway

Aggregare la velocità effettiva del gateway in byte/sec.

AzureMetrics 
| where TimeGenerated > ago(24h)
| where MetricName == "AverageBandwidth"
| summarize by Average, bin(TimeGenerated, 1h), Resource
| render timechart

Visualizzare i log dalla tabella AzureMetrics

Elenca i log più recenti nella tabella AzureMetrics, ordinati in base all'ora (prima più recente).

AzureMetrics
| top 10 by TimeGenerated

Visualizzare i log dalla tabella AzureMetrics

Elenca i log più recenti nella tabella AzureMetrics, ordinati in base all'ora (prima più recente).

AzureMetrics
| top 10 by TimeGenerated

Disponibilità del cluster (KeepAlive)

Visualizzare la disponibilità del cluster durante l'ultima ora.

// To create an alert for this query, click '+ New alert rule'
AzureMetrics 
| where ResourceProvider == "MICROSOFT.KUSTO"
| where TimeGenerated > ago(1d)
| where MetricName == "KeepAlive"
| parse _ResourceId with * "providers/microsoft.kusto/clusters/" cluster_name // Get the cluster name from the ResourceId string
| summarize heartbeat_count = count() by bin(TimeGenerated, 30m), cluster_name // bin is used to set the time grain to 30 minutes
| extend alive=iff(heartbeat_count > 0, true, false)
| sort by TimeGenerated asc // sort the results by time (ascending order)