arg_max() (funzione di aggregazione)

Si applica a: ✅Microsoft Fabric✅

Trova una riga nella tabella che ottimizza l'espressione specificata. Restituisce tutte le colonne della tabella di input o delle colonne specificate.

Alias deprecati: argmax()

Sintassi

arg_max ( ExprToMaximize,* | ExprToReturn [, ...])

Altre informazioni sulle convenzioni di sintassi.

Parametri

Valori restituiti

Restituisce una riga nella tabella che ottimizza l'espressione specificata ExprToMaximizee i valori delle colonne specificate in ExprToReturn.

Esempi

Trovare la latitudine massima di un evento storm in ogni stato.

StormEvents 
| summarize arg_max(BeginLat, BeginLocation) by State

Nella tabella dei risultati vengono visualizzate solo le prime 10 righe.

Trovare l'ultima volta che si è verificato un evento con un decesso diretto in ogni stato, mostrando tutte le colonne.

La query filtra prima gli eventi in modo da includere solo quelli in cui si è verificato almeno un decesso diretto. La query restituisce quindi l'intera riga con il valore StartTime più recente.

StormEvents
| where DeathsDirect > 0
| summarize arg_max(StartTime, *) by State

Nella tabella dei risultati vengono visualizzate solo le prime 10 righe e le prime 3 colonne.

Nell'esempio seguente viene illustrata la gestione dei valori Null.

datatable(Fruit: string, Color: string, Version: int) [
    "Apple", "Red", 1,
    "Apple", "Green", int(null),
    "Banana", "Yellow", int(null),
    "Banana", "Green", int(null),
    "Pear", "Brown", 1,
    "Pear", "Green", 2,
]
| summarize arg_max(Version, *) by Fruit

Output

Confronto con max()

La funzione arg_max() è diversa dalla funzione max(). La funzione arg_max() consente di restituire colonne aggiuntive insieme al valore massimo e max() restituisce solo il valore massimo stesso.

Esempi

arg_max()

Trovare l'ultima volta che si è verificato un evento con un decesso diretto, visualizzando tutte le colonne della tabella.

La query filtra prima gli eventi in modo da includere solo quelli in cui si è verificato almeno un decesso diretto. La query restituisce quindi l'intera riga con il valore StartTime più recente (massimo).

StormEvents
| where DeathsDirect > 0
| summarize arg_max(StartTime, *)

La tabella dei risultati restituisce tutte le colonne per la riga contenente il valore più alto nell'espressione specificata.

max()

Trovare l'ultima volta che si è verificato un evento con una morte diretta.

La query filtra gli eventi in modo da includere solo quelli in cui è presente almeno una morte diretta e quindi restituisce il valore massimo per StartTime.

StormEvents
| where DeathsDirect > 0
| summarize max(StartTime)

La tabella dei risultati restituisce il valore massimo di StartTime, senza restituire altre colonne per questo record.

Contenuto correlato

• max function
• funzione min
• funzione avg
• funzione percentile