Condividi tramite

Procedure consigliate per FinOps per l'archiviazione

  • Articolo

Questo articolo illustra una raccolta di procedure FinOps comprovate per i servizi di archiviazione. Fornisce strategie per ottimizzare i costi, migliorare l'efficienza e usare query di Azure Resource Graph (ARG) per ottenere informazioni dettagliate sulle risorse di archiviazione. Seguendo queste procedure, è possibile assicurarsi che i servizi di archiviazione siano convenienti e allineati agli obiettivi finanziari dell'organizzazione.


Backup

Le sezioni seguenti forniscono query ARG per i servizi di backup. Queste query consentono di ottenere informazioni dettagliate sulle risorse di backup e assicurarsi che siano configurate con le impostazioni appropriate. Analizzando gli elementi di backup e identificando i backup inattivi, è possibile ottimizzare i servizi di backup per un'efficienza dei costi.

Query: backup inattive

Questa query ARG analizza gli elementi di backup all'interno degli insiemi di credenziali di Servizi di ripristino di Azure e identifica tutti gli elementi di cui non è stato eseguito il backup per oltre 90 giorni.

Categoria

Ottimizzazione

Query

recoveryservicesresources
| where type =~ 'microsoft.recoveryservices/vaults/backupfabrics/protectioncontainers/protecteditems'
| extend vaultId = tostring(properties.vaultId)
| extend resourceId = tostring(properties.sourceResourceId)
| extend idleBackup= datetime_diff('day', now(), todatetime(properties.lastBackupTime)) > 90
| extend  resourceType=tostring(properties.workloadType)
| extend protectionState=tostring(properties.protectionState)
| extend lastBackupTime=tostring(properties.lastBackupTime)
| extend resourceGroup=strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup)
| extend lastBackupDate=todatetime(properties.lastBackupTime)
| where idleBackup != 0
| project resourceId,vaultId,idleBackup,lastBackupDate,resourceType,protectionState,lastBackupTime,location,resourceGroup,subscriptionId

Query: Elencare gli insiemi di credenziali di Servizi di ripristino

Questa query di Azure Resource Graph (ARG) recupera i dettagli degli insiemi di credenziali di Servizi di ripristino di Azure. La query include anche informazioni sul livello SKU, le impostazioni di ridondanza e altri metadati pertinenti.

Categoria

Ottimizzazione

Query

resources
| where type == 'microsoft.recoveryservices/vaults'
| where resourceGroup in ({ResourceGroup})
| extend skuTier = tostring(sku['tier'])
| extend skuName = tostring(sku['name'])
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| extend redundancySettings = tostring(properties.redundancySettings['standardTierStorageRedundancy'])
| order by id asc
| project id, redundancySettings, resourceGroup, location, subscriptionId, skuTier, skuName

Dischi

Le sezioni seguenti forniscono query ARG per i servizi disco. Queste query consentono di ottenere informazioni dettagliate sulle risorse del disco e assicurarsi che siano configurate con le impostazioni appropriate. Analizzando gli snapshot del disco e identificando i dischi inattivi, è possibile ottimizzare i servizi su disco per un'efficienza dei costi.

Query: dischi inattive

Questa query ARG identifica i dischi gestiti inattive o scollegati all'interno dell'ambiente Azure.

Categoria

Ottimizzazione

Query

resources
| where type =~ 'microsoft.compute/disks' and managedBy == ""
| extend diskState = tostring(properties.diskState)
| where managedBy == ""
    and diskState != 'ActiveSAS'
    and tags !contains 'ASR-ReplicaDisk'
    and tags !contains 'asrseeddisk'
| extend DiskId=id, DiskIDfull=id, DiskName=name, SKUName=sku.name, SKUTier=sku.tier, DiskSizeGB=tostring(properties.diskSizeGB), Location=location, TimeCreated=tostring(properties.timeCreated), SubId=subscriptionId
| order by DiskId asc 
| project DiskId, DiskIDfull, DiskName, DiskSizeGB, SKUName, SKUTier, resourceGroup, Location, TimeCreated, subscriptionId

Query: snapshot del disco precedente a 30 giorni

Questa query ARG identifica gli snapshot del disco precedenti a 30 giorni.

Categoria

Ottimizzazione

Query

resources
| where type == 'microsoft.compute/snapshots'
| extend TimeCreated = properties.timeCreated
| extend resourceGroup = strcat("/subscriptions/",subscriptionId,"/resourceGroups/",resourceGroup)
| where TimeCreated < ago(30d)
| order by id asc 
| project id, resourceGroup, location, TimeCreated, subscriptionId

Query: Snapshot con Archiviazione Premium

Questa query ARG identifica gli snapshot del disco che usano l'archiviazione Premium.

Categoria

Ottimizzazione

Query

resources
| where type == 'microsoft.compute/snapshots'
| extend
    StorageSku = tostring(sku.tier),
    resourceGroup = strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup),
    diskSize = tostring(properties.diskSizeGB)
| where StorageSku == "Premium"
| project id, name, StorageSku, diskSize, location, resourceGroup, subscriptionId

Account di archiviazione

La sezione seguente fornisce una query ARG per gli account di archiviazione. Consente di ottenere informazioni dettagliate sulle risorse di archiviazione e assicurarsi che siano configurate con le impostazioni appropriate. Analizzando gli account di archiviazione e identificando i tipi di account di archiviazione legacy, è possibile ottimizzare i servizi di archiviazione per un'efficienza dei costi.

Query: Account di archiviazione v1

Questa query ARG identifica gli account di archiviazione che usano ancora il tipo legacy v1, che potrebbe non fornire le stesse funzionalità ed efficienza dei tipi di account di archiviazione più recenti.

Categoria

Ottimizzazione

Query

resources
| where type =~ 'Microsoft.Storage/StorageAccounts'
    and kind !='StorageV2'
    and kind !='FileStorage'
| where resourceGroup in ({ResourceGroup})
| extend
    StorageAccountName = name,
    SAKind = kind,
    AccessTier = tostring(properties.accessTier),
    SKUName = sku.name,
    SKUTier = sku.tier,
    Location = location
| order by id asc
| project
    id,
    StorageAccountName,
    SKUName,
    SKUTier,
    SAKind,
    AccessTier,
    resourceGroup,
    Location,
    subscriptionId

Stai cercando di più?

Ci mancava qualcosa? Vuoi vedere qualcosa aggiunto? Ci piacerebbe ascoltare eventuali domande, problemi o soluzioni che vorresti vedere qui. Creare un nuovo problema con i dettagli che si desidera visualizzare qui.


Contenuto correlato

Risorse correlate:

Soluzioni correlate: