Guida introduttiva: Creare un'istanza di Azure Container con un indirizzo IP pubblico usando Terraform

Istanze di Azure Container consente di eseguire i contenitori Docker serverless in Azure in modo semplice e rapido. Distribuire un'applicazione in un'istanza di contenitore su richiesta quando non è necessaria una piattaforma di orchestrazione di contenitori completa come il servizio Azure Kubernetes. In questo articolo viene usato Terraform per distribuire un contenitore Docker isolato e rendere disponibile l'applicazione Web con un indirizzo IP pubblico.

Terraform consente di definire, visualizzare in anteprima e distribuire l'infrastruttura cloud. Con Terraform è possibile creare file di configurazione usando la sintassi HCL. La sintassi HCL consente di specificare il provider di servizi cloud, ad esempio Azure, e gli elementi che costituiscono l'infrastruttura cloud. Dopo aver creato i file di configurazione, è necessario creare un piano di esecuzione che consenta di visualizzare in anteprima le modifiche apportate all'infrastruttura prima che vengano distribuite. Dopo aver verificato le modifiche, è possibile applicare il piano di esecuzione per distribuire l'infrastruttura.

In questo articolo vengono illustrate le operazioni seguenti:

Prerequisiti

• Installare e configurare Terraform

Implementare il codice Terraform

1. Creare una directory in cui testare ed eseguire il codice Terraform di esempio e impostarla come directory corrente.

2. Creare un file denominato main.tf e inserire il codice seguente:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "container_name" {
     length  = 25
     lower   = true
     upper   = false
     special = false
   }
   
   resource "azurerm_container_group" "container" {
     name                = "${var.container_group_name_prefix}-${random_string.container_name.result}"
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
     ip_address_type     = "Public"
     os_type             = "Linux"
     restart_policy      = var.restart_policy
   
     container {
       name   = "${var.container_name_prefix}-${random_string.container_name.result}"
       image  = var.image
       cpu    = var.cpu_cores
       memory = var.memory_in_gb
   
       ports {
         port     = var.port
         protocol = "TCP"
       }
     }
   }
   

3. Creare un file denominato outputs.tf e inserire il codice seguente:

   output "container_ipv4_address" {
     value = azurerm_container_group.container.ip_address
   }
   

4. Creare un file denominato providers.tf e inserire il codice seguente:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. Creare un file denominato variables.tf e inserire il codice seguente:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location for all resources."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random value so name is unique in your Azure subscription."
   }
   
   variable "container_group_name_prefix" {
     type        = string
     description = "Prefix of the container group name that's combined with a random value so name is unique in your Azure subscription."
     default     = "acigroup"
   }
   
   variable "container_name_prefix" {
     type        = string
     description = "Prefix of the container name that's combined with a random value so name is unique in your Azure subscription."
     default     = "aci"
   }
   
   variable "image" {
     type        = string
     description = "Container image to deploy. Should be of the form repoName/imagename:tag for images stored in public Docker Hub, or a fully qualified URI for other registries. Images from private registries require additional registry credentials."
     default     = "mcr.microsoft.com/azuredocs/aci-helloworld"
   }
   
   variable "port" {
     type        = number
     description = "Port to open on the container and the public IP address."
     default     = 80
   }
   
   variable "cpu_cores" {
     type        = number
     description = "The number of CPU cores to allocate to the container."
     default     = 1
   }
   
   variable "memory_in_gb" {
     type        = number
     description = "The amount of memory to allocate to the container in gigabytes."
     default     = 2
   }
   
   variable "restart_policy" {
     type        = string
     description = "The behavior of Azure runtime if container has stopped."
     default     = "Always"
     validation {
       condition     = contains(["Always", "Never", "OnFailure"], var.restart_policy)
       error_message = "The restart_policy must be one of the following: Always, Never, OnFailure."
     }
   }
   

Inizializzare Terraform

Per inizializzare la distribuzione di Terraform, eseguire terraform init. Questo comando scarica il provider di Azure necessario per gestire le risorse di Azure.

terraform init -upgrade

Punti principali:

• Il parametro -upgrade aggiorna i plug-in del provider necessari alla versione più recente conforme ai vincoli di versione della configurazione.

Creare un piano di esecuzione Terraform

Eseguire terraform plan per creare un piano di esecuzione.

terraform plan -out main.tfplan

Punti principali:

• Il comando terraform plan consente di creare un piano di esecuzione, ma non di eseguirlo. Determina invece le azioni necessarie per creare la configurazione specificata nei file di configurazione. Questo modello consente di verificare se il piano di esecuzione corrisponde alle aspettative prima di apportare modifiche alle risorse effettive.
• Il parametro -out facoltativo consente di specificare un file di output per il piano. L'uso del parametro -out garantisce che il piano esaminato sia esattamente quello che viene applicato.

Applicare un piano di esecuzione Terraform

Eseguire terraform apply per applicare il piano di esecuzione all'infrastruttura cloud.

terraform apply main.tfplan

Punti principali:

• Il comando terraform apply di esempio presuppone che in precedenza sia stato eseguito terraform plan -out main.tfplan.
• Se è stato specificato un nome file diverso per il parametro -out, usare lo stesso nome file nella chiamata a terraform apply.
• Se non è stato usato il parametro -out, chiamare terraform apply senza parametri.

Verificare i risultati

1. Quando si applica il piano di esecuzione, Terraform restituisce l'indirizzo IP pubblico. Per visualizzare di nuovo l'indirizzo IP, eseguire l'output terraform.

   terraform output -raw container_ipv4_address
   

2. Immettere l'indirizzo IP pubblico dell'esempio nella barra degli indirizzi del browser.

   

Pulire le risorse

Quando le risorse create tramite Terraform non sono più necessarie, eseguire i passaggi seguenti:

1. Eseguire terraform plan e specificare il flag destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Punti principali:

   • Il comando terraform plan consente di creare un piano di esecuzione, ma non di eseguirlo. Determina invece le azioni necessarie per creare la configurazione specificata nei file di configurazione. Questo modello consente di verificare se il piano di esecuzione corrisponde alle aspettative prima di apportare modifiche alle risorse effettive.
   • Il parametro -out facoltativo consente di specificare un file di output per il piano. L'uso del parametro -out garantisce che il piano esaminato sia esattamente quello che viene applicato.

2. Eseguire terraform apply per applicare il piano di esecuzione.

   terraform apply main.destroy.tfplan
   

Risolvere i problemi di Terraform in Azure

Risolvere i problemi comuni relativi all'uso di Terraform in Azure

Passaggi successivi