Raccogliere ed eseguire query sui dati di qualità della connessione

Articolo
10/16/2024

Importante

I log dei dati della grafica di connessione sono attualmente in anteprima. Vedere le condizioni per l'utilizzo supplementari per le anteprime di Microsoft Azure per termini legali aggiuntivi che si applicano a funzionalità di Azure in versione beta, in anteprima o in altro modo non ancora disponibili a livello generale.

La qualità della connessione è essenziale per un'esperienza utente positiva, quindi è importante essere in grado di monitorare le connessioni per individuare potenziali problemi e risolvere i problemi man mano che si verificano. Desktop virtuale Azure si integra con strumenti come Log Analytics che consentono di monitorare l'integrità della connessione della distribuzione. Questo articolo illustra come configurare le impostazioni di diagnostica per consentire di raccogliere dati sulla qualità della connessione ed eseguire query sui dati per parametri specifici.

Prerequisiti

Per iniziare a raccogliere dati sulla qualità della connessione, è necessario configurare un'area di lavoro Log Analytics da usare con Desktop virtuale Azure.

Nota

Verranno applicati i normali addebiti per l'archiviazione per Log Analytics. Per altre informazioni, vedere Dettagli sui prezzi dei log di Monitoraggio di Azure.

Configurate le impostazioni di diagnostica

Per controllare e modificare le impostazioni di diagnostica nel portale di Azure:

Accedere al portale di Azure, quindi passare a Desktop virtuale Azure e selezionare Pool di host.
Selezionare il pool di host per cui si vogliono raccogliere i dati di rete.
Selezionare Impostazioni di diagnostica, quindi creare una nuova impostazione se non sono ancora state configurate le impostazioni di diagnostica. Se sono già state configurate le impostazioni di diagnostica, selezionare Modifica impostazione.
Selezionare allLogs se si desidera raccogliere dati per tutte le tabelle. Il parametro allLogs aggiungerà automaticamente nuove tabelle alla tabella dati in futuro.

Se si preferisce visualizzare tabelle più specifiche, selezionare prima di tutto Log dei dati di rete e Anteprima log di dati grafica connessione, quindi selezionare i nomi delle altre tabelle da visualizzare.
Selezionare la posizione in cui inviare i dati raccolti. Gli utenti di Desktop virtuale Azure devono selezionare un'area di lavoro Log Analytics.
Seleziona Salva per applicare le modifiche.
Ripetere questo processo per tutti gli altri pool di host da misurare.
Per controllare i dati di rete, tornare alla pagina delle risorse del pool di host, selezionare Loge quindi eseguire una delle query in Query di esempio per Azure Log Analytics. Affinché la query ottenga i risultati, il pool di host deve aver avuto utenti attivi connessi alle sessioni in passato. Tenere presente che la visualizzazione dei dati di rete nel portale di Azure può richiedere fino a 15 minuti.

Query di esempio per Azure Log Analytics: dati di rete

In questa sezione è disponibile un elenco di query che consentono di esaminare le informazioni sulla qualità della connessione. È possibile eseguire query nell'editor di query di Log Analytics.

Nota

Per ogni esempio, sostituire la variabile userupn con l'UPN dell'utente da cercare.

Larghezza di banda e RTT medi delle query

Per cercare il tempo medio di round trip e la larghezza di banda:

// 90th, 50th, 10th Percentile for RTT in 10 min increments
WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90),RTTP50=percentile(EstRoundTripTimeInMs,50),RTTP10=percentile(EstRoundTripTimeInMs,10) by bin(TimeGenerated,10m)
| render timechart
// 90th, 50th, 10th Percentile for BW in 10 min increments
WVDConnectionNetworkData
| summarize BWP90=percentile(EstAvailableBandwidthKBps,90),BWP50=percentile(EstAvailableBandwidthKBps,50),BWP10=percentile(EstAvailableBandwidthKBps,10) by bin(TimeGenerated,10m)
| render timechart

Per cercare il tempo di round trip e la larghezza di banda per ogni connessione:

// RTT and BW Per Connection Summary
// Returns P90 Round Trip Time (ms) and Bandwidth (KBps) per connection with connection details.
WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90),BWP90=percentile(EstAvailableBandwidthKBps,90),StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=leftouter (
WVDConnections
| extend Protocol = iff(UdpUse in ("0","<>"),"TCP","UDP")
| distinct CorrelationId, SessionHostName, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion, UserName
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion

Eseguire query sui dati per un utente specifico

Per cercare la larghezza di banda per un utente specifico:

let user = "alias@domain";
WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| where UserName == user
| project EstAvailableBandwidthKBps, TimeGenerated
| render columnchart

Per cercare il tempo di round trip per un utente specifico:

let user = "alias@domain";
WVDConnectionNetworkData
| join kind=leftouter (
WVDConnections
| distinct CorrelationId, UserName
) on CorrelationId
| where UserName == user
| project EstRoundTripTimeInMs, TimeGenerated
| render columnchart

Per cercare i primi 10 utenti con il tempo di round trip più alto:

WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=avg(EstRoundTripTimeInMs),RTT_P95=percentile(EstRoundTripTimeInMs,95) by UserName
| top 10 by AvgRTT desc

Per cercare i 10 utenti con la larghezza di banda più bassa:

WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps),BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Passaggi successivi

Altre informazioni sulla qualità della connessione sono disponibili in Qualità della connessione in Desktop virtuale Azure.

Condividi tramite