Query per la tabella WVDConnectionNetworkData

Articolo
11/05/2024

Per informazioni sull'uso di queste query nella portale di Azure, vedere Esercitazione su Log Analytics. Per l'API REST, vedere Query.

Tempo medio di round trip nel tempo

Visualizzare un grafico del tempo di round trip (in millisecondi) in tutte le connessioni in intervalli di 10 minuti al 10°, al 50° e al 90° percentile.

WVDConnectionNetworkData
| summarize percentiles(EstRoundTripTimeInMs, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

BW medio tra tutte le connessioni

Visualizza un grafico della larghezza di banda (in kilobyte al secondo) in tutte le connessioni in intervalli di 10 minuti al 10°, 50° e 90° percentile.

WVDConnectionNetworkData
| summarize percentiles(EstAvailableBandwidthKBps, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Primi 10 utenti con il tempo di round trip più alto

Restituisce un elenco dei primi 10 utenti con il tempo medio medio di round trip (in millisecondi).

WVDConnectionNetworkData
| join kind=leftouter 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=round(avg(EstRoundTripTimeInMs)), RTT_P95=percentile(EstRoundTripTimeInMs, 95) by UserName
| top 10 by AvgRTT desc

Primi 10 utenti con larghezza di banda più bassa

Restituisce un elenco dei primi 10 utenti con la larghezza di banda media più bassa (in Kilobyte al secondo).

WVDConnectionNetworkData
| join kind=inner 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps), BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Riepilogo del tempo di round trip e della larghezza di banda

Restituisce i 90° percentili per il tempo di round trip (in millisecondi) e la larghezza di banda (in kilobyte) per ogni connessione insieme a dettagli aggiuntivi sulla connessione.

WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90), BWP90=percentile(EstAvailableBandwidthKBps,90), StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=inner
(
    WVDConnections
    | where State == "Connected"
    | extend Protocol = iif(UdpUse in ("0", "<>"), "TCP", "UDP")
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion

Condividi tramite